35823_de-DE

liliconcom

JSL: DT<

Die normale Verwendung von „SelectWhere“ sieht wie folgt aus:

dt<<SelectWhere(:ExampleColumnName > 5);

Und das funktioniert gut. Ich habe Schwierigkeiten damit, wenn ich mehr Flexibilität bei der Gestaltung von „:ExampleColumnName“ benötige.

 

Wenn ich beispielsweise eine neue Spalte mit studentisierten Residuen in einem Anpassungsmodell speichere, wird eine Spalte mit dem Namen „Protokoll der studentisierten Residuale (KBE/ml) nach Bedingung“ erstellt. Nehmen wir an, ich möchte etwas über 3 oder unter -3 auswählen. Aufgrund des Spaltennamens müsste ich Folgendes verwenden:

dt<<SelectWhere(:Name("Studentized Resid Log(CFU/mL) By Condition")<-3 | :Name("Studentized Resid Log(CFU/mL) By Condition")>3);

Meistens ist das in Ordnung, aber nicht immer. Es ist nicht wirklich ideal, die vollständig ausgeschriebene Zeichenfolge in :Name() zu haben. Wenn beispielsweise geplant ist, eine Funktion für eine Vielzahl von Fit-Modellen nutzbar zu machen, die jeweils unterschiedliche Spaltennamen für studentisierte Reste erzeugen, ist dies nicht der Fall Es ist nicht effizient, für jedes mögliche Modell ein eindeutiges „SelectWhere“ zu schreiben (insbesondere, wenn Sie nicht immer vorhersehen können, welches Modell der Benutzer wählen wird).

 

Was ich gerne arbeiten würde, ist eines/beide der folgenden Dinge:

//Option 1
colName = ""Studentized Resid Log(CFU/mL) By Condition";
dt<<SelectWhere(:Name(colName)<-3 | ::Name(colName)>3);

//Option 2
colRef = Column(dt, colName);
dt<<SelectWhere( colRef <-3 | colRef >3 );

Option 1 gibt den Fehler „Name-Argument muss eine Zeichenfolge in Anführungszeichen sein“ zurück, wenn die SelectWhere-Funktion ausgeführt wird. Scheint, als ob :Name() eine vollständig ausgeschriebene Zeichenfolge erfordert und ein Verweis auf eine solche Zeichenfolge nicht akzeptabel ist.

 

Option 2 gibt keine Fehler zurück, aber es wird nichts ausgewählt. SelectWhere scheint Spaltenreferenzvariablen nicht wie explizit eingegebene „:XXXX“-Referenzen zu behandeln.

 

Meine aktuelle Problemumgehung ist nicht besonders gut: Nachdem Fit Model eine neue Spalte erstellt hat, benennen Sie die allerletzte Spalte in der Tabelle in etwas Einfaches und Einzigartiges (wie „StdResid“) um, das direkt in der „normalen Verwendung“ von SelectWhere verwendet werden kann (z. B. „ :StdResid").

 

Übersehe ich hier etwas Offensichtliches, das mir das Leben erleichtern würde?

 

Gibt es außerdem eine Möglichkeit, Option 1 und/oder Option 2 zum Laufen zu bringen?

Betreff: JSL: DT<

Meistens verwende ich die As-Spalte. Es funktioniert entweder mit einem Stringnamen oder einer Spaltenreferenz:

 

dt = Open("$SAMPLE_DATA/Big Class.jmp");

// column name
col = "height"; 
dt << Select Where( AsColumn(col) <60 );

Wait(2);
dt  << Clear Row States;

// column reference
col = Column(dt,"height");
dt << Select Where( AsColumn(col) > 65 );

Wenn ich das Bedürfnis verspüre, eine tatsächliche Textzeichenfolge spontan in :Name einzubetten, verwende ich die andere gezeigte Methode, obwohl ich eine andere Syntax verwende, mit der ich leichter umgehen kann:

dt = Open("$SAMPLE_DATA/Big Class.jmp");
colName = "height";
Eval(Parse(EvalInsert("\[ 
 dt << Select Where( :Name("^colName^") > 65 );
]\")));

Betreff: JSL: DT<

Hallo,

Ich denke, das Wichtigste, was man verstehen muss, ist, was jeder zurückgibt:

• Die :Name()-Syntax ist ein spezieller Parser, der, wie Sie gesehen haben, nur ein String-Argument akzeptiert. Dies macht es für die Skripterstellung ziemlich unflexibel.
• Die Funktion Column() gibt einen Verweis auf die Spalte als Ganzes zurück. Select Where() führt seine Vergleiche für jede Zeile durch. Das Hinzufügen eines Row()-Index (oder einfach nur []) zur Column()-Funktion weist JMP an, die Spalte in der aktuellen Zeile zu betrachten, was auch immer das ist, während Select Where() seinen Vergleich durchführt.

colName = "Studentized Resid Log(CFU/mL) By Condition";

dt << Select Where( Column( colName )[] < -3 | Column( colName )[] > 3 );

• Die Funktion „As Column()“ gibt einen Verweis auf den Wert in der angegebenen Spalte in der aktuellen Zeile zurück. Im Kontext eines Select Where() wird die aktuelle Zeile durch Select Where() gesteuert. Aus diesem Grund ist der Index Row() nicht erforderlich @pmroz Beispiel.  

Hoffentlich hilft das!

Betreff: JSL: DT<

Beides tolle Ideen, danke. Ich hatte zuvor versucht, Column(dt, colName) zu verwenden und wusste nicht, dass AsColumn() existiert.

 

Ich würde mich immer noch freuen, wenn die Funktionalität von Option 1 und Option 2 eines Tages implementiert würde. Wie fragt man am besten danach?

Betreff: JSL: DT<

JSL- und Spaltennamen sind verwirrend, insbesondere wenn Sie versuchen, GET ROWS WHERE oder SELECT WHERE zu verwenden. Ich neige dazu, das Konstrukt als Spalte (dt, „Spaltenname“) zu verwenden.

 

Das wird funktionieren:

dt = New Table( "Test Table", Add Rows( 9 ),
 New Column( "Studentized Resid Log(CFU/mL) By Condition",
  Numeric, Continuous, Format( "Best", 12 ),
  Set Values( [-4, -3, -2, -1, 0, 1, 2, 3, 4] ) )
);

colName = "Studentized Resid Log(CFU/mL) By Condition";

dt << Select Where(as column(dt, colName) < -3 | as column(dt, colName) > 3);

Betreff: JSL: DT<

Hier ist ein Ansatz, den ich verwende, wenn mir scheinbar nichts anderes die Ergebnisse bringt, die ich brauche:

Eval(parse("dt << select where(" || ":Name(\!"" || Char( Column( dt, 1 ) << get name ) || 
"\!")< -3 | :Name(\!"" || Char( Column( dt, 1 ) << get name ) || "\!")  > 3);"));