106187_it-IT

liliconcom

grafico con target o limiti di specifiche diversi

Ciao,

 

Ho un grafico per 2 prodotti (P e X) come questa immagine qui sotto.

 

Vorrei aggiungere una linea di riferimento e una zona colorata specifica per ogni prodotto con il jsl del grafico.

 

È possibile?

 

distinti saluti

 

 

 

Re: grafico con target o limiti di specifiche diversi

Sì.

 

Se nascondi i 'Maschi' (ad esempio, utilizzando un filtro dati locale), il riquadro della cornice che contiene questi punti (in questo caso 'FrameBox(2)') viene eliminato dal display, insieme allo script grafico associato. Quando i "Maschi" non sono nascosti, JMP creerà la cornice di cui ha bisogno, ma erediterà lo script grafico dalle "Femmine". Si potrebbe obiettare che non dovrebbe farlo, ma ovviamente non avresti battute per i "maschi".

 

Penso che potresti ottenere il comportamento desiderato usando un gestore dello stato di riga, ma ci vorrebbe del lavoro per renderlo generale.

Re: grafico con target o limiti di specifiche diversi

Ciao,

 

c'è un pb.

 

Se escludi M e poi includi nuovamente M, avrai gli stessi limiti di specifica per F e M.

 

distinti saluti

Re: grafico con target o limiti di specifiche diversi

Pensa che potresti dover ricorrere a script grafici. Fare questo generale richiederebbe un po' di lavoro, ma è perfettamente possibile. Usa "Aiuto > Indice degli script" per maggiori dettagli.

 

NamesDefaultToHere(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

// Using the axis gives common values for the groups
gb1 = dt << Graph Builder(
    Size( 534, 488 ),
    Show Control Panel( 0 ),
    Show Legend( 0 ),
    Variables( X( :weight ), Y( :height ), Group X( :sex ) ),
    Elements( Points( X, Y, Legend( 8 ) ), Smoother( X, Y, Legend( 9 ) ) ),
    SendToReport(
     Dispatch(
      {},
      "height",
      ScaleBox,
      {Add Ref Line( {60, 65}, "Solid", "Green", "Middle", 1, 0.25 ),
      Add Ref Line( {65, 70}, "Solid", "Medium Dark Cyan", "Top", 1, 0.25 ),
      Add Ref Line( 65, "Solid", "Orange", "", 1 )}
     )
    )
   );

// Different values for each group takes more work
gb2 = dt << Graph Builder(
    Size( 534, 488 ),
    Show Control Panel( 0 ),
    Show Legend( 0 ),
    Variables( X( :weight ), Y( :height ), Group X( :sex ) ),
    Elements( Points( X, Y, Legend( 8 ) ), Smoother( X, Y, Legend( 9 ) ) )
   );
gb2Rep = Report(gb2);
// Females . . .
gb2Rep[Framebox(1)] << addGraphicsScript(
       PenColor("Orange"); HLine(60);
       Transparency(0.25);
       FillColor("Green");
       Rect(50, 60, 180, 55, 1);
       FillColor("Blue");
       Rect(50, 65, 180, 60, 1);
      );
// Males . . .
gb2Rep[Framebox(2)] << addGraphicsScript(
       PenColor("Orange"); HLine(65);
       Transparency(0.25);
       FillColor("Green");
       Rect(50, 65, 180, 60, 1);
       FillColor("Blue");
       Rect(50, 70, 180, 65, 1);
      );