48771_it-IT

liliconcom

tracciamento della sequenza temporale per trama forcast con generatore grafico (script)

 

Mi sto chiedendo di poter mantenere la trama delle serie temporali previste nel grafico o meno. In modo che il mio supervisore possa sempre leggere la tendenza in futuro, quindi prendere immediatamente il piano. La trama che ho già creato ha raggruppato x, quindi dovrebbe mostrare diverse linee previste in un singolo grafico.

 

Lo script che segue è la trama prevista dalla serie temporale:

Time Series(
 X( :date ),
 Y( :CD ),
 ARIMA( 0, 1, 0 ),
 SendToReport(
 
  Dispatch(
   {"Model: I(1)  ", "Forecast"},
   "Time Series Predicted Graph",
   FrameBox,
   {Frame Size( 659, 144 )}
  )
 )
);

 

Ri: tracciare la sequenza temporale per la trama di forcast con il generatore di grafici (script)

Le previsioni di serie temporali non sembrano così semplici come le altre piattaforme.  Per risolvere questo io:

1. Ha salvato lo script delle serie temporali dalla piattaforma, ma poi lo ha diviso in funzioni separate di Time Series () e Arima () stagionale.
2. Previsioni previsionali in una nuova tabella
3. Copiato lo script di nuovo alla tabella originale
4. Grafico fatto

Names default to here( 1 );

//Open sample data
dt = Open( "$Sample_data/time series/co2.jmp" );

//Add rows to the original table
dt << Add rows( 12 );

//Calculate date for future rows
dt << New Column( "Year&Month Future",
 Numeric,
 "Continuous",
 Formula( 
  If( Is Missing( :Name( "Year&Month" ) ),
   Lag( :Name( "Year&Month Future" ), 1 ) + 1 / 24,
   :Name( "Year&Month" )
  )
 )
);

//Open time series
ts = dt << Time Series( Y( :CO2 ) );

//Add Arima
ar = ts << Seasonal Arima( 1, 1, 0, 0, 1, 1, 12 );

//Make a new table with predications
dtArima = ar << Save Prediction Formula;

//Graph with predictions in a separate data table
dtArima << Graph Builder(
 Size( 493, 303 ),
 Show Control Panel( 0 ),
 Variables( 
  X( :Row ), 
  Y( :Actual CO2 ), 
  Y( :Predicted CO2, Position( 1 ) ) ),
 Elements( 
  Points( X, Y( 1 ), 
  Legend( 19 ) ), 
  Line( X, Y( 2 ), 
  Legend( 20 ) ) )
);

//Or add predictions to original table:

//Copy the prediction formula and replace the column name, then save it to the original
//data table
Eval( Parse( 
 "dt << " || 
 Substitute( 
  Char((Column(dtArima, "CO2 Prediction Formula" ) << Get Script ) ), 
  ":Actual ", 
  ":" 
 ) 
) );

/*
//Close temporary windows
ts << Close Window
dtArima << Close Window;
*/

//Graph with predictions in the original table
dt << Graph Builder(
 Size( 493, 303 ),
 Show Control Panel( 0 ),
 Variables( 
  X( :Name("Year&Month Future") ), 
  Y( :CO2 ), 
  Y( :CO2 Prediction Formula, Position( 1 ) ) ),
 Elements( 
  Points( X, Y( 1 ), 
  Legend( 19 ) ), 
  Line( X, Y( 2 ), 
  Legend( 20 ) ) )
);