83689_ja-JP

liliconcom

異なる時間に2つのテスト間の変化率をグラフで表示する方法

私は時間とともに変化するグラフを描きました。範囲を非常に便利に表示することはできませんが、範囲で比率を表示したいのですが。たとえば、最後の値が最初のテスト値よりも10％変化したので、グラフに表示します。

再：どうすれば異なる時間に2つのテスト間のグラフで変化率を示すことができますか？

グラフビルダープラットフォーム内から作成された一時的な「列」を使用できます。  これを対話的に行うには、列名を右クリックして、グラフビルダープラットフォームの[変数]セクションから式（または変換、行など）を選択します。  最初の値を見つけるためのこの方法は、非常に大きなデータテーブルでは遅くなることがあります。

 

dt = New Table( "Change in Response",
 Add Rows( 10 ),
 New Column( "Response",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 12, 3 ),
  Formula( Random Normal( 10, 1 ) ),
  Set Display Width( 71 )
 )
);

dt << Graph Builder(
 Size( 553, 416 ),
 Variables(
  X( Transform Column( "Row", Formula( Row() ) ) ),
  Y(
   Transform Column(
    "Difference",
    Format( "Fixed Dec", 12, 3 ),
    Formula( :Response / (:Response << Get Values)[1] - 1 )
   )
  ),
  Y( :Response )
 ),
 Elements( Position( 1, 1 ), Points( X, Y, Legend( 5 ) ) ),
 Elements( Position( 1, 2 ), Points( X, Y, Legend( 3 ) ) ),
 SendToReport(
  Dispatch(
   {},
   "Difference[Response]",
   ScaleBox,
   {Format( "Percent", 12, 1 )}
  )
 )
);

 

再：どうすれば異なる時間に2つのテスト間のグラフで変化率を示すことができますか？

これは、イアンの反応に基づいています。  スクリプトは変換列（）を使用します。これは、列名を右クリックしてポイントアンドクリックで実行できます。応答と選択式 。

 

Graph Builder(
 Size( 534, 467 ),
 Show Control Panel( 0 ),
 Show Legend( 0 ),
 Variables(
  X( Transform Column( "Row", Formula( Row() ) ) ),
  Y( Transform Column("Response", Formula((:Response-:Response[1])/:Response[1]) ) ),
  Y( :Response )
 ),
 Elements( Position( 1, 1 ), Bar( X, Y, Legend( 8 ) ) ),
 Elements( Position( 1, 2 ), Bar( X, Y, Legend( 9 ) ) )
)

再：どうすれば異なる時間に2つのテスト間のグラフで変化率を示すことができますか？新しい列と式がなくてもできますか。再：どうすれば異なる時間に2つのテスト間のグラフで変化率を示すことができますか？

正しく理解できたら、このスクリプトを実行して表を作成してみてください。

New Table( "Change in Response",
 Add Rows( 10 ),
 New Script(
  "Response & Change in Response",
  Graph Builder(
   Size( 534, 467 ),
   Show Control Panel( 0 ),
   Show Legend( 0 ),
   Variables(
    X( Transform Column( "Row", Formula( Row() ) ) ),
    Y( :Change in Response ),
    Y( :Response )
   ),
   Elements( Position( 1, 1 ), Bar( X, Y, Legend( 8 ) ) ),
   Elements( Position( 1, 2 ), Bar( X, Y, Legend( 9 ) ) )
  )
 ),
 New Column( "Response",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 12, 3 ),
  Formula( Random Normal( 10, 1 ) ),
  Set Display Width( 71 )
 ),
 New Column( "Change in Response",
  Numeric,
  "Continuous",
  Format( "Percent", 12, 0 ),
  Formula(
   Local( {firstResponse = Column( "Response" )[1]},
    (:Response - firstResponse) / firstResponse
   )
  ),
  Set Display Width( 117 )
 )
)

テーブルに保存されているスクリプトで必要なものが得られたら、列式を見てください。