106187_ko-KR

liliconcom

다른 목표 또는 사양 한계가있는 그래프

안녕하세요,

 

나는이 이미지와 같은 2 개의 제품 (P와 X)에 대한 그래프를 가지고있다.

 

그래프의 jsl을 사용하여 각 제품에 대한 특정 색칠 된 영역과 색칠 된 영역을 추가하고 싶습니다.

 

가능한가?

 

친애하는

 

 

 

재 : 다른 목표 또는 사양 제한이있는 그래프

예.

 

'Males'(예 : 로컬 데이터 필터 사용)를 숨기면이 지점 (이 경우 'FrameBox (2)')을 포함하는 프레임 상자가 관련 그래픽 스크립트와 함께 디스플레이에서 삭제됩니다. 'Males'가 숨겨져있을 때 JMP는 필요한 프레임 상자를 만들지 만 'Females'에서 그래픽 스크립트를 상속받습니다. 물론 그렇게해서는 안된다고 주장 할 수는 있지만, 물론 '남성'에게 줄을 여는 것은 아닙니다.

 

난 당신이 행 상태 처리기를 사용하여 원하는 동작을 얻을 수있을 것 같아요하지만이 일을 만들기 위해 몇 가지 작업이 필요합니다.

재 : 다른 목표 또는 사양 제한이있는 그래프

안녕하세요,

 

pb가 있습니다.

 

M을 제외하고 M을 다시 포함하면 F와 M에 대해 동일한 사양 제한을 갖게됩니다.

 

친애하는

재 : 다른 목표 또는 사양 제한이있는 그래프

그래픽 스크립트를 사용해야 할 수도 있습니다. 이 장군이 어떤 일을하게 될 것이지만, 완벽하게 가능합니다. 자세한 내용은 '도움말> 스크립트 색인'을 사용하십시오.

 

NamesDefaultToHere(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

// Using the axis gives common values for the groups
gb1 = dt << Graph Builder(
    Size( 534, 488 ),
    Show Control Panel( 0 ),
    Show Legend( 0 ),
    Variables( X( :weight ), Y( :height ), Group X( :sex ) ),
    Elements( Points( X, Y, Legend( 8 ) ), Smoother( X, Y, Legend( 9 ) ) ),
    SendToReport(
     Dispatch(
      {},
      "height",
      ScaleBox,
      {Add Ref Line( {60, 65}, "Solid", "Green", "Middle", 1, 0.25 ),
      Add Ref Line( {65, 70}, "Solid", "Medium Dark Cyan", "Top", 1, 0.25 ),
      Add Ref Line( 65, "Solid", "Orange", "", 1 )}
     )
    )
   );

// Different values for each group takes more work
gb2 = dt << Graph Builder(
    Size( 534, 488 ),
    Show Control Panel( 0 ),
    Show Legend( 0 ),
    Variables( X( :weight ), Y( :height ), Group X( :sex ) ),
    Elements( Points( X, Y, Legend( 8 ) ), Smoother( X, Y, Legend( 9 ) ) )
   );
gb2Rep = Report(gb2);
// Females . . .
gb2Rep[Framebox(1)] << addGraphicsScript(
       PenColor("Orange"); HLine(60);
       Transparency(0.25);
       FillColor("Green");
       Rect(50, 60, 180, 55, 1);
       FillColor("Blue");
       Rect(50, 65, 180, 60, 1);
      );
// Males . . .
gb2Rep[Framebox(2)] << addGraphicsScript(
       PenColor("Orange"); HLine(65);
       Transparency(0.25);
       FillColor("Green");
       Rect(50, 65, 180, 60, 1);
       FillColor("Blue");
       Rect(50, 70, 180, 65, 1);
      );