83558_fr-FR

liliconcom

Col list box() ne respecte pas la référence de la table de données

Utilisation de JMP 14.1 :

Je veux que les gens sélectionnent deux tables de données, puis affichent les colonnes de ces tables de données dans deux zones de liste col. Cependant, lorsque je définis les colonnes dans les cases, JMP ne définira que les colonnes de la table de données active et ne respectera pas l'argument de la table de données. Aucune suggestion?

 

Voici un exemple rapide du mauvais comportement :

dt = New Table( "Table 1",
 Add Rows( 0 ),
 Compress File When Saved( 1 ),
 New Column( "Column 1",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [] )
 ),
 New Column( "Column 2",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [] )
 ),
 New Column( "Column 3",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [] )
 )
);

dtNew = New Table( "Table 2",
 Add Rows( 0 ),
 Compress File When Saved( 1 ),
 New Column( "Column 4",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [] )
 ),
 New Column( "Column 5",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [] )
 ),
 New Column( "Column 6",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [] )
 )
);

new window("Column renamer",
 h list box(
  Panel box("Source table",
   SourceBox = Col List Box(dt,All)
  ),
  Panel box("Destination table",
   DestBox = Col List Box(dtnew,All),
  ),
 )
);

Ce résultat est :

Le résultat attendu est que dans la liste de gauche les colonnes 1,2,3 sont affichées puisque ce sont les noms dans la première table. Au lieu de cela, il affiche la deuxième table (la dernière créée et en tant que telle la table active) deux fois.

 

Re : Col list box() ne respecte pas la référence de la table de données

Entendu! Vous pouvez faire une chose similaire avec 'ColListBox()' si vous préférez :

Names default to here(1);

ListOfOpenTables = sort list(Get Data Table List());

updateCLB = 
Expr(
 Try(clb << delete);
 thisTable = (tlb << getSelected)[1];
 CMD = Expr(nw << Append(clb = ColListBox(DataTable(tableTBD), All, maxSelected(1), clbAction)));
 SubstituteInto(CMD, Expr(tableTBD), Eval(thisTable));
 CMD;
 );

clbAction =
Expr(
 Speak("Column "||(clb << getSelected)[1]||" was selected.");
 );

nw = NewWindow("Test", tlb = ListBox(ListOfOpenTables, maxSelected(1), updateCLB));

 

Re : Col list box() ne respecte pas la référence de la table de donnéesOui, en utilisant une zone de liste standard, je l'ai fait fonctionner, mais cela ne ressemble pas aux boîtes de dialogue de sélection de colonne que JMP utilise normalement. Et il ne montre pas le groupement de colonnes de votre table de données. Par conséquent, je voudrais l'implémenter avec la zone de liste col Re : Col list box() ne respecte pas la référence de la table de données

Désolé Paul, je n'ai pas eu le temps de comprendre les nuances de ce que vous essayez de faire.

Mais voici un ancien extrait de code qui peut vous rapprocher (sans utiliser 'ColListBox()'):

Names default to here(1);

ListOfOpenTables = sort list(Get Data Table List());

updateCLB = 
Expr(
 thisTable = (tlb << getSelected)[1];
 CMD = Expr(cols = DataTable(tableTBD) << getColumnNames("String"));
 SubstituteInto(CMD, Expr(tableTBD), Eval(thisTable));
 CMD;
 clb << setItems(cols);
 );

clbAction =
Expr(
 Speak("Column "||(clb << getSelected)[1]||" was selected.");
 );

nw = NewWindow("Test",
   tlb = ListBox(ListOfOpenTables, maxSelected(1), updateCLB),
   clb = ListBox({"Pick a table above"}, maxSelected(1), clbAction) 
  );

Re : Col list box() ne respecte pas la référence de la table de données

Salut Ian, Merci pour votre aide mais en effet cela ne résout pas mon problème. Voici un extrait de code plus gros de ce que j'essaie vraiment de faire. Ainsi, vous sélectionnez deux tables différentes dans les tables ouvertes et lorsque vous sélectionnez une table différente, la liste de colonnes en dessous se remplit avec les colonnes des tables sélectionnées :

Names default to here(1);
ListOfOpenTables = sort list(Get Data Table List());
ColumnWidth = 300;

new window("Column renamer",
 h list box(
  Panel box("Source table",
   v list box(
    FirstDT = List box(ListOfOpenTables, maxSelected(1), width(ColumnWidth),
     dt = Data Table((FirstDT << get selected())[1]);
     SourceBox << Set items(Data Table((FirstDT << get selected())[1]) << Get Column Names("String"));
    ),
    SourceBox = Col List Box(,nlines(40), width(ColumnWidth),
     OldCounter << set text(char(n items(SourceBox << get selected())) || " Columns selected");
     dt << Select columns(SourceBox << get selected());
    ),
    OldCounter = Text Box("")
   )
  ),
  Panel box("Destination table",
   v list box(
    SecondDT = List box(ListOfOpenTables, maxSelected(1), width(ColumnWidth),
     dtnew = Data Table((SecondDT << get selected())[1]);
     DestBox << Set items(Data Table((SecondDT << get selected())[1]) << Get Column Names("String"));
    ),
    DestBox = Col List Box(,nlines(40), width(ColumnWidth),
     NewCounter << set text(char(n items(DestBox << get selected())) || " Columns selected");
     dtnew << Select columns(DestBox << get selected())
    ),
    NewCounter = Text Box("")
   )
  ),
  Panel box("Actions",
   v list box(
    button box("Change column names",DoTheWork),
    button box("Undo",Undo)
   )
  )
 )
);

Re : Col list box() ne respecte pas la référence de la table de données

Ne répondant pas à votre vraie question, mais cela fonctionne (JMP 14.2 sur Mac):

 

dt = New Table( "Table 1",
 Add Rows( 0 ),
 Compress File When Saved( 1 ),
 New Column( "Column 1",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [] )
 ),
 New Column( "Column 2",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [] )
 ),
 New Column( "Column 3",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [] )
 )
);

dtNew = New Table( "Table 2",
 Add Rows( 0 ),
 Compress File When Saved( 1 ),
 New Column( "Column 4",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [] )
 ),
 New Column( "Column 5",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [] )
 ),
 New Column( "Column 6",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [] )
 )
);

new window("Column renamer",
 h list box(
  Panel box("Source table",
   SourceBox = Col List Box(DataTable( "Table 1"),All)
  ),
  Panel box("Destination table",
   DestBox = Col List Box(DataTable( "Table 2"),All),
  ),
 )
);