106187_de-DE

liliconcom

Diagramm mit unterschiedlichen Ziel- oder Spezifikationsgrenzen

Hi,

 

Ich habe ein Diagramm für 2 Produkte (P und X) wie dieses Bild unten.

 

Ich möchte eine Referenzlinie und eine farbige Zone hinzufügen, die für jedes Produkt spezifisch ist, mit dem jsl des Diagramms.

 

Ist es möglich?

 

mit freundlichen Grüßen

 

 

 

Re: Diagramm mit unterschiedlichen Ziel- oder Spezifikationsgrenzen

Ja.

 

Wenn Sie die „Männer“ ausblenden (z. B. durch Verwendung eines lokalen Datenfilters), wird die Rahmenbox, die diese Punkte enthält (in diesem Fall „FrameBox(2)“), zusammen mit dem zugehörigen Grafikskript aus der Anzeige gelöscht. Wenn die „Männer“ eingeblendet werden, erstellt JMP die benötigte Rahmenbox, erbt jedoch das Grafikskript von den „Frauen“. Man könnte argumentieren, dass es das nicht tun sollte, aber dann hätten Sie natürlich keine Zeilen für die 'Männer'.

 

Ich denke, Sie könnten das gewünschte Verhalten erzielen, indem Sie einen Zeilenzustandshandler verwenden, aber es würde einige Arbeit erfordern, dies allgemein zu machen.

Re: Diagramm mit unterschiedlichen Ziel- oder Spezifikationsgrenzen

Hi,

 

es gibt ein pb.

 

Wenn Sie M ausschließen und dann M wieder einschließen, haben Sie dieselben Spezifikationsgrenzen für F und M.

 

mit freundlichen Grüßen

Re: Diagramm mit unterschiedlichen Ziel- oder Spezifikationsgrenzen

Denken Sie, Sie müssen möglicherweise auf Grafikskripte zurückgreifen. Das Erstellen dieses Generals würde einige Arbeit erfordern, ist aber durchaus möglich. Verwenden Sie „Hilfe > Skriptindex“ für weitere Einzelheiten.

 

NamesDefaultToHere(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

// Using the axis gives common values for the groups
gb1 = dt << Graph Builder(
    Size( 534, 488 ),
    Show Control Panel( 0 ),
    Show Legend( 0 ),
    Variables( X( :weight ), Y( :height ), Group X( :sex ) ),
    Elements( Points( X, Y, Legend( 8 ) ), Smoother( X, Y, Legend( 9 ) ) ),
    SendToReport(
     Dispatch(
      {},
      "height",
      ScaleBox,
      {Add Ref Line( {60, 65}, "Solid", "Green", "Middle", 1, 0.25 ),
      Add Ref Line( {65, 70}, "Solid", "Medium Dark Cyan", "Top", 1, 0.25 ),
      Add Ref Line( 65, "Solid", "Orange", "", 1 )}
     )
    )
   );

// Different values for each group takes more work
gb2 = dt << Graph Builder(
    Size( 534, 488 ),
    Show Control Panel( 0 ),
    Show Legend( 0 ),
    Variables( X( :weight ), Y( :height ), Group X( :sex ) ),
    Elements( Points( X, Y, Legend( 8 ) ), Smoother( X, Y, Legend( 9 ) ) )
   );
gb2Rep = Report(gb2);
// Females . . .
gb2Rep[Framebox(1)] << addGraphicsScript(
       PenColor("Orange"); HLine(60);
       Transparency(0.25);
       FillColor("Green");
       Rect(50, 60, 180, 55, 1);
       FillColor("Blue");
       Rect(50, 65, 180, 60, 1);
      );
// Males . . .
gb2Rep[Framebox(2)] << addGraphicsScript(
       PenColor("Orange"); HLine(65);
       Transparency(0.25);
       FillColor("Green");
       Rect(50, 65, 180, 60, 1);
       FillColor("Blue");
       Rect(50, 70, 180, 65, 1);
      );