43974_zh-TW

liliconcom

如何在組合頁面上使用單一本地過濾器自動縮放來自不同平台的軸

你好，

我剛開始使用儀表板和本地過濾器，但遇到了一些困難。 我正在嘗試為我產生一份日常分析的單頁摘要。 我可以使用我想要的元素來建立窗口，並且過濾器根據每個圖表中顯示的資料在各種平台（2xOneway 和 1xBivariate 圖）上工作，但是 2xOneway 圖表上的軸會隨著本地的更改而重新縮放過濾器，但雙變量沒有- 有沒有辦法讓雙變量圖在我更改本地過濾器選擇時也重新縮放？  

 

這是我創建組合視窗的程式碼部分（我不是編碼員，所以它可能不太漂亮！）

 

nw = new window( "DASHBORAD DEVELOPMENT",
 Data Filter Context Box(
  V List Box(
   H List Box(
    Current Data Table() << Data Filter(
     Conditional,
     Local,
     Add Filter(
      columns( :PRODUCTION_LINE, :PRESS_ID, :AREA_ID, :METROLOGY_FLAG, :Desport_Flag),
      Display( :AREA_ID, Size( 160, 75 ), List Display ),
      Display( :PRESS_ID, Size( 143, 30 ), List Display )
     )
    ),
    Oneway(
     Y( :HEIGHT),
     X( :MACH ),
     Automatic Recalc( 1 ),
     Means( 1 ),
     Mean Diamonds( 1 ),
     SendToReport(
      Dispatch( {}, "Oneway Anova", OutlineBox, {Close( 1 )} )
     )
    ),
    Oneway(
     Y( :HEIGHT),
     X( :OPERATOR),
     Automatic Recalc( 1 ),
     Means( 1 ),
     Mean Diamonds( 1 ),
     SendToReport(
      Dispatch( {}, "Oneway Anova", OutlineBox, {Close( 1 )} )
     )
    )
   ),
   Bivariate(
    Y( :HEIGHT ),
    X( :PRODUCTION_DATE),
    Automatic Recalc( 1 ),
    SendToReport(
     Dispatch(
      {},
      "Bivar Plot",
      FrameBox,
      {Frame Size( 1018, 240 )
      }
     )
    )
   )
  )
 )
);

如果這是我遺漏的非常基本的東西，請提前道歉！

尼爾

回覆：如何在組合頁面上使用單一本地過濾器自動縮放來自不同平台的軸才華橫溢的吉姆，非常感謝！回覆：如何在組合頁面上使用單一本地過濾器自動縮放來自不同平台的軸

這是對我發送給您的腳本的修改，其中添加了一個無意義的附加到添加圖形腳本中。 這是無意義的，但它確實有效

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA\Big Class.jmp" );

nw = New Window( "DASHBORAD DEVELOPMENT",
 originHold = 0;
 originRange = 0;
 Data Filter Context Box(
  V List Box(
   H List Box(
    Current Data Table() << Data Filter( Conditional, Local, Add Filter( columns( :Age, :Weight ) ) ),
    ow1 = dt << Oneway(
     Y( :HEIGHT ),
     X( :Sex ),
     Automatic Recalc( 1 ),
     Means( 1 ),
     Mean Diamonds( 1 ),
     SendToReport( Dispatch( {}, "Oneway Anova", OutlineBox, {Close( 1 )} ) )
    ),
    ow2 = dt << Oneway(
     Y( :HEIGHT ),
     X( :Age ),
     Automatic Recalc( 1 ),
     Means( 1 ),
     Mean Diamonds( 1 ),
     SendToReport( Dispatch( {}, "Oneway Anova", OutlineBox, {Close( 1 )} ) )
    )
   ),
   biv = dt << Bivariate(
    Y( :HEIGHT ),
    X( :Weight ),
    Automatic Recalc( 1 ),
    SendToReport( Dispatch( {}, "Bivar Plot", FrameBox, {Frame Size( 1018, 240 )} ) )
   )
  )
 );
);
Report( ow1 )[Frame Box( 1 )] << Add Graphics Script(
 If( originHold != Y Origin() | rangeHold != Y Range(),
  originHold = Y Origin();
  rangeHold = Y Range();
  Report( ow1 )[Axis Box( 1 )] << Copy Axis Settings;
  Try( Report( biv )[Axis Box( 1 )] << Paste Axis Settings );
  Report( biv )[Outline Box( 1 )] << append( text box("Changed " || char(originHold)))
 );
 
);

回覆：如何在組合頁面上使用單一本地過濾器自動縮放來自不同平台的軸吉姆，
首先感謝您的回复，非常感謝！ 這有效
非常適合我詢問的情況。

是否可以使用相同的方法（新增圖形腳本）
使用append()為現有開啟的視窗新增一個部分？ 我嘗試過
將它包含在附加函數中，但它給我一個錯誤？
回覆：如何在組合頁面上使用單一本地過濾器自動縮放來自不同平台的軸

我用來執行此操作的方法是，我會在 Oneway 平台上新增一個 << Add Graphics Script()，用於檢查 Y Origin() 或 Y Range() 是否已更改，如果已更改，然後<< 從Y軸複製軸設置，然後<< 將軸設置貼到雙變量平台上的Y 軸。

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA\Big Class.jmp" );

nw = New Window( "DASHBORAD DEVELOPMENT",
 originHold = 0;
 originRange = 0;
 Data Filter Context Box(
  V List Box(
   H List Box(
    Current Data Table() << Data Filter( Conditional, Local, Add Filter( columns( :Age, :Weight ) ) ),
    ow1 = dt << Oneway(
     Y( :HEIGHT ),
     X( :Sex ),
     Automatic Recalc( 1 ),
     Means( 1 ),
     Mean Diamonds( 1 ),
     SendToReport( Dispatch( {}, "Oneway Anova", OutlineBox, {Close( 1 )} ) )
    ),
    ow2 = dt << Oneway(
     Y( :HEIGHT ),
     X( :Age ),
     Automatic Recalc( 1 ),
     Means( 1 ),
     Mean Diamonds( 1 ),
     SendToReport( Dispatch( {}, "Oneway Anova", OutlineBox, {Close( 1 )} ) )
    )
   ),
   biv = dt << Bivariate(
    Y( :HEIGHT ),
    X( :Weight ),
    Automatic Recalc( 1 ),
    SendToReport( Dispatch( {}, "Bivar Plot", FrameBox, {Frame Size( 1018, 240 )} ) )
   )
  )
 );
);
Report( ow1 )[Frame Box( 1 )] << Add Graphics Script(
 If( originHold != Y Origin() | rangeHold != Y Range(),
  originHold = Y Origin();
  rangeHold = Y Range();
  Report( ow1 )[Axis Box( 1 )] << Copy Axis Settings;
  Try( Report( biv )[Axis Box( 1 )] << Paste Axis Settings );
 )
);