46567_fr-FR

liliconcom

Sélection de plusieurs colonnes dans un script

J'ai travaillé sur un script pour évaluer certaines transformations possibles pour l'ajustement des polynômes du premier et du deuxième ordre. Le script semble bien fonctionner. Cependant, je ne peux sélectionner qu'une seule colonne à la fois. Existe-t-il un moyen de modifier ce script pour permettre l'évaluation de plusieurs colonnes à la fois ?

 

 

Clear Log();
dt = Current Data Table(); // Use Current Data Table;
xvar = .;
yvar = .;
win = New Window( "Transformation Variable Selection",
<<MODAL></MODAL>

 

Re : Sélection de plusieurs colonnes dans un script

Voici une autre approche de la boîte de dialogue qui permet à l'utilisateur de sélectionner une ou plusieurs colonnes pour X et Y. Cela renvoie une liste de colonnes pour chaque rôle. Cependant, avec plusieurs colonnes sélectionnées, le reste de votre script devra effectuer un traitement supplémentaire de la liste pour récupérer les colonnes avant de parcourir les transformations - vous devrez peut-être ajouter un autre niveau d'itération.

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Body Fat.jmp" );
win = New Window( "Transformation Variable Selection",
 <<MODAL></MODAL>

 

 

Re : Sélection de plusieurs colonnes dans un script

Désolé, il y avait quelques bugs dans ce script.Voici quelque chose de plus proche de la façon dont je mettrais cela en œuvre :

Names Default To Here( 1 );
//Fit all requested combinations of transformations and fit types for a single pair of variables
processPair = function({dt, xvar, yvar},
 transformations = {"Log", "Sqrt", "Square", "Reciprocal", "Exp", "None"};
 
 For( transx = 1, transx < 7, transx++,  
  For( transy = 1, transy < 7 /* 7 */, transy++,   
   For (FitDegree = 1, FitDegree <= 3, FitDegree++,
    
    biv = dt << Bivariate(
     Y( Column( yvar ) ),
     X( Column( xvar ) ),
     Fit Special(
      xTran( transformations[transx] ),
      yTran( transformations[transy] ),
      Degree( FitDegree ),
      //Centered Polynomial( 1 ),
      {Line Color( {212, 73, 88} )}
     )
    );
    
    rbiv = Report( biv );
    bivmatrix = Try( rbiv[Outline Box( 3 )][1][2] << Get As Matrix );
    If( Is Missing( bivmatrix = Try( rbiv[Outline Box( 3 )][1][2] << Get As Matrix ) ), 0 );
    
    dtOutput << Add Rows( 1, At End );
    rowout = n rows( dtOutput );
    
    Column( dtOutput, "Independent Variable" )[rowout] = xvar;
    Column( dtOutput, "Dependent Variable" )[rowout] = yvar;
    Column( dtOutput, "X Transformation" )[rowout] = transformations[transx];
    Column( dtOutput, "Y Transformation" )[rowout] = transformations[transy];
    Column( dtOutput, "Polynomial Degree" )[rowout] = FitDegree;
    Column( dtOutput, "R2" )[rowout] = bivmatrix[1];
    Column( dtOutput, "RMSE" )[rowout] = bivmatrix[3];
    
    biv << Close Window;
   );
  );
 ); 
);

//Function to analyze all variables, runs when button is pressed and at least one variable is selected
processAll = function({dt, xvars, yvars},
 tbStatus << Set Text("Starting analysis...");
 
 //Make a data table to hold output
 dtOutput = New Table( "Tranformation Evalutation Results",
  New Column( "Independent Variable", Character, Text, Width( 5 ) ),
  New Column( "Dependent Variable", Character, Text, Width( 5 ) ),
  New Column( "X Transformation", Character, Text, Width( 5 ) ),
  New Column( "Y Transformation", Character, Text, Width( 5 ) ),
  New Column( "Polynomial Degree", Numeric, Ordinal, Width( 5 ) ),
  New Column( "R2", Numeric, Continuous, Width( 5 ) ),
  New Column( "RMSE", Numeric, Continuous, Width( 5 ) )
 );
 
 //for each combination of x and y variable update status and fit all types of transformations
 for( xvar_n = 1, xvar_n <= N items(xvars), xvar_n++,
  for(yvar_n = 1, yvar_n <= N items(yvars), yvar_n++,
   tbStatus << Set Text("Processing x = '" || xvars[xvar_n] || "', y = '" || yvars[yvar_n] || "'");
   processPair( dt, xvars[xvar_n], yvars[yvar_n] );
  );
 ); 
 tbStatus << Set Text("Done with analysis."); 
);

//open sample data
dt = Open( "$SAMPLE_DATA/Body Fat.jmp" );

//window to select columns and button to run functions above
win = New Window( "Transformation Variable Selection",
 
 Text Box( " Select Numeric Columns. " ),
 H List Box(
  Text Box( " X, Factor " ),
  x = Col List Box(
   dt, // data table reference
   all // display all columns from the data table;
  ),
  Text Box( "Y, Response" ),
  y = Col List Box(
   dt,
   all
  )
 ),
 tbStatus = Text Box("Ready."),
 Button Box("Analyze Variables",

  //Get variables
  xvars = x << Get selected;
  yvars = y << Get selected;
  
  If( n items(xvars) == 0  | n items(yvars) == 0, 
   tbStatus << Set Text("Select at least one ind and one dep variable to continue."),
   processAll(dt, xvars, yvars);
  )
 )
);

Re : Sélection de plusieurs colonnes dans un script

Chaque fois que je supprime le [1] (voir souligné et italique dans le script ci-dessous) de la partie du script ci-dessous, cela ne fonctionne pas.Le script que vous avez fourni ne me permet pas de cliquer sur OK dans la zone de texte et n'exécute donc pas réellement la partie bivariée du script.

 

Je ne veux pas être pénible, j'essaie toujours de maîtriser JSL. Toute aide que vous pouvez fournir serait grandement appréciée.

 

Zone de liste H (

Zone de texte( " X, Facteur " ),

x = Zone de liste de colonnes (

dt, // référence à la table de données

all, // affiche toutes les colonnes de la table de données

xvar = (x << Obtenir la sélection)[1];

// récupère le nom de la colonne sélectionnée avant la fermeture de la fenêtre

Afficher( xvar );

),

Zone de texte( "O, Réponse" ),

y = Zone de liste de colonnes (

dt,

tous,

yvar = (y << Obtenir la sélection)[1];

Afficher( yvar );

Re : Sélection de plusieurs colonnes dans un script

Lorsque vous obtenez les noms de colonnes de la zone de liste Col dans votre script, vous sous-définissez la liste renvoyée avec [1].Cela renvoie uniquement la première colonne sélectionnée.Si vous supprimez les crochets puis parcourez les listes, vous pouvez appliquer votre script à plusieurs paires de colonnes x et y.Vous souhaiterez probablement résumer ou concaténer vos résultats, mais l’idée de base ressemblerait au script ci-dessous. Notez que pour accélérer les choses, j'évalue uniquement a=1 (voir le /* 7 */ commenté)

 

Names Default To Here( 1 );

//wrap your script to process both variables in a function
//this is not necessary but it make the new for loops more clear
processpair = function({dt, xvar, yvar},
 d = 1;
 m = Matrix( 72, 5 );
 l = List( 72 );
 l1 = List( 72 );
 l2 = List( 72 );
 For( c = 1, c < 3, c++,
  For( b = 1, b < 7, b++,
   transb = Match( b, 1, "Log", 2, "Sqrt", 3, "Square", 4, "Reciprocal", 5, "Exp", 6, "None", );
   For( a = 1, a < 7 /* 7 */, a++,
    transa = Match( a, 1, "Log", 2, "Sqrt", 3, "Square", 4, "Reciprocal", 5, "Exp", 6, "None", );
    biv = Bivariate(
     Y( Column( yvar ) ),
     X( Column( xvar ) ),
     Fit Special(
      xTran( transb ),
      yTran( transa ),
      Degree( c ),
      Centered Polynomial( 0 ),
      {Line Color( {213, 72, 87} )}
     ), 
 //SendToReport(
     // Dispatch(
     // {"Transformed Fit Log to Log"},
     // "Summary of Fit",
     // OutlineBox,
     // {Set Title( "Summary of Fit" )}
     // )
     //)

    );
    rbiv = Report( biv );
    bivmatrix = Try( rbiv[Outline Box( 3 )][1][2] << Get As Matrix );
    If( Is Missing( bivmatrix = Try( rbiv[Outline Box( 3 )][1][2] << Get As Matrix ) ),
     0
    );
 //bivmatrix2 = rbiv[Number Col Box( 7 )] << Get As Matrix;
    //bivMatrix3 = rbiv[Number Col Box( 8 )] << Get As Matrix;
    bivR2 = bivmatrix[1];
    bivRMSE = bivmatrix[3];
 //bivIntercept = bivMatrix2[1];
    //bivX = bivMatrix2[2];
    //bivForm = rbiv[Text Edit Box( 4 )];
    //l[d] = transb || "(" || xvar || ") vs " || transa || "(" || yvar || ")";
    l[d] = xvar;
    l1[d] = transb;
    l2[d] = transa;
    m[d, 1] = c;
    m[d, 2] = bivR2;
    m[d, 3] = bivRMSE;
    Close All( Reports, No Save );
 //m[d, 3] = bivIntercept;
    //m[d, 4] = bivx;
    d++;

   );
  )
 );
 ds = New Table( "Tranformation Evalutation" || " " || xvar || " vs " || yvar );
 ds << New Column( "Independent Variable", Character, Text, Width( 5 ), Values( l ) );
 ds << New Column( "X Transformation", Character, Text, Width( 5 ), Values( l1 ) );
 ds << New Column( "Y Transformation", Character, Text, Width( 5 ), Values( l2 ) );
 ds << New Column( "Polynomial Degree", Numeric, Continuous, Width( 5 ), Values( m[0, 1] ) );
 ds << New Column( "R2", Numeric, Continuous, Width( 5 ), Values( m[0, 2] ) );
 ds << New Column( "RMSE", Numeric, Continuous, Width( 5 ), Values( m[0, 3] ) );
);

//use sample data
dt = Open( "$SAMPLE_DATA/Body Fat.jmp" );

xvar = .;
yvar = .;



win = New Window( "Transformation Variable Selection",
 Text Box( " Select Numeric Columns. " ),
 H List Box(
  Text Box( " X, Factor " ),
  x = Col List Box(
   dt, // data table reference
   all, // display all columns from the data table
   // get the name of the selected column before the window closes
   xvars = (x << Get Selected);
   Show( xvar );
  ),
  Text Box( "Y, Response" ),
  y = Col List Box(
   dt,
   all,
   yvars = (y << Get Selected);
   Show( yvar );
  )
 ),
 tbStatus = Text Box("Ready."),
 Button Box("Analyze Variables",

  //Get variables
  xvars = x << Get selected;
  yvars = y << Get selected;
  
  If( n items(xvars) == 0  | n items(yvars) == 0, 
   tbStatus << Set Text("Select at least one ind and one dep variable to continue."),
   
   //for each combination of x and y variable
   for( xvar_n = 1, xvar_n <= N items(xvars), xvar_n ++,
    xvar = xvars[xvar_n];
    show(xvar);
    for(yvar_n = 1, yvar_n <= N items(yvars), yvar_n ++,
     yvar = yvars[yvar_n];
     show(yvar);
     
     //Run your script
     processpair( dt, xvar, yvar );
    )
   );
  );
 )
);

édité : correction de quelques bugs, voir réécriture plus tard dans le fil de discussion