46732_ja-JP

liliconcom

JMPスクリプトを使用して分析結果のグラフサイズを修正する

こんにちは

 

私は解析結果のフレームボックスのサイズを修正しようとしていました、例として次のコード：

 

dt = Open( "$SAMPLE_DATA/Flight Distances.jmp" );
dt << Multidimensional Scaling(
    Y(
        :Birmingham,
        :Boston,
        :Buffalo,
        :Chicago,
        :Cleveland,
        :Dallas,
        :Denver,
        :Detroit,
        :El Paso,
        :Houston,
        :Indianapolis,
        :Kansas City,
        :Los Angeles,
        :Louisville,
        :Memphis,
        :Miami,
        :Minneapolis,
        :New Orleans,
        :New York,
        :Omaha,
        :Philadelphia,
        :Phoenix,
        :Pittsburgh,
        :St. Louis,
        :Salt Lake City,
        :San Francisco,
        :Seattle,
        :Washington DC
    ),
    SendToReport(
        Dispatch(
            {"Multidimensional Scaling Plot"},
            "MDS Report Plot",
            FrameBox,
            {Frame Size( 750, 500 )}
        )
    )
);

 

フレームサイズ（750、500）が望ましい設定です。ただし、「左右反転」ボタンの「上下反転」ボタンをクリックした後はデフォルト設定になりました。

 

                                 ビフォアーアフター

 

フレームボックスを右クリックして手動でフレームサイズを設定する代わりに、JMPスクリプトを使用してフレームボックスのサイズを自動的に修正する方法はありますか？

 

 

 

再：JMPスクリプトを使用して分析結果のグラフサイズを修正

どうもありがとう、それこそまさに私が必要としていたものでした。

再：JMPスクリプトを使用して分析結果のグラフサイズを修正

1つの方法は、フレームサイズを設定し、JSLを使用してグラフを反転することです。  'mds << Show Tree Structure;'からのレポート'FrameBox（1）'の由来を示します。

mds = dt << Multidimensional Scaling( ... );
mds << Flip Horizontal( 1 );
(mds << Find( FrameBox(1) )) << Frame Size ( 750, 500 );

 

これをインタラクティブにするには、フリップボタンを自分のものに置き換えることができます。

Names default to here( 1 );

dt = Open( "$SAMPLE_DATA/Flight Distances.jmp" );
mds = dt << Multidimensional Scaling(
    Y(  :Birmingham, :Boston, :Buffalo, :Chicago, :Cleveland, 
  :Dallas, :Denver, :Detroit, :El Paso, :Houston, :Indianapolis, 
  :Kansas City, :Los Angeles, :Louisville, :Memphis, :Miami, 
  :Minneapolis, :New Orleans, :New York, :Omaha, :Philadelphia, 
  :Phoenix, :Pittsburgh, :St. Louis, :Salt Lake City, 
  :San Francisco, :Seattle, :Washington DC
    ),
    SendToReport(
  Dispatch(
   {"Multidimensional Scaling Plot"}, 
   "MDS Report Plot", 
   FrameBox, 
   {Frame Size( 750, 500 )} 
  )
 )
);

//Hide the default Flip buttons:
(mds << Find( Button Box(1) ) ) << visibility( "collapse" );
(mds << Find( Button Box(2) ) ) << visibility( "collapse" );

//Add new Flip buttons that set the frame size
(mds << Find( Listbox(3) )) << Append( Button Box( 
 "Flip Vertical New" , 
 mds << Flip Vertical( 1 );
 (mds << Find( FrameBox(1) )) << Frame Size ( 750, 500 )
));

(mds << Find( Listbox(3) )) << Append( Button Box( 
 "Flip Horizontal New" , 
 mds << Flip Horizontal( 1 );
 (mds << Find( FrameBox(1) )) << Frame Size ( 750, 500 )
));