48616_fr-FR

liliconcom

Contrôle de la sortie du rapport ANOVA via dispatch avec une variable chaîne

Bonjour,

J'essaie de faire référence à une variable de chaîne ( colname ) en expédition, mais il ne parvient pas à obay la OutlineBox, {Fermer (0)} (ou Fermer (1) ) par opposition à quand la chaîne est explicitement écrite.

J'apprécierais votre aide.

Revital

 

Voici le code:

For( i = 1, i <= N Items( ColumnNames ), i++,
colname = "Response " || char(colnameames[i]);
Cobj = dt << Fit Model(
Y( colnameames[i] ),
Effects( :Visit, :Group, :Group * :Visit ),
Random Effects( :SubjectNumber[:Group] ),
Personality( "Standard Least Squares" ),
Method( "REML" ),
Emphasis( "Minimal Report" ),
Run(
colnameames[i] << {Analysis of Variance( 0 ), Lack of Fit( 0 ),
Plot Actual by Predicted( 0 ), Plot Regression( 0 ),
Plot Residual by Predicted( 0 ), Plot Effect Leverage( 0 ), {:Visit <<
{LSMeans Plot( 1 ), LSMeans Contrast( [1 0 0 -1] )}, :Group << {LSMeans Plot( 1 ),
LSMeans Contrast( [1 0 0 -1] )}, :Group * :Visit << {LSMeans Plot( 1 )}}
),
SendToReport(
Dispatch(
{colname , "Effect Details", "Visit", "Contrast"},
"Test Detail",
OutlineBox,
{Close( 0 )}
),
Dispatch(
{colname , "Effect Details", "Group", "Contrast"},
"Test Detail",
OutlineBox,
{Close( 0 )}
),
Dispatch(
{colname , "Effect Details"},
"SubjectNumber[Group]",
OutlineBox,
{Close( 1 )}
)
)
);

Re: Contrôle de la sortie du rapport ANOVA via dispatch avec une variable chaîne

Merci beaucoup pour l'aide. J'ai utilisé la solution comme dans votre exemple et cela a fonctionné !!

Revtal 

 

Re: Contrôle de la sortie du rapport ANOVA via dispatch avec une variable chaîne

Vous devez créer la chaîne contenant le nom de la zone de contour avant d’évaluer le reste de l’expression.  Vous pouvez le faire de différentes manières en utilisant des chaînes, consultez Parse (Substitute ()) et Eval Insert (), car dans certains cas, ils pourraient constituer de meilleurs choix.  Une façon, cependant, consiste à utiliser Eval Expr () comme indiqué ci-dessous:

 

Essayez de remplacer Eval (par Write (Char) et regardez dans le journal pour voir quel code est évalué. Vous pouvez copier et coller du journal dans une fenêtre de script, puis utiliser le bouton "reformater le script".

 

Names default to here( 1 );

dt = Open( "$Sample_data/Iris.jmp" );

targets = {"Sepal length", "Petal length"};

For( i = 1, i <= N Items( targets ), i++,

 //Here is a Fit Model expression with some parts contained in Expr()
 //First the Fit model 'code' goes to Eval Expr() to evalute only those parts
 //contained in Expr().  Then it goes to Eval() to actually run the code.
 Eval( Eval Expr(
  Fit Model(
   Y( targets[i] ),
   Effects( :Sepal width, :Petal width ),
   Random Effects( :Species ),
   NoBounds( 1 ),
   Personality( "Standard Least Squares" ),
   Method( "REML" ),
   Emphasis( "Minimal Report" ),
   Run(
    :Sepal length << {Summary of Fit( 1 ), Analysis of Variance( 0 ),
    Parameter Estimates( 1 ), Lack of Fit( 0 ), Plot Actual by Predicted( 0 ),
    Plot Regression( 0 ), Plot Residual by Predicted( 0 ),
    Plot Studentized Residuals( 0 ), Plot Effect Leverage( 0 )}
   ),
   SendToReport(
    Dispatch(
     { Expr( "Response" ||  targets[i] ) }, //This is evaluated first
     "Parameter Estimates",
     OutlineBox,
     {Close( 1 )}
    ),
    Dispatch(
     { Expr( "Response" ||  targets[i] ) }, //This is evaluated first
     "REML Variance Component Estimates",
     OutlineBox,
     {Close( 1 )}
    ),
    Dispatch(
     { Expr( "Response" ||  targets[i] ) }, //This is evaluated first
     "Fixed Effect Tests",
     OutlineBox,
     {Close( 1 )}
    )
   )
  )
 ) );
);