83985_fr-FR

liliconcom

Ajuster Y par X avec plusieurs données y et un groupe de contrôle

salut

 

J'ai plusieurs groupes différents et un contrôle. Je voudrais faire une analyse Fit Y par X où j'ai les différents groupes sur des parcelles séparées mais le comparateur du groupe de contrôle sur chaque parcelle. Par exemple, contrôlez le groupe A avec les groupes B, C, D et le groupe de contrôle A avec les groupes E, F et G. En espérant que vous fassiez tout en un sans avoir à utiliser masquer / exclure et tracer plusieurs fois.

 

Merci

 

R.

Re: Ajustez Y par X avec plusieurs données y et un groupe de contrôle

Probablement pas tout à fait ce que vous voulez, mais vous pouvez essayer d’utiliser des «Favoris» avec le filtre de données local (et peut-être ensuite consigner les résultats filtrés dans un journal).

Pour voir cela, exécutez le code ci-dessous pour créer une table, puis exécutez le script enregistré dans la table:

New Table( "Test",
 Add Rows( 100 ),
 New Script(
  "Oneway",
  Oneway(
   Y( :Response ),
   X( :Group ),
   Automatic Recalc( 1 ),
   Local Data Filter(
    Add Filter(
     columns( :Group ),
     Display( :Group, Size( 160, 105 ), List Display )
    ),
    Favorites(
     "Group = Control, B, C, D"(Match( columns( :Group ),
      Where( :Group == {1, 2, 3, 4} )
     )),
     "Group = Control, E, F, G"(Match( columns( :Group ),
      Where( :Group == {1, 5, 6, 7} )
     ))
    )
   )
  )
 ),
 New Column( "Group",
  Numeric,
  "Nominal",
  Format( "Best", 12 ),
  Formula( Random Integer( 1, 7 ) ),
  Value Labels(
   {1 = "Control", 2 = "B", 3 = "C", 4 = "D", 5 = "E", 6 = "F", 7 = "G"}
  ),
  Use Value Labels( 1 )
 ),
 New Column( "Response",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 12, 2 ),
  Formula( Random Normal() )
 )
)