48771_fr-FR

liliconcom

tracer le tracé de la séquence temporelle avec le générateur de graphes (script)

 

Je me demande si je peux garder le tracé du tracé prédit dans le générateur de graphes ou non. Pour que mon superviseur puisse lire tous les jours la tendance à l’avenir, planifiez immédiatement. Le tracé que j'ai déjà créé a groupé x, il devrait donc afficher plusieurs lignes prédites dans un même tracé.

 

Le script suivant est le tracé prédit de la série chronologique:

Time Series(
 X( :date ),
 Y( :CD ),
 ARIMA( 0, 1, 0 ),
 SendToReport(
 
  Dispatch(
   {"Model: I(1)  ", "Forecast"},
   "Time Series Predicted Graph",
   FrameBox,
   {Frame Size( 659, 144 )}
  )
 )
);

 

Re: traçage du graphe de la séquence temporelle avec le générateur de graphes (script)

Les prévisions de séries chronologiques ne semblent pas aussi simples que d’autres plates-formes.  Pour résoudre ceci, je:

1. Enregistrement du script de série chronologique de la plate-forme, puis division de celui-ci en deux fonctions distinctes: Time Series () et Seasonal Arima ().
2. Sauvegarde des prévisions dans une nouvelle table
3. Copié le script dans la table d'origine
4. Graphique fait

Names default to here( 1 );

//Open sample data
dt = Open( "$Sample_data/time series/co2.jmp" );

//Add rows to the original table
dt << Add rows( 12 );

//Calculate date for future rows
dt << New Column( "Year&Month Future",
 Numeric,
 "Continuous",
 Formula( 
  If( Is Missing( :Name( "Year&Month" ) ),
   Lag( :Name( "Year&Month Future" ), 1 ) + 1 / 24,
   :Name( "Year&Month" )
  )
 )
);

//Open time series
ts = dt << Time Series( Y( :CO2 ) );

//Add Arima
ar = ts << Seasonal Arima( 1, 1, 0, 0, 1, 1, 12 );

//Make a new table with predications
dtArima = ar << Save Prediction Formula;

//Graph with predictions in a separate data table
dtArima << Graph Builder(
 Size( 493, 303 ),
 Show Control Panel( 0 ),
 Variables( 
  X( :Row ), 
  Y( :Actual CO2 ), 
  Y( :Predicted CO2, Position( 1 ) ) ),
 Elements( 
  Points( X, Y( 1 ), 
  Legend( 19 ) ), 
  Line( X, Y( 2 ), 
  Legend( 20 ) ) )
);

//Or add predictions to original table:

//Copy the prediction formula and replace the column name, then save it to the original
//data table
Eval( Parse( 
 "dt << " || 
 Substitute( 
  Char((Column(dtArima, "CO2 Prediction Formula" ) << Get Script ) ), 
  ":Actual ", 
  ":" 
 ) 
) );

/*
//Close temporary windows
ts << Close Window
dtArima << Close Window;
*/

//Graph with predictions in the original table
dt << Graph Builder(
 Size( 493, 303 ),
 Show Control Panel( 0 ),
 Variables( 
  X( :Name("Year&Month Future") ), 
  Y( :CO2 ), 
  Y( :CO2 Prediction Formula, Position( 1 ) ) ),
 Elements( 
  Points( X, Y( 1 ), 
  Legend( 19 ) ), 
  Line( X, Y( 2 ), 
  Legend( 20 ) ) )
);