46732_it-IT

liliconcom

Correggere la dimensione del grafico del risultato dell'analisi utilizzando lo script JMP

Ciao

 

Stavo cercando di correggere la dimensione del frame box nel risultato dell'analisi, il seguente codice come esempio:

 

dt = Open( "$SAMPLE_DATA/Flight Distances.jmp" );
dt << Multidimensional Scaling(
    Y(
        :Birmingham,
        :Boston,
        :Buffalo,
        :Chicago,
        :Cleveland,
        :Dallas,
        :Denver,
        :Detroit,
        :El Paso,
        :Houston,
        :Indianapolis,
        :Kansas City,
        :Los Angeles,
        :Louisville,
        :Memphis,
        :Miami,
        :Minneapolis,
        :New Orleans,
        :New York,
        :Omaha,
        :Philadelphia,
        :Phoenix,
        :Pittsburgh,
        :St. Louis,
        :Salt Lake City,
        :San Francisco,
        :Seattle,
        :Washington DC
    ),
    SendToReport(
        Dispatch(
            {"Multidimensional Scaling Plot"},
            "MDS Report Plot",
            FrameBox,
            {Frame Size( 750, 500 )}
        )
    )
);

 

La dimensione della cornice (750, 500) è l'impostazione desiderata. Tuttavia, è diventato l'impostazione predefinita dopo aver fatto clic sul pulsante "Capovolgi verticalmente" del pulsante "Capovolgi orizzontalmente".

 

                                 prima dopo

 

C'è un modo per correggere la dimensione della cornice in modo automatico usando lo scripting JMP invece di fare clic con il tasto destro del mouse sulla cornice e impostare manualmente la dimensione del frammento?

 

 

 

Ri: Fissare la dimensione del grafico del risultato dell'analisi usando lo scripting JMP

Grazie mille, era esattamente quello di cui avevo bisogno.

Ri: Fissare la dimensione del grafico del risultato dell'analisi usando lo scripting JMP

Un modo sarebbe quello di impostare la dimensione del frame e capovolgere il grafico usando JSL.  Il rapporto da 'mds << Mostra struttura ad albero;' mostra da dove proviene "FrameBox (1)".

mds = dt << Multidimensional Scaling( ... );
mds << Flip Horizontal( 1 );
(mds << Find( FrameBox(1) )) << Frame Size ( 750, 500 );

 

Per rendere questo interattivo è possibile sostituire i pulsanti flip con il proprio:

Names default to here( 1 );

dt = Open( "$SAMPLE_DATA/Flight Distances.jmp" );
mds = dt << Multidimensional Scaling(
    Y(  :Birmingham, :Boston, :Buffalo, :Chicago, :Cleveland, 
  :Dallas, :Denver, :Detroit, :El Paso, :Houston, :Indianapolis, 
  :Kansas City, :Los Angeles, :Louisville, :Memphis, :Miami, 
  :Minneapolis, :New Orleans, :New York, :Omaha, :Philadelphia, 
  :Phoenix, :Pittsburgh, :St. Louis, :Salt Lake City, 
  :San Francisco, :Seattle, :Washington DC
    ),
    SendToReport(
  Dispatch(
   {"Multidimensional Scaling Plot"}, 
   "MDS Report Plot", 
   FrameBox, 
   {Frame Size( 750, 500 )} 
  )
 )
);

//Hide the default Flip buttons:
(mds << Find( Button Box(1) ) ) << visibility( "collapse" );
(mds << Find( Button Box(2) ) ) << visibility( "collapse" );

//Add new Flip buttons that set the frame size
(mds << Find( Listbox(3) )) << Append( Button Box( 
 "Flip Vertical New" , 
 mds << Flip Vertical( 1 );
 (mds << Find( FrameBox(1) )) << Frame Size ( 750, 500 )
));

(mds << Find( Listbox(3) )) << Append( Button Box( 
 "Flip Horizontal New" , 
 mds << Flip Horizontal( 1 );
 (mds << Find( FrameBox(1) )) << Frame Size ( 750, 500 )
));