83985_it-IT

liliconcom

Adatta Y per X con più dati y e un gruppo di controllo

Ciao

 

Ho più gruppi diversi e un controllo. Mi piacerebbe fare un analysi Fit Y by X dove ho i diversi gruppi su grafici separati ma ho il comparatore del gruppo di controllo su ogni trama. Per esempio Control grp A con grps B, C, D e control grp A con grps E, F, G. Sperando di fare tutto in uno senza dover usare hide / exclude e plottare più volte.

 

Grazie

 

R.

Ri: Adatta Y per X con più dati y e un gruppo di controllo

Probabilmente non è esattamente ciò che desideri, ma potresti provare a utilizzare "Preferiti" con il filtro locale dei dati (e quindi forse inserire nel diario i risultati filtrati per metterli in un unico posto).

Per vederlo, esegui il codice qui sotto per creare una tabella, quindi esegui lo script salvato nella tabella:

New Table( "Test",
 Add Rows( 100 ),
 New Script(
  "Oneway",
  Oneway(
   Y( :Response ),
   X( :Group ),
   Automatic Recalc( 1 ),
   Local Data Filter(
    Add Filter(
     columns( :Group ),
     Display( :Group, Size( 160, 105 ), List Display )
    ),
    Favorites(
     "Group = Control, B, C, D"(Match( columns( :Group ),
      Where( :Group == {1, 2, 3, 4} )
     )),
     "Group = Control, E, F, G"(Match( columns( :Group ),
      Where( :Group == {1, 5, 6, 7} )
     ))
    )
   )
  )
 ),
 New Column( "Group",
  Numeric,
  "Nominal",
  Format( "Best", 12 ),
  Formula( Random Integer( 1, 7 ) ),
  Value Labels(
   {1 = "Control", 2 = "B", 3 = "C", 4 = "D", 5 = "E", 6 = "F", 7 = "G"}
  ),
  Use Value Labels( 1 )
 ),
 New Column( "Response",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 12, 2 ),
  Formula( Random Normal() )
 )
)