48771_de-DE

liliconcom

Plotten Zeitablauf-Forcast-Plot mit Graph Builder (Skript)

 

Ich frage mich, ob ich die geplottete Zeitreihe im Diagrammgenerator beibehalten kann oder nicht. Damit mein Vorgesetzter in Zukunft regelmäßig den Trend ablesen kann, nehmen Sie sofort den Plan auf. Das Diagramm, das ich bereits erstellt habe, hat x gruppiert, es sollten also mehrere vorhergesagte Linien in einem Diagramm angezeigt werden.

 

Das fowllowing-Skript ist die geplante Zeitreihe:

Time Series(
 X( :date ),
 Y( :CD ),
 ARIMA( 0, 1, 0 ),
 SendToReport(
 
  Dispatch(
   {"Model: I(1)  ", "Forecast"},
   "Time Series Predicted Graph",
   FrameBox,
   {Frame Size( 659, 144 )}
  )
 )
);

 

Betreff: Plotten der Zeitsequenz-Prognose mit Graph Builder (Skript)

Zeitreihenvorhersagen erscheinen nicht so unkompliziert wie andere Plattformen.  Um das zu lösen, habe ich:

1. Das Zeitreihenskript wurde von der Plattform gespeichert und dann in separate Zeitreihenfunktionen () und saisonale Arima () - Funktionen aufgeteilt.
2. Vorhersagen in einer neuen Tabelle gespeichert
3. Kopieren Sie das Skript zurück in die ursprüngliche Tabelle
4. Graph gemacht

Names default to here( 1 );

//Open sample data
dt = Open( "$Sample_data/time series/co2.jmp" );

//Add rows to the original table
dt << Add rows( 12 );

//Calculate date for future rows
dt << New Column( "Year&Month Future",
 Numeric,
 "Continuous",
 Formula( 
  If( Is Missing( :Name( "Year&Month" ) ),
   Lag( :Name( "Year&Month Future" ), 1 ) + 1 / 24,
   :Name( "Year&Month" )
  )
 )
);

//Open time series
ts = dt << Time Series( Y( :CO2 ) );

//Add Arima
ar = ts << Seasonal Arima( 1, 1, 0, 0, 1, 1, 12 );

//Make a new table with predications
dtArima = ar << Save Prediction Formula;

//Graph with predictions in a separate data table
dtArima << Graph Builder(
 Size( 493, 303 ),
 Show Control Panel( 0 ),
 Variables( 
  X( :Row ), 
  Y( :Actual CO2 ), 
  Y( :Predicted CO2, Position( 1 ) ) ),
 Elements( 
  Points( X, Y( 1 ), 
  Legend( 19 ) ), 
  Line( X, Y( 2 ), 
  Legend( 20 ) ) )
);

//Or add predictions to original table:

//Copy the prediction formula and replace the column name, then save it to the original
//data table
Eval( Parse( 
 "dt << " || 
 Substitute( 
  Char((Column(dtArima, "CO2 Prediction Formula" ) << Get Script ) ), 
  ":Actual ", 
  ":" 
 ) 
) );

/*
//Close temporary windows
ts << Close Window
dtArima << Close Window;
*/

//Graph with predictions in the original table
dt << Graph Builder(
 Size( 493, 303 ),
 Show Control Panel( 0 ),
 Variables( 
  X( :Name("Year&Month Future") ), 
  Y( :CO2 ), 
  Y( :CO2 Prediction Formula, Position( 1 ) ) ),
 Elements( 
  Points( X, Y( 1 ), 
  Legend( 19 ) ), 
  Line( X, Y( 2 ), 
  Legend( 20 ) ) )
);