106187_es-ES

liliconcom

gráfico con diferentes objetivos o límites de especificaciones

Hola,

 

Tengo una gráfica para 2 productos (P y X) como esta imagen a continuación.

 

Me gustaría agregar una línea de referencia y una zona de color específica para cada producto con el jsl del gráfico.

 

¿Es posible?

 

atentamente

 

 

 

Re: gráfico con diferentes objetivos o límites de especificaciones

Sí.

 

Si oculta los 'Hombres' (por ejemplo, mediante el uso de un filtro de datos local), el cuadro de cuadro que contiene estos puntos (en este caso, 'FrameBox (2)') se elimina de la pantalla, junto con el guión de gráficos asociado. Cuando los 'Machos' no están ocultos, JMP creará el cuadro de marco que necesita, pero heredará el script de gráficos de las 'Mujeres'. Uno podría argumentar que no debería hacer esto, pero, por supuesto, no tendría líneas para los 'Hombres'.

 

Creo que podría obtener el comportamiento que desea mediante el uso de un controlador de estado de fila, pero tomaría un poco de trabajo hacer esto en general.

Re: gráfico con diferentes objetivos o límites de especificaciones

Hola,

 

hay un pb.

 

Si excluye M y luego vuelve a incluir M, tendrá los mismos límites de especificación para F y M.

 

atentamente

Re: gráfico con diferentes objetivos o límites de especificaciones

Piensa que puedes tener que recurrir a guiones gráficos. Hacer esto general requeriría algo de trabajo, pero es perfectamente posible. Utilice 'Ayuda> Índice de secuencias de comandos' para obtener más detalles.

 

NamesDefaultToHere(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

// Using the axis gives common values for the groups
gb1 = dt << Graph Builder(
    Size( 534, 488 ),
    Show Control Panel( 0 ),
    Show Legend( 0 ),
    Variables( X( :weight ), Y( :height ), Group X( :sex ) ),
    Elements( Points( X, Y, Legend( 8 ) ), Smoother( X, Y, Legend( 9 ) ) ),
    SendToReport(
     Dispatch(
      {},
      "height",
      ScaleBox,
      {Add Ref Line( {60, 65}, "Solid", "Green", "Middle", 1, 0.25 ),
      Add Ref Line( {65, 70}, "Solid", "Medium Dark Cyan", "Top", 1, 0.25 ),
      Add Ref Line( 65, "Solid", "Orange", "", 1 )}
     )
    )
   );

// Different values for each group takes more work
gb2 = dt << Graph Builder(
    Size( 534, 488 ),
    Show Control Panel( 0 ),
    Show Legend( 0 ),
    Variables( X( :weight ), Y( :height ), Group X( :sex ) ),
    Elements( Points( X, Y, Legend( 8 ) ), Smoother( X, Y, Legend( 9 ) ) )
   );
gb2Rep = Report(gb2);
// Females . . .
gb2Rep[Framebox(1)] << addGraphicsScript(
       PenColor("Orange"); HLine(60);
       Transparency(0.25);
       FillColor("Green");
       Rect(50, 60, 180, 55, 1);
       FillColor("Blue");
       Rect(50, 65, 180, 60, 1);
      );
// Males . . .
gb2Rep[Framebox(2)] << addGraphicsScript(
       PenColor("Orange"); HLine(65);
       Transparency(0.25);
       FillColor("Green");
       Rect(50, 65, 180, 60, 1);
       FillColor("Blue");
       Rect(50, 70, 180, 65, 1);
      );