83689_it-IT

liliconcom

come posso mostrare il rapporto di variazione nel grafico tra due test in tempi diversi?

Ho disegnato un grafico che è cambiato nel tempo. Non posso mostrare la gamma molto conveniente, ma voglio mostrare il rapporto sulla gamma. esempio, l'ultimo valore è cambiato del 10% rispetto al primo valore di test, voglio mostrare nel grafico.

Ri: come posso mostrare il rapporto di variazione nel grafico tra due test in tempi diversi?

È possibile utilizzare "colonne" temporanee create all'interno della piattaforma del generatore di grafici.  Per fare ciò in modo interattivo, fare clic con il pulsante destro del mouse sul nome di una colonna e selezionare la formula (o Trasforma, Riga, ecc.) Dalla sezione "Variabili" della piattaforma di creazione di grafici.  Si noti che questo metodo per trovare il primo valore può essere lento con tabelle di dati molto grandi.

 

dt = New Table( "Change in Response",
 Add Rows( 10 ),
 New Column( "Response",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 12, 3 ),
  Formula( Random Normal( 10, 1 ) ),
  Set Display Width( 71 )
 )
);

dt << Graph Builder(
 Size( 553, 416 ),
 Variables(
  X( Transform Column( "Row", Formula( Row() ) ) ),
  Y(
   Transform Column(
    "Difference",
    Format( "Fixed Dec", 12, 3 ),
    Formula( :Response / (:Response << Get Values)[1] - 1 )
   )
  ),
  Y( :Response )
 ),
 Elements( Position( 1, 1 ), Points( X, Y, Legend( 5 ) ) ),
 Elements( Position( 1, 2 ), Points( X, Y, Legend( 3 ) ) ),
 SendToReport(
  Dispatch(
   {},
   "Difference[Response]",
   ScaleBox,
   {Format( "Percent", 12, 1 )}
  )
 )
);

 

Ri: come posso mostrare il rapporto di variazione nel grafico tra due test in tempi diversi?

Questo si basa sulla risposta di Ian.  Lo script utilizza una colonna di trasformazione (). Questo può essere fatto tramite un clic facendo clic con il pulsante destro del mouse sul nome della colonna: Risposta e selezione Formula .

 

Graph Builder(
 Size( 534, 467 ),
 Show Control Panel( 0 ),
 Show Legend( 0 ),
 Variables(
  X( Transform Column( "Row", Formula( Row() ) ) ),
  Y( Transform Column("Response", Formula((:Response-:Response[1])/:Response[1]) ) ),
  Y( :Response )
 ),
 Elements( Position( 1, 1 ), Bar( X, Y, Legend( 8 ) ) ),
 Elements( Position( 1, 2 ), Bar( X, Y, Legend( 9 ) ) )
)

Ri: come posso mostrare il rapporto di variazione nel grafico tra due test in tempi diversi?Posso farlo senza nuova colonna e la Formula?Ri: come posso mostrare il rapporto di variazione nel grafico tra due test in tempi diversi?

Se ho capito bene, prova a eseguire questo script per creare una tabella.

New Table( "Change in Response",
 Add Rows( 10 ),
 New Script(
  "Response & Change in Response",
  Graph Builder(
   Size( 534, 467 ),
   Show Control Panel( 0 ),
   Show Legend( 0 ),
   Variables(
    X( Transform Column( "Row", Formula( Row() ) ) ),
    Y( :Change in Response ),
    Y( :Response )
   ),
   Elements( Position( 1, 1 ), Bar( X, Y, Legend( 8 ) ) ),
   Elements( Position( 1, 2 ), Bar( X, Y, Legend( 9 ) ) )
  )
 ),
 New Column( "Response",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 12, 3 ),
  Formula( Random Normal( 10, 1 ) ),
  Set Display Width( 71 )
 ),
 New Column( "Change in Response",
  Numeric,
  "Continuous",
  Format( "Percent", 12, 0 ),
  Formula(
   Local( {firstResponse = Column( "Response" )[1]},
    (:Response - firstResponse) / firstResponse
   )
  ),
  Set Display Width( 117 )
 )
)

Se lo script salvato nella tabella ti dà quello che vuoi, dai un'occhiata alla formula della colonna.