83689_es-ES

liliconcom

¿Cómo puedo mostrar la relación de cambio en el gráfico entre dos pruebas en un momento diferente?

Dibujé una gráfica que cambió con el tiempo. No puedo mostrar el rango muy conveniente, pero quiero mostrar la relación en el rango. Por ejemplo, el último valor cambió 10% con respecto al primer valor de prueba, quiero mostrarlo en el gráfico.

Re: ¿cómo puedo mostrar la relación de cambio en el gráfico entre dos pruebas en un momento diferente?

Podría usar 'columnas' temporales creadas desde la plataforma del generador de gráficos.  Para hacer esto de manera interactiva, haga clic derecho en el nombre de una columna y seleccione la fórmula (o Transformar, Fila, etc.) dentro de la sección 'Variables' de la plataforma del generador de gráficos.  Tenga en cuenta que este método para encontrar el primer valor puede ser lento con tablas de datos muy grandes.

 

dt = New Table( "Change in Response",
 Add Rows( 10 ),
 New Column( "Response",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 12, 3 ),
  Formula( Random Normal( 10, 1 ) ),
  Set Display Width( 71 )
 )
);

dt << Graph Builder(
 Size( 553, 416 ),
 Variables(
  X( Transform Column( "Row", Formula( Row() ) ) ),
  Y(
   Transform Column(
    "Difference",
    Format( "Fixed Dec", 12, 3 ),
    Formula( :Response / (:Response << Get Values)[1] - 1 )
   )
  ),
  Y( :Response )
 ),
 Elements( Position( 1, 1 ), Points( X, Y, Legend( 5 ) ) ),
 Elements( Position( 1, 2 ), Points( X, Y, Legend( 3 ) ) ),
 SendToReport(
  Dispatch(
   {},
   "Difference[Response]",
   ScaleBox,
   {Format( "Percent", 12, 1 )}
  )
 )
);

 

Re: ¿cómo puedo mostrar la relación de cambio en el gráfico entre dos pruebas en un momento diferente?

Esto se basa en la respuesta de Ian.  La secuencia de comandos utiliza una columna de transformación (). Esto se puede hacer con un clic y un clic haciendo clic con el botón derecho en el nombre de la columna: Respuesta y seleccione Fórmula .

 

Graph Builder(
 Size( 534, 467 ),
 Show Control Panel( 0 ),
 Show Legend( 0 ),
 Variables(
  X( Transform Column( "Row", Formula( Row() ) ) ),
  Y( Transform Column("Response", Formula((:Response-:Response[1])/:Response[1]) ) ),
  Y( :Response )
 ),
 Elements( Position( 1, 1 ), Bar( X, Y, Legend( 8 ) ) ),
 Elements( Position( 1, 2 ), Bar( X, Y, Legend( 9 ) ) )
)

Re: ¿cómo puedo mostrar la relación de cambio en el gráfico entre dos pruebas en un momento diferente?¿Puedo hacerlo sin nueva columna y la Fórmula?Re: ¿cómo puedo mostrar la relación de cambio en el gráfico entre dos pruebas en un momento diferente?

Si entiendo correctamente, intente ejecutar este script para hacer una tabla.

New Table( "Change in Response",
 Add Rows( 10 ),
 New Script(
  "Response & Change in Response",
  Graph Builder(
   Size( 534, 467 ),
   Show Control Panel( 0 ),
   Show Legend( 0 ),
   Variables(
    X( Transform Column( "Row", Formula( Row() ) ) ),
    Y( :Change in Response ),
    Y( :Response )
   ),
   Elements( Position( 1, 1 ), Bar( X, Y, Legend( 8 ) ) ),
   Elements( Position( 1, 2 ), Bar( X, Y, Legend( 9 ) ) )
  )
 ),
 New Column( "Response",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 12, 3 ),
  Formula( Random Normal( 10, 1 ) ),
  Set Display Width( 71 )
 ),
 New Column( "Change in Response",
  Numeric,
  "Continuous",
  Format( "Percent", 12, 0 ),
  Formula(
   Local( {firstResponse = Column( "Response" )[1]},
    (:Response - firstResponse) / firstResponse
   )
  ),
  Set Display Width( 117 )
 )
)

Si la secuencia de comandos guardada en la tabla le da lo que desea, eche un vistazo a la fórmula de la columna.