35823_zh-TW

liliconcom

JSL：DT<

正常的“SelectWhere”用法如下：

dt<<SelectWhere(:ExampleColumnName > 5);

這很好用。 我遇到的困難是當我需要更靈活地選擇“:ExampleColumnName”時。

 

例如，如果我在擬合模型中儲存新的 Studentized Residuals 資料列，它將建立一個名為「Studentized Resid Log(CFU/mL) By Condition」的欄位。 假設我想選擇高於 3 或低於 -3 的任何值。 由於該列的名稱，我需要使用：

dt<<SelectWhere(:Name("Studentized Resid Log(CFU/mL) By Condition")<-3 | :Name("Studentized Resid Log(CFU/mL) By Condition")>3);

大多數時候這都很好，但並非總是如此。 必須在:Name() 中完全寫出字串並不是很理想- 例如，如果計劃使一個函數可用於各種擬合模型，每個擬合模型將產生不同的Studentized Residual 列名稱，那麼它是不理想的為每個可能的模型編寫唯一的“SelectWhere”效率不高（特別是如果您不能總是預測使用者將選擇什麼模型）。

 

我想要的工作是以下一項/兩項：

//Option 1
colName = ""Studentized Resid Log(CFU/mL) By Condition";
dt<<SelectWhere(:Name(colName)<-3 | ::Name(colName)>3);

//Option 2
colRef = Column(dt, colName);
dt<<SelectWhere( colRef <-3 | colRef >3 );

當執行 SelectWhere 函數時，選項 1 會傳回「名稱參數必須是帶有引號的字串」錯誤。 似乎 :Name() 需要一個完全寫出的字串，而對字串的引用是不可接受的。

 

選項 2 不回傳任何錯誤，但不會選擇任何內容。 SelectWhere 似乎沒有像明確鍵入“：XXXX”引用那樣對待列引用變數。

 

我目前的解決方法不是很好：在Fit Model 建立新列後，將表中的最後一列重新命名為簡單且唯一的名稱（例如「StdResid」），可以直接在SelectWhere 的「正常用法」中使用（例如，“ ：標準殘留”）。

 

我是否錯過了一些明顯的東西，可以讓我的生活更輕鬆？

 

另外，有什麼方法可以讓選項 1 和/或選項 2 發揮作用嗎？

回覆：JSL：DT<

我大部分時間都使用 As Column。 它適用於字串名稱或列引用：

 

dt = Open("$SAMPLE_DATA/Big Class.jmp");

// column name
col = "height"; 
dt << Select Where( AsColumn(col) <60 );

Wait(2);
dt  << Clear Row States;

// column reference
col = Column(dt,"height");
dt << Select Where( AsColumn(col) > 65 );

如果我覺得需要將實際的文字字串嵌入到 :Name 中，那麼我會使用所示的其他方法，儘管我使用其他我認為更容易處理的語法：

dt = Open("$SAMPLE_DATA/Big Class.jmp");
colName = "height";
Eval(Parse(EvalInsert("\[ 
 dt << Select Where( :Name("^colName^") > 65 );
]\")));

回覆：JSL：DT<

你好，

我認為需要理解的重要部分是每個返回的內容：

• :Name() 語法是一種特殊的解析器，它只接受字串參數，如您所見。 這使得腳本編寫非常不靈活。
• Column() 函數傳回整個列的參考。 SelectWhere() 對每一行執行比較。 將 Row() 下標（或只是 []）新增至 Column() 函數將指示 JMP 查看目前行上的列，無論 SelectWhere() 執行比較時是什麼。

colName = "Studentized Resid Log(CFU/mL) By Condition";

dt << Select Where( Column( colName )[] < -3 | Column( colName )[] > 3 );

• As Column() 函數傳回目前行指定列中的值的參考。 在 SelectWhere() 的上下文中，目前行由 SelectWhere() 控制。 這就是為什麼 Row() 下標不是必需的@pmroz的例子。  

希望有幫助！

回覆：JSL：DT<

兩個都是好主意，謝謝。 我之前一直嘗試使用 Column(dt, colName) ，但不知道 AsColumn() 的存在。

 

我仍然希望有一天看到選項 1 和選項 2 的功能得以實現。 提出這個問題的最佳方式是什麼？

回覆：JSL：DT<

JSL 和列名稱令人困惑，尤其是當您嘗試使用 GET ROWS WHERE 或 SELECT WHERE 時。 我傾向於使用該構造作為column(dt,“column-name”)。

 

這會起作用：

dt = New Table( "Test Table", Add Rows( 9 ),
 New Column( "Studentized Resid Log(CFU/mL) By Condition",
  Numeric, Continuous, Format( "Best", 12 ),
  Set Values( [-4, -3, -2, -1, 0, 1, 2, 3, 4] ) )
);

colName = "Studentized Resid Log(CFU/mL) By Condition";

dt << Select Where(as column(dt, colName) < -3 | as column(dt, colName) > 3);

回覆：JSL：DT<

當沒有其他方法似乎無法獲得我需要的結果時，我使用以下方法：

Eval(parse("dt << select where(" || ":Name(\!"" || Char( Column( dt, 1 ) << get name ) || 
"\!")< -3 | :Name(\!"" || Char( Column( dt, 1 ) << get name ) || "\!")  > 3);"));