<meta http-equiv="Content-Type" content="text/html; charset=UTF-8" />Hallo zusammen,
Ich komme oft mit dieser Frage zusammen;
Einen Formeltyp auf viele neu generierte Spalten anwenden. Könnte jemand bitte die Hauptlogik dahinter erklären?
Zum Beispiel:
1 Ich habe einen Datensatz von 72 Jahren mit 12 Monaten. Ich möchte eines aus dem Jahr / Monat als das Beste definieren und es als = 100 akzeptieren und ich möchte alle anderen in Prozent mit diesem Jahr / Monat vergleichen (insbesondere Umsatzsteigerung oder -abnahme).
2 Ich habe 1 Spalte als MainColumn mit 100 anderen Spalten (1,2,3,4,5, ...) in einer Datentabelle zu denken, und mit dem Hinzufügen von 100 neuen Spalten möchte ich dieselbe Formel für jede verwenden: NewColumn1 = Column1 / MainColumn, NewColumn2 = Column2 / MainColumn ... etc ...
3. Ich habe Spalten in gepaarten Relationen (Spalte1, Spalte2, Spalte3, Spalte4) und möchte eine neue Spalte (ColumnNew1) mit einer Formel erstellen, die mit gepaarten Spalten (= Spalte1 + Spalte2), (Spalte3 + Spalte3 + Spalte4) ... zusammenhängt .
Wie mache ich das?
Danke vielmals
Ich nehme an, Sie suchen nach einer Skriptlösung. Nachfolgend einige Ideen.
//Example tables
dt1 = New Table("example 1",
add rows(12 * 72),
New Column("year", numeric, Formula(Sequence(1944, 2015, 1, 12))),
New Column("month", numeric, values(Repeat(1 :: 12, 72))),
New Column("revenue", numeric, Formula(Random Integer(10000)))
);
dt2 = New Table("example 2", add rows(5), New Column("main column", numeric, values(1 :: 5)));
dt2 << add multiple columns("column", 10, after last, numeric);
For(i = 2, i <= 11, i++,
Column(dt2, i) << set formula(Random Integer(10))
);
// 1)
dt1 << New Column("revenue, % of year's best month", numeric, Format("percent"), Formula(:revenue / Col Max(:revenue, year)));
// 2) and 3) The trick is to use Eval Expr() and Name Expr() when defining formulas.
cols = dt2 << get column names;
// add formulas for 2
For(i = 2, i <= 11, i++,
colname = Char(cols[i]) || " by main";
f = Eval Expr(Expr(cols[i]) / :main column);
dt2 << New Column(colname, numeric, formula(Name Expr(f)));
);
// dito for 3
For(i = 2, i <= 6, i = i + 2,
colname = Char(cols[i]) || "+" || Char(cols[i + 1]);
f = Eval Expr(Expr(cols[i]) + Expr(cols[i + 1]));
dt2 << New Column(colname, numeric, formula(Name Expr(f)));
);