51436_fr-FR

liliconcom

Comment modifier le nom du groupe de l'axe X dans le graphique de variabilité à l'aide d'un script

Bonjour à tous,

J'ai tracé un graphique de variabilité en regroupant certaines variables à l'aide d'un script.

Veuillez trouver le plan ci-joint.

Je ne veux pas imprimer le nom de la variable de groupe dans l'axe des x mais je le veux dans le nom du titre de la variable.

Pourriez-vous s'il vous plaît donner une solution pour supprimer le nom de la variable X de l'axe X.

Merci d'avance.

Re : Comment modifier le nom du groupe de l'axe X dans le graphique de variabilité à l'aide d'un script

Merci beaucoup.

Il fonctionne bien.

Re : Comment modifier le nom du groupe de l'axe X dans le graphique de variabilité à l'aide d'un script

Voici 3 façons de modifier l'axe X du groupe 1

Names Default To Here( 1 );

// Setup some sample data to resemble the example provided
dt = Open( "$SAMPLE_DATA\Semiconductor Capability.jmp" );
dt:NPN1 << set name( "ISO_NW-N+" ) << set property( "Units", "A" );
dt << New Column( "Lot_Des", character, set each value( "ML7" ) );
dt << New Column( "DR", character, set each value( "S_0.40" ) );
dt << New Column( "Group 1", character, set each value( "ISO_NW-N+" ) );

// Sample 1, use the window name as the reference to delete the
// 2 components of the X axis that are not wanted
Variability Chart(
 Y( :Name( "ISO_NW-N+" ) ),
 X( :Group 1, :DR, :Lot_Des, :wafer ),
 Max Iter( 100 ),
 Conv Limit( 0.00000001 ),
 Number Integration Abscissas( 128 ),
 Number Function Evals( 65536 ),
 Analysis Type( "Choose best analysis (EMS REML Bayesian)" ),
 Std Dev Chart( 0 )
);
Window( "Semiconductor Capability - Variability Chart of ISO_NW-N+" )[Border Box( 5 )] << delete;
Window( "Semiconductor Capability - Variability Chart of ISO_NW-N+" )[NomAxisBox( 4 )] << delete;

// Sample 2, Set a Pointer/Handle variable reference to delete the
// 2 components of the X axis that are not wanted
VC = Variability Chart(
 Y( :Name( "ISO_NW-N+" ) ),
 X( :Group 1, :DR, :Lot_Des, :wafer ),
 Max Iter( 100 ),
 Conv Limit( 0.00000001 ),
 Number Integration Abscissas( 128 ),
 Number Function Evals( 65536 ),
 Analysis Type( "Choose best analysis (EMS REML Bayesian)" ),
 Std Dev Chart( 0 )
);
Report( VC )[Border Box( 5 )] << delete;
Report( VC )[NomAxisBox( 4 )] << delete;

// Sample 3, Since there is only 1 value for the Group 1 column,
// and the title of the chart will come from the Y Column, not
// the X Column, then just leave Group 1 out of the definition
// of the chart
Variability Chart(
 Y( :Name( "ISO_NW-N+" ) ),
 X( :DR, :Lot_Des, :wafer ),
 Max Iter( 100 ),
 Conv Limit( 0.00000001 ),
 Number Integration Abscissas( 128 ),
 Number Function Evals( 65536 ),
 Analysis Type( "Choose best analysis (EMS REML Bayesian)" ),
 Std Dev Chart( 0 )
);