35823_es-ES

liliconcom

JSL: DT<

El uso normal de "Selectwhere" parece ser el siguiente:

dt<<SelectWhere(:ExampleColumnName > 5);

Y esto funciona bien. Con lo que tengo dificultades es cuando necesito más flexibilidad en lo que será ":ExampleColumnName".

 

Por ejemplo, si guardo una nueva columna de residuos estudentizados en un modelo de ajuste, se creará una columna llamada algo así como "Registro de residuos estudentizados (UFC/mL) por condición". Digamos que quiero seleccionar cualquier cosa por encima de 3 o por debajo de -3. Debido al nombre de la columna, necesitaría usar:

dt<<SelectWhere(:Name("Studentized Resid Log(CFU/mL) By Condition")<-3 | :Name("Studentized Resid Log(CFU/mL) By Condition")>3);

Esto está bien la mayor parte del tiempo, pero no siempre. Tener que tener la cadena completamente escrita dentro de :Name() no es realmente ideal; por ejemplo, si el plan es hacer que una función se pueda usar para una variedad de Modelos de ajuste que producirán diferentes nombres de columna Residual estudentizado, es No es eficiente escribir un "Seleccionar dónde" único para cada modelo posible (especialmente si no siempre puede anticipar qué modelo elegirá el usuario).

 

Lo que me gustaría trabajar es uno o ambos de los siguientes:

//Option 1
colName = ""Studentized Resid Log(CFU/mL) By Condition";
dt<<SelectWhere(:Name(colName)<-3 | ::Name(colName)>3);

//Option 2
colRef = Column(dt, colName);
dt<<SelectWhere( colRef <-3 | colRef >3 );

La opción 1 devuelve el error "El argumento del nombre debe ser una cadena entre comillas" cuando se ejecuta la función Seleccionar dónde. Parece que :Name() requiere una cadena completamente escrita y una referencia a una es inaceptable.

 

La opción 2 no devuelve errores, pero no se seleccionará nada. Selectwhere no parece tratar las variables de referencia de columna como referencias explícitamente escritas ": XXXX".

 

Mi solución actual no es excelente: después de que Fit Model cree una nueva columna, cambie el nombre de la última columna de la tabla a algo simple y único (como "StdResid") que se puede usar directamente en el "uso normal" de SelectWhere (por ejemplo, " :StdResidencia").

 

¿Me estoy perdiendo algo obvio aquí que haría mi vida más fácil?

 

Además, ¿hay alguna forma de hacer que la Opción 1 y/o la Opción 2 funcionen?

Re: JSL: DT<

Uso la columna As la mayor parte del tiempo. Funciona con un nombre de cadena o una referencia de columna:

 

dt = Open("$SAMPLE_DATA/Big Class.jmp");

// column name
col = "height"; 
dt << Select Where( AsColumn(col) <60 );

Wait(2);
dt  << Clear Row States;

// column reference
col = Column(dt,"height");
dt << Select Where( AsColumn(col) > 65 );

Si siento la necesidad de incrustar una cadena de texto real en :Name sobre la marcha, uso el otro método que se muestra, aunque uso otra sintaxis que me resulta más fácil de manejar:

dt = Open("$SAMPLE_DATA/Big Class.jmp");
colName = "height";
Eval(Parse(EvalInsert("\[ 
 dt << Select Where( :Name("^colName^") > 65 );
]\")));

Re: JSL: DT<

Hola,

Creo que la pieza importante a entender es lo que cada uno devuelve:

• La sintaxis :Name() es un analizador especial que solo acepta un argumento de cadena, como viste. Esto lo hace bastante inflexible para las secuencias de comandos.
• La función Column() devuelve una referencia a la columna como un todo. Select Where() realiza sus comparaciones en cada fila. Agregar un subíndice Row() (o simplemente []) a la función Column() le indicará a JMP que mire la columna en la fila actual, sea lo que sea, mientras Select Where() realiza su comparación.

colName = "Studentized Resid Log(CFU/mL) By Condition";

dt << Select Where( Column( colName )[] < -3 | Column( colName )[] > 3 );

• La función As Column() devuelve una referencia al valor de la columna especificada en la fila actual. En el contexto de Select Where(), la fila actual está siendo controlada por Select Where(). Es por eso que el subíndice Row() no es necesario para @pmroz ejemplo de .  

¡Espero que ayude!

Re: JSL: DT<

Ambas muy buenas ideas, gracias. Había estado tratando de usar Column(dt, colName) antes y no sabía que existía AsColumn().

 

Todavía me encantaría ver la funcionalidad de la Opción 1 y la Opción 2 implementada algún día. ¿Cuál es la mejor manera de pedir esto?

Re: JSL: DT<

JSL y los nombres de las columnas son confusos, especialmente cuando intenta usar OBTENER FILAS DONDE o SELECCIONAR DONDE. Tiendo a usar la construcción como columna (dt, "nombre de columna").

 

Esto funcionará:

dt = New Table( "Test Table", Add Rows( 9 ),
 New Column( "Studentized Resid Log(CFU/mL) By Condition",
  Numeric, Continuous, Format( "Best", 12 ),
  Set Values( [-4, -3, -2, -1, 0, 1, 2, 3, 4] ) )
);

colName = "Studentized Resid Log(CFU/mL) By Condition";

dt << Select Where(as column(dt, colName) < -3 | as column(dt, colName) > 3);

Re: JSL: DT<

Aquí hay un enfoque que utilizo, cuando nada más parece estar dándome los resultados que necesito:

Eval(parse("dt << select where(" || ":Name(\!"" || Char( Column( dt, 1 ) << get name ) || 
"\!")< -3 | :Name(\!"" || Char( Column( dt, 1 ) << get name ) || "\!")  > 3);"));