83689_ko-KR

liliconcom

어떻게 다른 시간에 두 가지 테스트 사이의 그래프에서 변화 비율을 보여줄 수 있습니까?

나는 시간이 지남에 따라 변화하는 그래프를 그렸습니다. 범위를 매우 편리하게 보여줄 수는 없지만 범위에 대한 비율을 보여주고 싶습니다. 예를 들어, 마지막 값이 첫 번째 테스트 값보다 10 % 변경된 경우 그래프에 표시하고 싶습니다.

어떻게 다른 시간에 두 테스트 사이의 그래프에서 변경 비율을 표시 할 수 있습니까?

그래프 빌더 플랫폼에서 생성 된 임시 '열'을 사용할 수 있습니다.  이 작업을 대화식으로 수행하려면 열 이름을 마우스 오른쪽 단추로 클릭하고 그래프 빌더 플랫폼의 '변수'섹션에서 수식 (또는 변환, 행 등)을 선택하십시오.  매우 큰 데이터 테이블에서는 첫 번째 값을 찾는이 방법이 느려질 수 있습니다.

 

dt = New Table( "Change in Response",
 Add Rows( 10 ),
 New Column( "Response",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 12, 3 ),
  Formula( Random Normal( 10, 1 ) ),
  Set Display Width( 71 )
 )
);

dt << Graph Builder(
 Size( 553, 416 ),
 Variables(
  X( Transform Column( "Row", Formula( Row() ) ) ),
  Y(
   Transform Column(
    "Difference",
    Format( "Fixed Dec", 12, 3 ),
    Formula( :Response / (:Response << Get Values)[1] - 1 )
   )
  ),
  Y( :Response )
 ),
 Elements( Position( 1, 1 ), Points( X, Y, Legend( 5 ) ) ),
 Elements( Position( 1, 2 ), Points( X, Y, Legend( 3 ) ) ),
 SendToReport(
  Dispatch(
   {},
   "Difference[Response]",
   ScaleBox,
   {Format( "Percent", 12, 1 )}
  )
 )
);

 

어떻게 다른 시간에 두 테스트 사이의 그래프에서 변경 비율을 표시 할 수 있습니까?

이것은 이안의 반응에 기초를두고 있습니다.  스크립트는 변환 열 ()을 사용합니다. 이 작업은 열 이름을 마우스 오른쪽 버튼으로 클릭하여 클릭하여 수행 할 수 있습니다. 응답 및 선택 공식 .

 

Graph Builder(
 Size( 534, 467 ),
 Show Control Panel( 0 ),
 Show Legend( 0 ),
 Variables(
  X( Transform Column( "Row", Formula( Row() ) ) ),
  Y( Transform Column("Response", Formula((:Response-:Response[1])/:Response[1]) ) ),
  Y( :Response )
 ),
 Elements( Position( 1, 1 ), Bar( X, Y, Legend( 8 ) ) ),
 Elements( Position( 1, 2 ), Bar( X, Y, Legend( 9 ) ) )
)

어떻게 다른 시간에 두 테스트 사이의 그래프에서 변경 비율을 표시 할 수 있습니까?새로운 칼럼과 수식없이 그것을 할 수 있습니까?어떻게 다른 시간에 두 테스트 사이의 그래프에서 변경 비율을 표시 할 수 있습니까?

올바르게 이해하면이 스크립트를 실행하여 테이블을 만들어보십시오.

New Table( "Change in Response",
 Add Rows( 10 ),
 New Script(
  "Response & Change in Response",
  Graph Builder(
   Size( 534, 467 ),
   Show Control Panel( 0 ),
   Show Legend( 0 ),
   Variables(
    X( Transform Column( "Row", Formula( Row() ) ) ),
    Y( :Change in Response ),
    Y( :Response )
   ),
   Elements( Position( 1, 1 ), Bar( X, Y, Legend( 8 ) ) ),
   Elements( Position( 1, 2 ), Bar( X, Y, Legend( 9 ) ) )
  )
 ),
 New Column( "Response",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 12, 3 ),
  Formula( Random Normal( 10, 1 ) ),
  Set Display Width( 71 )
 ),
 New Column( "Change in Response",
  Numeric,
  "Continuous",
  Format( "Percent", 12, 0 ),
  Formula(
   Local( {firstResponse = Column( "Response" )[1]},
    (:Response - firstResponse) / firstResponse
   )
  ),
  Set Display Width( 117 )
 )
)

테이블에 저장된 스크립트가 원하는 것을 제공하면 열 수식을 살펴보십시오.