108602_fr-FR

liliconcom

Problème de manipulation des tableaux tabulés

Je ne comprends pas très bien pourquoi j'ai des problèmes pour manipuler les colonnes d'un tableau créé à partir d'un rapport tabulé. J'ai joint les tableaux et les scripts pour vos références. J'essaie de créer un tableau qui correspond à notre tableau de rapport actuel.

 

Toujours, merci pour votre aide

 

 

Names Default To Here(1);

dt = Current Data Table();

LotListSQLString = "Wafer_1";

 tab = dt  
  << Tabulate(
  invisible,
   Show Control Panel( 0 ),
   Add Table(
    Column Table( 
     Category Table, 
     Statistics(
      N,
      Name( "% of Total" ) 
     ) 
    ),
    
    Row Table( 
     Columns by Categories( 
      :Name( "test" ),
      :Name( "[Rx] test1" ),
      :Name( "[Rx] test2" ),
      :Name( "[Rx] test3" ),
      :Name( "[Tx] test1" ),
      :Name( "[Tx] test2" ),
      :Name( "[Tx] test3" ),
      :Name( "test4" ),
      :Name( "Composite" ) 
      ) 
     )
   )
  );
  
 dtFinal = tab << Make Into Data Table;
 
 Wait( 1 );
 
 dtFinal << set name( " Yield Report" );
 
 dtFinal = New Column( "Mode",
  << Formula( 
   If( (:Columns by Categories == "test" ), "-",
    IF( :Columns by Categories == "[Rx] test1", "Rx", 
     IF( :Columns by Categories == "[Rx] test2", "Rx",
      IF( :Columns by Categories == "[Rx] test3", "Rx",
       IF( :Columns by Categories == "[Tx] test1", "Tx", 
        IF( :Columns by Categories == "[Tx] test2", "Tx",
         IF( :Columns by Categories == "[Tx] test3", "Tx",
          If( :Columns by Categories == "test4", "-"
          )
         )
        )
       )
      )
     )
    )
   )
  )
 );
 
 Wait( 0 );
 
 dtFinal = New Column( "TestName",
  << Formula( 
   If( (:Columns by Categories == "test" ), "test",
    IF( :Columns by Categories == "[Rx] test1", "test1", 
     IF( :Columns by Categories == "[Rx] test2", "test2",
      IF( :Columns by Categories == "[Rx] test3", "test3",
       IF( :Columns by Categories == "[Tx] test1", "test1", 
        IF( :Columns by Categories == "[Tx] test2", "test2",
         IF( :Columns by Categories == "[Tx] test3", "test3",
          If( :Columns by Categories == "test4", "test4"
          )
         )
        )
       )
      )
     )
    )
   )
  )
 );
 
// ------------------------ BEGIN FORMATING TABLE FOR FINAL REPORTING

// Says Scriptable[] but won't delete
 
 dtFinal << Delete Columns( {"N(Fail)", "% of Total(Fail)"} );

// Works Correctly

 dtFinal = New Column( "wafer_number",
  << Formula(
   LotListSQLString
  )
 );

// Says Scriptable[] but won't go to column and obviously doesn't move

 dtFinal << Go To( "wafer_number" );
 Wait ( 0.5 );
 dtFinal << move selected Columns( To First );
 dtFinal << clear Column selection;

// Works Correctly
 
 dtFinal = Column( "Mode" ) << Delete Formula;
 dtFinal = Column( "TestName" ) << Delete Formula;
 
// Says Scriptable[] but won't go to column and obviously doesn't move
 
 dtFinal << Go To( :Mode );
 Wait ( 1 );
 dtFinal << move selected Columns( after( "wafer_number" ) );
 dtFinal << Clear Column Selection;
 
// Says Scriptable[] but won't go to delete

 dtFinal << Delete Columns( :Columns by Categories);

// Says Scriptable[] but won't go to delete
 
 dtFinal << go to( :TestName );
 Wait( 1 );
 dtFinal << Move Selected Column( after( "name" ) );
 dtFinal << clear Column selection;

// Works Correctly
 
 lot = "XYZ";
 
 part = New Column( "part_number" );
 part << Set Formula( lot );

// Says Scriptable[] but won't go to column and obviously doesn't move
 
 dtFinal << go to( :part_number );
 Wait ( 1 );
 dtFinal << Move Selected Column( after( "name" ) );
 dtFinal << clear Column selection;

// Works Correctly
 
 die = 334;
 
 numdie = New Column( "NumDie" );
 numdie << Set Formula( die ); 

// Says Scriptable[] but won't go to column and obviously doesn't move
 
 dtFinal<< go to( :NumDie );
 Wait ( 1 );
 dtFinalYield<< move selected Columns( after( "part_number" ) );
 dtFinalYield<< clear Column selection;
 
 

 

Re : Problème de manipulation des tableaux tabulésLe simple fait d'obtenir la syntaxe me tue.. Merci d'avoir fait remarquer cela.. Comme j'apprends encore à coder en JSL, j'ai très certainement ces deux formus, le guide de script et l'index de script tous ouverts pour rechercher comment faire les choses. J'ai raté ça = à << ..Re : Problème de manipulation des tableaux tabulésLe dtFinalYield est censé être juste dtFinal.. Quand je joins des scripts à ce forum, je dois tout renommer et j'ai raté celui-là.. Mes excuses.

Je vois les problèmes avec le signe '=' au lieu du '<<' Je ne sais pas pourquoi je faisais ça..Re : Problème de manipulation des tableaux tabulés

Vous trouverez ci-dessous mon examen de votre script ...... les problèmes semblent ne pas comprendre la différence entre quand utiliser "=" et quand utiliser "<<", et vous semblez également être plus prudent, ce qui concerne parfois à ne pas comprendre totalement JSL.Je vous suggère donc fortement de lire le Guide de Scripting !

Aide==>Livres==>Guide de script

Voici mon script annoté

Names Default To Here(1);

dt = Current Data Table();

LotListSQLString = "Wafer_1";

 tab = dt  
  << Tabulate(
  invisible,
   Show Control Panel( 0 ),
   Add Table(
    Column Table( 
     Category Table, 
     Statistics(
      N,
      Name( "% of Total" ) 
     ) 
    ),
    
    Row Table( 
     Columns by Categories( 
      :Name( "test" ),
      :Name( "[Rx] test1" ),
      :Name( "[Rx] test2" ),
      :Name( "[Rx] test3" ),
      :Name( "[Tx] test1" ),
      :Name( "[Tx] test2" ),
      :Name( "[Tx] test3" ),
      :Name( "test4" ),
      :Name( "Composite" ) 
      ) 
     )
   )
  );
  
 dtFinal = tab << Make Into Data Table;
 
 Wait( 1 );
 
 dtFinal << set name( " Yield Report" );
 
 // changed from 
 // dtFinal = New Column( "Mode", 
 // to
 dtFinal << New Column( "Mode", character,
  // More efficient way to code the If()
  Formula(
   If(
    :Columns by Categories == "test", "-",
    :Columns by Categories == "[Rx] test1", "Rx",
    :Columns by Categories == "[Rx] test2", "Rx",
    :Columns by Categories == "[Rx] test3", "Rx",
    :Columns by Categories == "[Tx] test1", "Tx",
    :Columns by Categories == "[Tx] test2", "Tx",
    :Columns by Categories == "[Tx] test3", "Tx",
    :Columns by Categories == "test4", "-"
   )
  )
 );
 
 Wait( 0 );
 // changed from 
 // dtFinal = New Column( "TestName", 
 // to
 dtFinal << New Column( "TestName", character,
  // More efficient way to code the If()
  Formula(
   If(
    :Columns by Categories == "test", "test",
    :Columns by Categories == "[Rx] test1", "test1",
    :Columns by Categories == "[Rx] test2", "test2",
    :Columns by Categories == "[Rx] test3", "test3",
    :Columns by Categories == "[Tx] test1", "test1",
    :Columns by Categories == "[Tx] test2", "test2",
    :Columns by Categories == "[Tx] test3", "test3",
    If( :Columns by Categories == "test4",
     "test4"
    )
   )
  )
 );
 
// ------------------------ BEGIN FORMATING TABLE FOR FINAL REPORTING

// Says Scriptable[] but won't delete
// You had not used the proper syntax in the above step, so that dtFinal 
// was changed from a data table pointer to pointer to column "TestName"
 
 dtFinal << Delete Columns( {"N(Fail)", "% of Total(Fail)"} );

// Works Correctly
 // changed from 
 // dtFinal = New Column( "wafer_number",
 // to
 dtFinal << New Column( "wafer_number", character,
  << Formula(
   LotListSQLString
  )
 );

// Says Scriptable[] but won't go to column and obviously doesn't move

 dtFinal << Go To( "wafer_number" );
 Wait ( 0.5 );
 dtFinal << move selected Columns( To First );
 dtFinal << clear Column selection;

// Works Correctly
 // Changed from
 // dtFinal = Column( "Mode" ) << Delete Formula;
 // to
 dtFinal:Mode << Delete Formula;
 // Changed from
 // dtFinal = Column( "TestName" ) << Delete Formula;
 // to
 dtFinal:TestName << Delete Formula;
 
// Says Scriptable[] but won't go to column and obviously doesn't move

 // With keeping dtFinal as a pointer to the data table this now works 
 dtFinal << Go To( :Mode );
 // Wait ( 1 ); // not necessary wait
 dtFinal << move selected Columns( after( "wafer_number" ) );
 dtFinal << Clear Column Selection;
 
// Says Scriptable[] but won't go to delete
 
 // With keeping dtFinal as a pointer to the data table this now works
 dtFinal << Delete Columns( :Columns by Categories);

// Says Scriptable[] but won't go to delete
 
 dtFinal << go to( :TestName );
 //Wait( 1 );
 // changed from
 // dtFinal << Move Selected Column( after( "name" ) );
 // to
 dtFinal << Move Selected Column( after( :name("N(Pass)" ) ) );
 dtFinal << clear Column selection;

// Works Correctly
 
 // This form will not work, once you save the table and reopen it
 // because the formula requires a variable named Lot
 //lot = "XYZ";
 
 //part = New Column( "part_number" );
 //part << Set Formula( lot );
 // here is a form that will work
 dtFinal << New Column( "part_number", character, set each value("XYZ" ) );

// Says Scriptable[] but won't go to column and obviously doesn't move
 
 dtFinal << go to( :part_number );
 //Wait ( 1 );
 // There is not a column named "name", therefore 
 // changed
 // dtFinal << Move Selected Column( after( "name" ) );
 // to
 dtFinal << Move Selected Column( after( :name("N(Pass)" ) ) );
 dtFinal << clear Column selection;

// Works Correctly
 
 // This form will not work, once you save the table and reopen it
 // because the formula requires a variable named die
 //die = 334;
 
 //numdie = New Column( "NumDie" );
 //numdie << Set Formula( die );
 dtFinal << New Column( "NumDie", set each value(334) ); 

// Says Scriptable[] but won't go to column and obviously doesn't move
 
 dtFinal<< go to( :NumDie );
 //Wait ( 1 );
 // There is no pointer called dtFinalYield
 // changed from
 // dtFinalYield<< move selected Columns( after( "part_number" ) );
 // dtFinalYield<< clear Column selection;
 // to
 dtFinal << move selected Columns( after( "part_number" ) );
 dtFinal << clear Column selection;
 
 

Re : Problème de manipulation des tableaux tabulés

Une syntaxe incorrecte a créé plusieurs collisions de noms :

dtFinal = tab << Make Into Data Table;
 
 Wait( 1 );
 
 dtFinal << set name( " Yield Report" );
 
 dtFinal = New Column( "Mode",

Comme écrit, votre script s'attend à ce que dtFinal soit la référence de la table, mais la syntaxe dtFinal = New Column() affecte la nouvelle colonne à la référence dtFinal.La syntaxe doit être dtFinal << New Column( ) aussi à la fin de votre script vous vous référez à dtFinalyield, il n'y a pas une telle table.

 

Vous devez également rechercher la syntaxe des fonctions JMP If(). Vous n'avez pas besoin d'imbriquer les ifs :

Si (cond1, result1, cond2, result2, ...condk, result k, else);

Re : Problème de manipulation des tableaux tabulés

j'exécute votre script avec vos données sans problème....

créé un rapport tabulé et un tableau associé.... et il est également possible de modifier ce tableau....

 

pouvez-vous mieux expliquer quel genre de problème vous avez

 

ciao

Gianpaolo