83689_fr-FR

liliconcom

Comment puis-je afficher le taux de variation sur un graphique entre deux tests à un moment différent?

J'ai dessiné un graphique qui a changé au fil du temps. Je ne peux pas montrer la gamme très pratique, mais je veux montrer le rapport sur la gamme. Par exemple, la dernière valeur a changé de 10% par rapport à la valeur du premier test, je veux montrer dans le graphique.

Re: comment puis-je afficher le taux de variation sur un graphique entre deux tests à un moment différent?

Vous pouvez utiliser des "colonnes" temporaires créées à partir de la plateforme du générateur de graphes.  Pour le faire de manière interactive, cliquez avec le bouton droit de la souris sur le nom d'une colonne et sélectionnez une formule (ou une transformation, une ligne, etc.) dans la section "Variables" de la plateforme de création de graphes.  Notez que cette méthode pour rechercher la première valeur peut être lente avec des tables de données très volumineuses.

 

dt = New Table( "Change in Response",
 Add Rows( 10 ),
 New Column( "Response",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 12, 3 ),
  Formula( Random Normal( 10, 1 ) ),
  Set Display Width( 71 )
 )
);

dt << Graph Builder(
 Size( 553, 416 ),
 Variables(
  X( Transform Column( "Row", Formula( Row() ) ) ),
  Y(
   Transform Column(
    "Difference",
    Format( "Fixed Dec", 12, 3 ),
    Formula( :Response / (:Response << Get Values)[1] - 1 )
   )
  ),
  Y( :Response )
 ),
 Elements( Position( 1, 1 ), Points( X, Y, Legend( 5 ) ) ),
 Elements( Position( 1, 2 ), Points( X, Y, Legend( 3 ) ) ),
 SendToReport(
  Dispatch(
   {},
   "Difference[Response]",
   ScaleBox,
   {Format( "Percent", 12, 1 )}
  )
 )
);

 

Re: comment puis-je afficher le taux de variation sur un graphique entre deux tests à un moment différent?

Ceci s'appuie sur la réponse de Ian.  Le script utilise une colonne de transformation (). Cela peut être fait par un clic droit en cliquant sur le nom de la colonne: Réponse et sélectionnez Formule .

 

Graph Builder(
 Size( 534, 467 ),
 Show Control Panel( 0 ),
 Show Legend( 0 ),
 Variables(
  X( Transform Column( "Row", Formula( Row() ) ) ),
  Y( Transform Column("Response", Formula((:Response-:Response[1])/:Response[1]) ) ),
  Y( :Response )
 ),
 Elements( Position( 1, 1 ), Bar( X, Y, Legend( 8 ) ) ),
 Elements( Position( 1, 2 ), Bar( X, Y, Legend( 9 ) ) )
)

Re: comment puis-je afficher le taux de variation sur un graphique entre deux tests à un moment différent?Puis-je le faire sans nouvelle colonne et la formule?Re: comment puis-je afficher le taux de variation sur un graphique entre deux tests à un moment différent?

Si je comprends bien, essayez d’exécuter ce script pour créer un tableau.

New Table( "Change in Response",
 Add Rows( 10 ),
 New Script(
  "Response & Change in Response",
  Graph Builder(
   Size( 534, 467 ),
   Show Control Panel( 0 ),
   Show Legend( 0 ),
   Variables(
    X( Transform Column( "Row", Formula( Row() ) ) ),
    Y( :Change in Response ),
    Y( :Response )
   ),
   Elements( Position( 1, 1 ), Bar( X, Y, Legend( 8 ) ) ),
   Elements( Position( 1, 2 ), Bar( X, Y, Legend( 9 ) ) )
  )
 ),
 New Column( "Response",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 12, 3 ),
  Formula( Random Normal( 10, 1 ) ),
  Set Display Width( 71 )
 ),
 New Column( "Change in Response",
  Numeric,
  "Continuous",
  Format( "Percent", 12, 0 ),
  Formula(
   Local( {firstResponse = Column( "Response" )[1]},
    (:Response - firstResponse) / firstResponse
   )
  ),
  Set Display Width( 117 )
 )
)

Si le script enregistré dans le tableau vous donne ce que vous voulez, jetez un coup d'œil à la formule de la colonne.