108081_de-DE

liliconcom

Maximalwert mehrerer variabler Spalten für bestimmte Zeilen

Hallo alle,

 

So erstellen Sie eine Formelspalte, um das Maximum mehrerer variabler Spalten für bestimmte Zeilen zu ermitteln

 

 

colList = dt << get column names;<BR />colList = remove( colList, 1,2);
Show( colList );

 New Column( "Column 15",
  Numeric,
  Continuous,
  Format( "Best", 8 ),
  Formula( Maximum(colList[1]), colList[2],colList[3] ) ),
  Set Selected
 );

 

 

Betreff: Maximalwert mehrerer variabler Spalten für bestimmte Zeilen

Siehe die folgende Diskussion Hier.

Betreff: Maximalwert mehrerer variabler Spalten für bestimmte Zeilen

@txnelson Ich stoße auf ein ähnliches Problem, aber anstatt meine Spaltenlänge zu kennen, kennt der Op seine Länge von 3. Wie ändere ich es, damit es die maximale Länge von n erreicht?

Betreff: Maximalwert mehrerer variabler Spalten für bestimmte Zeilen

Funktioniert der von mir bereitgestellte Beispielcode so, wie ich ihn bereitgestellt habe?Es sollte ohne Änderung funktionieren.

Die Fehlermeldung weist darauf hin, dass Sie ein Problem mit der Erkennung des Wortes „Name“ haben. Könnten Sie ein Beispiel Ihrer Daten und Ihres fehlerhaften Skripts bereitstellen?

Betreff: Maximalwert mehrerer variabler Spalten für bestimmte Zeilen

Tut mir leid, aber es funktioniert immer noch nicht (Lösung 2).

Meine Namen – Datum, Format – 30.01.2019.

Danke.

 

 

Betreff: Maximalwert mehrerer variabler Spalten für bestimmte Zeilen

Hier ist mein Skript, mit der einzigen Änderung, dass es auf die SAMPLE-Datentabelle „Blutdruck“ verweist.

 

Names Default To Here( 1 );
dt = Open("$SAMPLE_DATA/Blood Pressure.jmp");

colList = dt << get column names;
colList = Remove( colList, 1, 2 );
Show( colList );

New Column( "Column 15",
 Numeric,
 Continuous,
 Format( "Best", 8 ),
 Formula(
  Max(
   As Column( colList[1] ),
   As Column( colList[2] ),
   As Column( colList[3] )
  ),
  Set Selected
 )
);

Eval(
 Substitute(
   Expr(
    New Column( "Column 16",
     Numeric,
     Continuous,
     Format( "Best", 8 ),
     Formula(
      Max( __col1__, __col2__, __col3__ ),
      Set Selected
     )
    )
   ),
  Expr( __col1__ ), Parse( ":" || Char( colList[1] ) ),
  Expr( __col2__ ), Parse( ":" || Char( colList[2] ) ),
  Expr( __col3__ ), Parse( ":" || Char( colList[3] ) )
 )
);

Das Problem kann sein, dass Sie über komplexe Spaltennamen verfügen, die Zeichen enthalten, mit denen JMP Berechnungen durchzuführen versucht.Wenn dies der Fall ist, müssen Sie die Substitution wie folgt ändern:

Expr( __col1__ ), Parse( ":Name\!"(" || Char( colList[1] ) || "\!")" ) 

Ändern Sie dies natürlich für alle drei Auswechslungen

Betreff: Maximalwert mehrerer variabler Spalten für bestimmte Zeilen

Danke Kumpel für deine schnelle Antwort.

Bitte beachten Sie die Antworten unten

* Die erste Lösung (Colmun 15) funktioniert gut

* Der zweite (Colmun 16) funktioniert nicht sehr gut

 

 

Betreff: Maximalwert mehrerer variabler Spalten für bestimmte Zeilen

Unten finden Sie ein Skript, das auf zwei verschiedene Arten berechnet, was Sie möchten.Die erste ist eine Korrektur Ihres Codes.Einige „(“ mussten verschoben werden, da sie nicht an der richtigen Stelle waren, und außerdem musste die Funktion „As Column()“ hinzugefügt werden, um JMP anzuweisen, die colList[]-Werte als Spalten zu behandeln.Dieser Code funktioniert zwar, aber wenn Sie JMP jemals beenden und dann zu JMP zurückkehren, würde die Formel nicht funktionieren, da es keine Liste namens „colList“ gäbe, die in der Formel verwendet werden könnte.Was Sie also wirklich verwenden müssen, ist das, was ich als neue Spalte „Spalte 16“ eingefügt habe.Führen Sie das Skript für Ihre Daten aus und sehen Sie sich dann die tatsächlichen Formeln für die beiden Spalten an. Sie werden den Unterschied erkennen.

Names Default To Here( 1 );
dt = Current Data Table();

colList = dt << get column names;
colList = Remove( colList, 1, 2 );
Show( colList );

New Column( "Column 15",
 Numeric,
 Continuous,
 Format( "Best", 8 ),
 Formula(
  Max(
   As Column( colList[1] ),
   As Column( colList[2] ),
   As Column( colList[3] )
  ),
  Set Selected
 )
);

Eval(
 Substitute(
   Expr(
    New Column( "Column 16",
     Numeric,
     Continuous,
     Format( "Best", 8 ),
     Formula(
      Max( __col1__, __col2__, __col3__ ),
      Set Selected
     )
    )
   ),
  Expr( __col1__ ), Parse( ":" || Char( colList[1] ) ),
  Expr( __col2__ ), Parse( ":" || Char( colList[2] ) ),
  Expr( __col3__ ), Parse( ":" || Char( colList[3] ) )
 )
);

Betreff: Maximalwert mehrerer variabler Spalten für bestimmte ZeilenIch freue mich über Ihr Feedback.