52455_it-IT

liliconcom

Aggiunta di punti dati specifici con etichette a un grafico di contorno

Ciao Comunità,

 

Sono relativamente nuovo a jmp e ho una domanda sulla trama del contorno.

 

Ho eseguito 20 esperimenti il cui design era composito centrale. Ho adattato un modello di superficie di risposta ai miei dati.

Ho quindi utilizzato il modello per generare previsioni sull'intero spazio deisgn. Ho quindi fatto un grafico di contorno delle previsioni.

C'è un modo per aggiungere i miei punti dati sperimentali, diciamo contrassegnati da una x, al grafico del contorno. C'è anche un modo per etichettare questi punti dati con il valore della variabile dipendente che ho trovato nei miei esperimenti?

In allegato c'è un'immagine che ho disegnato con la vernice per illustrare ciò che voglio fare. Non so come programmare, quindi una risposta con selezioni di menu e/o schermate sarebbe molto utile. Grazie mille

 

Oggetto: Aggiunta di punti dati specifici con etichette a un grafico di contorno

Grazie per la risposta. Non ero in grado di capire lo scripting. Ma ho trovato un modo per farlo. Ho creato i miei grafici di contorno con il grafico di contorno dal menu del grafico. Ho anche creato grafici a dispersione delle mie variabili indipendenti. Ho copiato il contenuto del fotogramma dal grafico a dispersione nei grafici contorti. Quindi ho etichettato manualmente i punti con annotazioni di testo.

Oggetto: Aggiunta di punti dati specifici con etichette a un grafico di contorno

Ciao @Alessandro S ,

Benvenuto nella comunità! Questo è un po' stupido per un nuovo utente JMP perché dovremo fare un sacco di script JMP, ma eccoci qui:

Presumo che tu stia visualizzando il profiler del contorno in Fit Model e non in un profiler personalizzato separato.In ogni caso, si applicano gli stessi passaggi generali.Sto utilizzando il set di dati di esempio RSM personalizzato dalla libreria di dati di esempio.

Inizia aprendo un nuovo script e crea un riferimento variabile alla tua tabella di dati.Ecco, sto solo aprendo la tabella RSM personalizzata.

dt = Open("$Sample_Data\Design Experiment\Custom RSM.jmp");

Devi ottenere lo script per il report che contiene il tuo profiler.Se proviene da Fit Model, lo script sarà simile a Fit Model(Y(:Y), Effects(...),...); Dobbiamo ottenere un riferimento alla finestra del report in modo da poter personalizzare i contenuti del profiler.Ecco come l'ho fatto con l'esempio RSM personalizzato:

rpt = (
 dt << Fit Model(
  Y( :Y ),
  Effects(
   :X1 & RS,
   :X2 & RS,
   :X3 & RS,
   :X1 * :X1,
   :X1 * :X2,
   :X2 * :X2,
   :X1 * :X3,
   :X2 * :X3,
   :X3 * :X3
  ),
  Personality( "Standard Least Squares" ),
  Emphasis( "Effect Screening" ),
  Run(
   Contour Profiler(
    1,
    Term Value(
     X1( 0, Lock( 0 ), Show( 1 ) ),
     X2( 0, Lock( 0 ), Show( 1 ) ),
     X3( 0, Lock( 0 ), Show( 1 ) )
    ),
    Contour Value( Y( 62.703, Min( 52.5 ), Max( 75 ) ) ),
    Grid Density( "40 x 40" ),
    Contour Grid( 50, 80, 5, Y ),
    Horizontal Factor( :X1 ),
    Vertical Factor( :X2 ),
    Y Colors( 21 ),
    Up Dots( 0 )
   ),
   :Y << {Summary of Fit( 1 ), Analysis of Variance( 1 ),
   Parameter Estimates( 1 ), Effect Details( 0 ), Sorted Estimates( 0 ),
   Scaled Estimates( 0 ), Plot Actual by Predicted( 1 ), Plot Regression( 0 ),
   Plot Residual by Predicted( 1 ), Plot Residual by Row( 1 ),
   Plot Studentized Residuals( 0 ), Plot Effect Leverage( 0 ),
   Box Cox Y Transformation( 1 ), Show VIF( 1 )}
  )
 )
) << Report;

Si noti che ho preceduto lo script Fit Model con "rpt = (dt <<" e poi ho inserito questo nel back-end: ") << Report;".La variabile "rpt" ora contiene un riferimento alla finestra del report per Stima modello.

Successivamente, abbiamo bisogno di ottenere i valori delle variabili che stai tracciando nel Contour Profiler.Nel mio esempio, le 2 variabili sono x1 e x2.Ho anche bisogno dei valori Y per le mie etichette dei punti.

 

//plotted points
x1_vals = :x1 << Get Values;
x2_vals = :x2 << Get Values;

//values used in labels
y_vals = :y << Get Values;

Ora posso aggiungere uno script grafico per tracciare i punti e il testo all'interno del profiler in questo modo:

rpt["Contour Profiler"][FrameBox(1)] << Add Graphics Script(
 Marker(x1_vals, x2_vals);
 for(i=1,i<=N Row(dt),i++,
  text(eval list({x1_vals[i],x2_vals[i]+0.05}),char(y_vals[i]));
 )
);

 

Le cose tra parentesi mi aiutano a navigare lungo l'albero del display per arrivare al framebox che contiene la trama.Uso Marker() per aggiungere i punti.Uso il ciclo per aggiungere le etichette.

Il risultato finale è simile a questo:

 

 

Si noti che ho alcuni punti ed etichette tracciati uno sopra l'altro perché ho un terzo fattore, X3.Potremmo personalizzarlo ulteriormente per evitare che le etichette siano una sopra l'altra, ma probabilmente vorrai anche aggiungere il valore per x3 a tutte queste etichette.Fondamentalmente, questa soluzione non scala molto bene per più di 2 fattori, ma se ne hai solo 2, dovrebbe funzionare molto bene.