43974_it-IT

liliconcom

Come posso ridimensionare automaticamente l'asse da piattaforme diverse con un singolo filtro locale su una pagina combinata

CIAO,

Sto appena iniziando a lavorare con dashboard e filtri locali, ma ho qualche difficoltà. Sto cercando di generare un riepilogo di una singola pagina di un'analisi di routine per me. Posso creare la finestra con gli elementi che desidero e il filtro funziona sulle varie piattaforme (grafici 2xOneway e 1xBivariate) in termini di dati visualizzati in ciascun grafico, tuttavia l'asse sul grafico 2xOneway viene ridimensionato con le modifiche al grafico locale filter, ma Bivariate no - c'è un modo per fare in modo che anche il grafico Bivariate venga ridimensionato quando cambio la selezione del filtro locale?  

 

Ecco la mia sezione di codice per creare la finestra combinata (non sono un programmatore quindi potrebbe non essere carino!)

 

nw = new window( "DASHBORAD DEVELOPMENT",
 Data Filter Context Box(
  V List Box(
   H List Box(
    Current Data Table() << Data Filter(
     Conditional,
     Local,
     Add Filter(
      columns( :PRODUCTION_LINE, :PRESS_ID, :AREA_ID, :METROLOGY_FLAG, :Desport_Flag),
      Display( :AREA_ID, Size( 160, 75 ), List Display ),
      Display( :PRESS_ID, Size( 143, 30 ), List Display )
     )
    ),
    Oneway(
     Y( :HEIGHT),
     X( :MACH ),
     Automatic Recalc( 1 ),
     Means( 1 ),
     Mean Diamonds( 1 ),
     SendToReport(
      Dispatch( {}, "Oneway Anova", OutlineBox, {Close( 1 )} )
     )
    ),
    Oneway(
     Y( :HEIGHT),
     X( :OPERATOR),
     Automatic Recalc( 1 ),
     Means( 1 ),
     Mean Diamonds( 1 ),
     SendToReport(
      Dispatch( {}, "Oneway Anova", OutlineBox, {Close( 1 )} )
     )
    )
   ),
   Bivariate(
    Y( :HEIGHT ),
    X( :PRODUCTION_DATE),
    Automatic Recalc( 1 ),
    SendToReport(
     Dispatch(
      {},
      "Bivar Plot",
      FrameBox,
      {Frame Size( 1018, 240 )
      }
     )
    )
   )
  )
 )
);

Mi scuso in anticipo se questo è qualcosa di molto semplice che mi manca!

Niall

Ri: Come posso ridimensionare automaticamente l'asse da diverse piattaforme con un singolo filtro locale su una pagina combinataBrillante Jim, molto apprezzato!Ri: Come posso ridimensionare automaticamente l'asse da diverse piattaforme con un singolo filtro locale su una pagina combinata

Ecco una modifica allo script che ti ho inviato con un'aggiunta senza senso aggiunta allo script di aggiunta grafica. Non ha senso, ma funziona

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA\Big Class.jmp" );

nw = New Window( "DASHBORAD DEVELOPMENT",
 originHold = 0;
 originRange = 0;
 Data Filter Context Box(
  V List Box(
   H List Box(
    Current Data Table() << Data Filter( Conditional, Local, Add Filter( columns( :Age, :Weight ) ) ),
    ow1 = dt << Oneway(
     Y( :HEIGHT ),
     X( :Sex ),
     Automatic Recalc( 1 ),
     Means( 1 ),
     Mean Diamonds( 1 ),
     SendToReport( Dispatch( {}, "Oneway Anova", OutlineBox, {Close( 1 )} ) )
    ),
    ow2 = dt << Oneway(
     Y( :HEIGHT ),
     X( :Age ),
     Automatic Recalc( 1 ),
     Means( 1 ),
     Mean Diamonds( 1 ),
     SendToReport( Dispatch( {}, "Oneway Anova", OutlineBox, {Close( 1 )} ) )
    )
   ),
   biv = dt << Bivariate(
    Y( :HEIGHT ),
    X( :Weight ),
    Automatic Recalc( 1 ),
    SendToReport( Dispatch( {}, "Bivar Plot", FrameBox, {Frame Size( 1018, 240 )} ) )
   )
  )
 );
);
Report( ow1 )[Frame Box( 1 )] << Add Graphics Script(
 If( originHold != Y Origin() | rangeHold != Y Range(),
  originHold = Y Origin();
  rangeHold = Y Range();
  Report( ow1 )[Axis Box( 1 )] << Copy Axis Settings;
  Try( Report( biv )[Axis Box( 1 )] << Paste Axis Settings );
  Report( biv )[Outline Box( 1 )] << append( text box("Changed " || char(originHold)))
 );
 
);

Ri: Come posso ridimensionare automaticamente l'asse da diverse piattaforme con un singolo filtro locale su una pagina combinataJim,
Innanzitutto grazie per la risposta, è molto apprezzata! Questo funziona
perfettamente per il caso di cui ho chiesto informazioni.

È possibile utilizzare lo stesso tipo di approccio (Aggiungi script grafico) quando
usando append() per aggiungere una sezione a una finestra aperta esistente? ci ho provato
includerlo nella funzione append ma mi restituisce un errore?
Ri: Come posso ridimensionare automaticamente l'asse da diverse piattaforme con un singolo filtro locale su una pagina combinata

Il metodo che ho usato per fare questo è aggiungere alla tua Oneway Platform un << Add Graphics Script() che controlla se Y Origin() o Y Range() è cambiato, e se lo è, quindi << Copia le impostazioni dell'asse dall'asse Y e poi << Incolla le impostazioni dell'asse negli assi Y sulla piattaforma bivariata.

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA\Big Class.jmp" );

nw = New Window( "DASHBORAD DEVELOPMENT",
 originHold = 0;
 originRange = 0;
 Data Filter Context Box(
  V List Box(
   H List Box(
    Current Data Table() << Data Filter( Conditional, Local, Add Filter( columns( :Age, :Weight ) ) ),
    ow1 = dt << Oneway(
     Y( :HEIGHT ),
     X( :Sex ),
     Automatic Recalc( 1 ),
     Means( 1 ),
     Mean Diamonds( 1 ),
     SendToReport( Dispatch( {}, "Oneway Anova", OutlineBox, {Close( 1 )} ) )
    ),
    ow2 = dt << Oneway(
     Y( :HEIGHT ),
     X( :Age ),
     Automatic Recalc( 1 ),
     Means( 1 ),
     Mean Diamonds( 1 ),
     SendToReport( Dispatch( {}, "Oneway Anova", OutlineBox, {Close( 1 )} ) )
    )
   ),
   biv = dt << Bivariate(
    Y( :HEIGHT ),
    X( :Weight ),
    Automatic Recalc( 1 ),
    SendToReport( Dispatch( {}, "Bivar Plot", FrameBox, {Frame Size( 1018, 240 )} ) )
   )
  )
 );
);
Report( ow1 )[Frame Box( 1 )] << Add Graphics Script(
 If( originHold != Y Origin() | rangeHold != Y Range(),
  originHold = Y Origin();
  rangeHold = Y Range();
  Report( ow1 )[Axis Box( 1 )] << Copy Axis Settings;
  Try( Report( biv )[Axis Box( 1 )] << Paste Axis Settings );
 )
);