108081_ja-JP

liliconcom

特定の行に対する複数の変数列の最大値

こんにちは、みんな、

 

数式列を作成して、特定の行に対する複数の変数列の最大値を見つける方法

 

 

colList = dt << get column names;<BR />colList = remove( colList, 1,2);
Show( colList );

 New Column( "Column 15",
  Numeric,
  Continuous,
  Format( "Best", 8 ),
  Formula( Maximum(colList[1]), colList[2],colList[3] ) ),
  Set Selected
 );

 

 

Re: 特定の行に対する複数の変数列の最大値

次のディスカッションを参照してくださいここ。

Re: 特定の行に対する複数の変数列の最大値

@txnelson同様の問題に遭遇していますが、列の長さを知る代わりに、op が 3 の長さを知っているようです。 nの長さの最大になるように変更するにはどうすればよいですか?

Re: 特定の行に対する複数の変数列の最大値

提供したサンプル コードは、提供したとおりに機能しますか?変更なしで動作するはずです。

エラー ステートメントは、単語 "Name" の認識に問題があることを示しています。 データのサンプルと、失敗しているスクリプトを提供していただけますか?

Re: 特定の行に対する複数の変数列の最大値

申し訳ありませんが、まだ機能していません (解決策 2)。

私の名前 - 日付、形式 -01/30/2019 。

どうも。

 

 

Re: 特定の行に対する複数の変数列の最大値

これが私のスクリプトです。唯一の変更点は、SAMPLE データ テーブル "Blood Presure" を指していることです。

 

Names Default To Here( 1 );
dt = Open("$SAMPLE_DATA/Blood Pressure.jmp");

colList = dt << get column names;
colList = Remove( colList, 1, 2 );
Show( colList );

New Column( "Column 15",
 Numeric,
 Continuous,
 Format( "Best", 8 ),
 Formula(
  Max(
   As Column( colList[1] ),
   As Column( colList[2] ),
   As Column( colList[3] )
  ),
  Set Selected
 )
);

Eval(
 Substitute(
   Expr(
    New Column( "Column 16",
     Numeric,
     Continuous,
     Format( "Best", 8 ),
     Formula(
      Max( __col1__, __col2__, __col3__ ),
      Set Selected
     )
    )
   ),
  Expr( __col1__ ), Parse( ":" || Char( colList[1] ) ),
  Expr( __col2__ ), Parse( ":" || Char( colList[2] ) ),
  Expr( __col3__ ), Parse( ":" || Char( colList[3] ) )
 )
);

問題は、JMP が計算しようとしている文字を含む複雑な列名を使用している可能性があります。その場合は、Substitution を次のように変更する必要があります。

Expr( __col1__ ), Parse( ":Name\!"(" || Char( colList[1] ) || "\!")" ) 

もちろん、3 つの置換すべての場合は変更します

Re: 特定の行に対する複数の変数列の最大値

あなたの素早い答えに感謝します。

以下の回答をご覧ください

* 最初の解決策 (コラム 15) うまく機能しています

* 2 番目 (Colmun 16) はうまく機能していません

 

 

Re: 特定の行に対する複数の変数列の最大値

以下は、2 つの異なる方法で必要なものを計算するスクリプトです。1 つ目は、コードの修正です。一部の "(" は正しい場所になかったため移動する必要があり、また、ColList[] 値を列として扱うように JMP に指示するために As Column() 関数を追加する必要がありました。このコードは機能しますが、JMP を終了してから JMP に戻った場合、式で使用する「colList」というリストがないため、式は機能しません。したがって、実際に使用する必要があるのは、私が新しいコラム「コラム 16」として入れたものです。データに対してスクリプトを実行し、2 つの列の実際の数式を確認すると、違いがわかります。

Names Default To Here( 1 );
dt = Current Data Table();

colList = dt << get column names;
colList = Remove( colList, 1, 2 );
Show( colList );

New Column( "Column 15",
 Numeric,
 Continuous,
 Format( "Best", 8 ),
 Formula(
  Max(
   As Column( colList[1] ),
   As Column( colList[2] ),
   As Column( colList[3] )
  ),
  Set Selected
 )
);

Eval(
 Substitute(
   Expr(
    New Column( "Column 16",
     Numeric,
     Continuous,
     Format( "Best", 8 ),
     Formula(
      Max( __col1__, __col2__, __col3__ ),
      Set Selected
     )
    )
   ),
  Expr( __col1__ ), Parse( ":" || Char( colList[1] ) ),
  Expr( __col2__ ), Parse( ":" || Char( colList[2] ) ),
  Expr( __col3__ ), Parse( ":" || Char( colList[3] ) )
 )
);

Re: 特定の行に対する複数の変数列の最大値フィードバックをお待ちしております。