51436_it-IT

liliconcom

Come modificare il nome del gruppo dell'asse X nel grafico di variabilità utilizzando lo script

Ciao a tutti,

Ho tracciato un grafico di variabilità raggruppando alcune variabili usando lo script.

Si prega di trovare la trama allegata.

Non voglio stampare il nome della variabile di gruppo nell'asse x ma lo voglio nel nome del titolo della variabile.

Potresti per favore dare una soluzione per eliminare il nome della variabile X dall'asse X.

Grazie in anticipo.

Ri: Come modificare il nome del gruppo dell'asse X nel grafico di variabilità utilizzando lo script

Grazie mille.

Funziona bene.

Ri: Come modificare il nome del gruppo dell'asse X nel grafico di variabilità utilizzando lo script

Ecco 3 modi per modificare l'asse X del Gruppo 1

Names Default To Here( 1 );

// Setup some sample data to resemble the example provided
dt = Open( "$SAMPLE_DATA\Semiconductor Capability.jmp" );
dt:NPN1 << set name( "ISO_NW-N+" ) << set property( "Units", "A" );
dt << New Column( "Lot_Des", character, set each value( "ML7" ) );
dt << New Column( "DR", character, set each value( "S_0.40" ) );
dt << New Column( "Group 1", character, set each value( "ISO_NW-N+" ) );

// Sample 1, use the window name as the reference to delete the
// 2 components of the X axis that are not wanted
Variability Chart(
 Y( :Name( "ISO_NW-N+" ) ),
 X( :Group 1, :DR, :Lot_Des, :wafer ),
 Max Iter( 100 ),
 Conv Limit( 0.00000001 ),
 Number Integration Abscissas( 128 ),
 Number Function Evals( 65536 ),
 Analysis Type( "Choose best analysis (EMS REML Bayesian)" ),
 Std Dev Chart( 0 )
);
Window( "Semiconductor Capability - Variability Chart of ISO_NW-N+" )[Border Box( 5 )] << delete;
Window( "Semiconductor Capability - Variability Chart of ISO_NW-N+" )[NomAxisBox( 4 )] << delete;

// Sample 2, Set a Pointer/Handle variable reference to delete the
// 2 components of the X axis that are not wanted
VC = Variability Chart(
 Y( :Name( "ISO_NW-N+" ) ),
 X( :Group 1, :DR, :Lot_Des, :wafer ),
 Max Iter( 100 ),
 Conv Limit( 0.00000001 ),
 Number Integration Abscissas( 128 ),
 Number Function Evals( 65536 ),
 Analysis Type( "Choose best analysis (EMS REML Bayesian)" ),
 Std Dev Chart( 0 )
);
Report( VC )[Border Box( 5 )] << delete;
Report( VC )[NomAxisBox( 4 )] << delete;

// Sample 3, Since there is only 1 value for the Group 1 column,
// and the title of the chart will come from the Y Column, not
// the X Column, then just leave Group 1 out of the definition
// of the chart
Variability Chart(
 Y( :Name( "ISO_NW-N+" ) ),
 X( :DR, :Lot_Des, :wafer ),
 Max Iter( 100 ),
 Conv Limit( 0.00000001 ),
 Number Integration Abscissas( 128 ),
 Number Function Evals( 65536 ),
 Analysis Type( "Choose best analysis (EMS REML Bayesian)" ),
 Std Dev Chart( 0 )
);