48771_es-ES

liliconcom

trazar la secuencia de tiempo forcast plot con el generador de gráficos (script)

 

Me pregunto si puedo mantener la gráfica de la serie de tiempo predicha en el generador de gráficos o no. Para que mi supervisor pueda leer la tendencia en el futuro y luego tomar el plan de inmediato. La trama que ya hice se ha agrupado x, por lo que debería mostrar varias líneas predichas en una sola trama.

 

El siguiente script es la trama predicha de la serie temporal:

Time Series(
 X( :date ),
 Y( :CD ),
 ARIMA( 0, 1, 0 ),
 SendToReport(
 
  Dispatch(
   {"Model: I(1)  ", "Forecast"},
   "Time Series Predicted Graph",
   FrameBox,
   {Frame Size( 659, 144 )}
  )
 )
);

 

Re: plotear la secuencia de tiempo forcast plot con el generador de gráficos (script)

Las predicciones de series de tiempo no parecen tan simples como otras plataformas.  Para resolver esto yo:

1. Guardó el script de series de tiempo de la plataforma, pero luego lo dividió en funciones separadas Series temporales () y Arima estacional ().
2. Predicciones guardadas en una nueva tabla
3. Copiado el script de nuevo a la tabla original
4. Hecho grafico

Names default to here( 1 );

//Open sample data
dt = Open( "$Sample_data/time series/co2.jmp" );

//Add rows to the original table
dt << Add rows( 12 );

//Calculate date for future rows
dt << New Column( "Year&Month Future",
 Numeric,
 "Continuous",
 Formula( 
  If( Is Missing( :Name( "Year&Month" ) ),
   Lag( :Name( "Year&Month Future" ), 1 ) + 1 / 24,
   :Name( "Year&Month" )
  )
 )
);

//Open time series
ts = dt << Time Series( Y( :CO2 ) );

//Add Arima
ar = ts << Seasonal Arima( 1, 1, 0, 0, 1, 1, 12 );

//Make a new table with predications
dtArima = ar << Save Prediction Formula;

//Graph with predictions in a separate data table
dtArima << Graph Builder(
 Size( 493, 303 ),
 Show Control Panel( 0 ),
 Variables( 
  X( :Row ), 
  Y( :Actual CO2 ), 
  Y( :Predicted CO2, Position( 1 ) ) ),
 Elements( 
  Points( X, Y( 1 ), 
  Legend( 19 ) ), 
  Line( X, Y( 2 ), 
  Legend( 20 ) ) )
);

//Or add predictions to original table:

//Copy the prediction formula and replace the column name, then save it to the original
//data table
Eval( Parse( 
 "dt << " || 
 Substitute( 
  Char((Column(dtArima, "CO2 Prediction Formula" ) << Get Script ) ), 
  ":Actual ", 
  ":" 
 ) 
) );

/*
//Close temporary windows
ts << Close Window
dtArima << Close Window;
*/

//Graph with predictions in the original table
dt << Graph Builder(
 Size( 493, 303 ),
 Show Control Panel( 0 ),
 Variables( 
  X( :Name("Year&Month Future") ), 
  Y( :CO2 ), 
  Y( :CO2 Prediction Formula, Position( 1 ) ) ),
 Elements( 
  Points( X, Y( 1 ), 
  Legend( 19 ) ), 
  Line( X, Y( 2 ), 
  Legend( 20 ) ) )
);