83985_es-ES

liliconcom

Ajuste Y por X con múltiples datos y y un grupo de control

Hola

 

Tengo varios grupos diferentes y un control. Me gustaría hacer un análisis Fit Y by X donde tengo los diferentes grupos en parcelas separadas pero tengo el comparador del grupo de control en cada parcela. Por ejemplo, Control grp A con grps B, C, D y control grp A con grps E, F, G. Con la esperanza de hacer todo en uno sin necesidad de usar ocultar / excluir y trazar varias veces.

 

Gracias

 

R.

Re: Ajuste Y por X con múltiples datos y y un grupo de control

Probablemente no sea exactamente lo que desea, pero puede intentar usar 'Favoritos' con el filtro de datos locales (y luego tal vez registrar los resultados filtrados para obtenerlos en un solo lugar).

Para ver esto, ejecute el siguiente código para hacer una tabla, luego ejecute el script guardado en la tabla:

New Table( "Test",
 Add Rows( 100 ),
 New Script(
  "Oneway",
  Oneway(
   Y( :Response ),
   X( :Group ),
   Automatic Recalc( 1 ),
   Local Data Filter(
    Add Filter(
     columns( :Group ),
     Display( :Group, Size( 160, 105 ), List Display )
    ),
    Favorites(
     "Group = Control, B, C, D"(Match( columns( :Group ),
      Where( :Group == {1, 2, 3, 4} )
     )),
     "Group = Control, E, F, G"(Match( columns( :Group ),
      Where( :Group == {1, 5, 6, 7} )
     ))
    )
   )
  )
 ),
 New Column( "Group",
  Numeric,
  "Nominal",
  Format( "Best", 12 ),
  Formula( Random Integer( 1, 7 ) ),
  Value Labels(
   {1 = "Control", 2 = "B", 3 = "C", 4 = "D", 5 = "E", 6 = "F", 7 = "G"}
  ),
  Use Value Labels( 1 )
 ),
 New Column( "Response",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 12, 2 ),
  Formula( Random Normal() )
 )
)