64046_de-DE

liliconcom

Überlagern von Daten aus mehreren Parametern (jeder mit einem eindeutigen Maßstab) auf einer Karte

Hallo,

Ich habe JMP routinemäßig verwendet, um Daten auf Karten zu überlagern, eine Funktion, die ich liebe. Normalerweise standardisiere ich meine Daten so, dass sie alle auf derselben Skala liegen, stapele die Spalten, die ich darstellen möchte, und überlagere die gestapelten Daten im Graph Builder (als Konturdiagramme; siehe beigefügtes Bild für ein Beispiel). Ich möchte jetzt jedoch Daten von mehreren Parametern überlagern, OHNE sie zuerst zu standardisieren (damit sie ihre ursprünglichen Skalen beibehalten). Mir ist klar, dass ich einzelne Diagramme erstellen, kopieren und in Adobe Illustrator einfügen könnte, aber ich würde es vorziehen, Graph Builder zu verwenden und wenn möglich nach Parameternamen ("Label") umzubrechen. Gibt es eine Möglichkeit, Spalten zu stapeln, die NICHT denselben Maßstab haben, und dann ein kartenbasiertes Diagramm zu erstellen, in dem sie unterschiedliche y-Achsen aufweisen? Ich habe ein Datenblatt gepostet, in dem ich Temperatur, Salzgehalt und ALCC auf einer Karte darstellen möchte. Vielen Dank!

Re: Überlagern von Daten aus mehreren Parametern (jeweils mit einem eindeutigen Maßstab) auf einer Karte

Rahmengröße und Abstand können auch mit Jims Lösung geändert werden.Ich verwende gerne LineUpBox, weil ich nach dem Zeichnen des Fensters die Nachricht senden kann, ncol() zu ändern oder den Abstand zu ändern:

lub << ncol( 3 );
lub<< spacing( 20,6);

Re: Überlagern von Daten aus mehreren Parametern (jeweils mit einem eindeutigen Maßstab) auf einer Karte

Am besten finden Sie das heraus, indem Sie LineUp Box() im Scripting Index nachschlagen

Hilfe==>Scripting-Index

Re: Überlagern von Daten aus mehreren Parametern (jeweils mit einem eindeutigen Maßstab) auf einer Karte

Übrigens (für andere interessierte Personen), es scheint, dass es noch andere Möglichkeiten gibt: https://community.jmp.com/t5/Discussions/Graph-Builder-Wrap-With-different-Y-Axis-Scale/td-p/50307

Re: Überlagern von Daten aus mehreren Parametern (jeweils mit einem eindeutigen Maßstab) auf einer Karte

Danke für Ihre Antwort. Ist der Hauptunterschied in Ihrem Skript, dass die Rahmengröße und der Abstand geändert werden können? Was ist eine Aufstellungsbox?

Re: Überlagern von Daten aus mehreren Parametern (jeweils mit einem eindeutigen Maßstab) auf einer Karte

Dies ist nur eine einfache Ergänzung/Alternative zu Jims detailliertem Skript: Sie möchten vielleicht versuchen, eine LineUpBox zu verwenden.

nw = New Window( "xxx", V List Box(  lub = LineUpBox(ncol(2)) ) );

lub << append( Report( gb1 )[List Box( 2 )] );
lub << append( Report( gb2 )[List Box( 2 )] );
lub << append( Report( gb3 )[List Box( 2 )] );
lub << append( Report( gb4 )[List Box( 2 )] );
_fb = lub << xpath("//FrameBox"); //get all frameboxes
_fb << FrameSize(175,175);         //change the framebox size
lub << Spacing(20,10);             //set horizontal and vertical spacing between 

Re: Überlagern von Daten aus mehreren Parametern (jeweils mit einem eindeutigen Maßstab) auf einer Karte

Jim, ich habe völlig vergessen, dass das Kombinieren von Fenstern eine Option ist, und wusste nicht, wie einfach es ist, JSL-Skripte in ein gemeinsames Skriptfenster zu kopieren, also denke ich, dass dies funktionieren wird. Grundsätzlich versuche ich, Zahlen in Veröffentlichungsqualität zu erstellen, ohne Illustrator verwenden zu müssen, um verschiedene Grafiken, Plots usw. zusammenzuführen. Ich mag Ihr Skript, weil es nur die Zahlen zeigt, nicht mit all den verwirrenden Kästchen und Containern, die im Dashboard zu finden sind! Vielen Dank!

Re: Überlagern von Daten aus mehreren Parametern (jeweils mit einem eindeutigen Maßstab) auf einer Karte

Ist das die Art von Sache, die Sie suchen?

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

gb1 = Graph Builder(
 invisible,
 Size( 534, 454 ),
 Show Control Panel( 0 ),
 Variables( X( :PNP1 ), Y( :NPN1 ), Color( :NPN2 ) ),
 Elements( Contour( X, Y, Legend( 5 ) ) )
);
gb2 = Graph Builder(
 invisible,
 Size( 534, 454 ),
 Show Control Panel( 0 ),
 Variables( X( :NPN2 ), Y( :PNP3 ), Color( :PNP4 ) ),
 Elements( Contour( X, Y, Legend( 5 ) ) )
);
gb3 = Graph Builder(
 invisible,
 Size( 534, 454 ),
 Show Control Panel( 0 ),
 Variables( X( :PNP4 ), Y( :NPN4 ), Color( :INM2 ) ),
 Elements( Contour( X, Y, Legend( 5 ) ) )
);
gb4 = Graph Builder(
 invisible,
 Size( 534, 454 ),
 Show Control Panel( 0 ),
 Variables( X( :PBA1 ), Y( :WPR1 ), Color( :PLY10 ) ),
 Elements( Contour( X, Y, Legend( 5 ) ) )
);

nw = New Window( "xxx", V List Box( hlb1 = H List Box(), hlb2 = H List Box() ) );

hlb1 << append( Report( gb1 )[List Box( 2 )] );
hlb1 << append( Report( gb2 )[List Box( 2 )] );
hlb2 << append( Report( gb3 )[List Box( 2 )] );
hlb2 << append( Report( gb4 )[List Box( 2 )] );