55340_ko-KR

liliconcom

IR 차트 레이블 및 LCL

나는 잘 작동하는 다음과 같은 스크립트를 가지고있다. 그것은 여러 개의 IR 차트를 생성하는데, 그 중 하나는 datatable의 유일한 값으로부터 생성 된리스트에 값을 기반으로한다.  각 차트에 생성 된 목록의 값과 동일한 레이블을 지정하고 싶습니다.  또한 모든 하위 컨트롤 한계를 0으로 설정하고 싶습니다.   나는 이것을하는 방법을 볼 수 없다.

 

summary (SNTime2, UnitNames = by (Column ( "Sub_name")));
count_UnitNames = nitems (UnitNames);

새 창 ( "M11 런타임 시간 요약 - 관리도",
V 목록 상자 (
for (i = 1, i = count_UnitNames, i ++,
관리도 (
샘플 레이블 (: 날짜),
그룹 크기 (1),
KSigma (3),
차트 색 (: 이름 ( "평균 (런타임)"), 개별 측정),
Where (: Sub_name == UnitNames [i]),
SendToReport (
급파(
{ "개별 측정 (평균 (런타임)"},
"2",
ScaleBox,
{Format ( "hr : m : s", 11, 0}}
))));
);
));

 

감사

Re : IR 차트 레이블 및 LCL

나는 당신에게 당신이 원하는 것을하기 위해 필요한 변화를 보여줄 것입니다, 그러나 JMP가 이것을 어떻게하는지 보여주기 때문에 당신이 스스로 이것을 알아낼 수 있다는 것을 보여줌으로써 그것을 할 것입니다.

귀하의 요청은 제목을 반복하여 생성 된 개요 상자의 이름을 변경하고, "평균 (런타임)의 개별 측정"  첫 번째 단계는 출력 중 하나에서 제목을 변경하는 것입니다.

그런 다음 빨간색 삼각형으로 이동하여 변경된 차트의 스크립트를 저장하십시오.

Control Chart(
 Sample Label( :Date ),
 Group Size( 1 ),
 KSigma( 3 ),
 Chart Col( :Name( "Mean(RunTime)" ), Individual Measurement( LCL( 0 ) ) ),
 Where( :Sub_name == UnitNames[i] ),
 SendToReport(
  Dispatch(
   {},
   "Individual Measurement of Mean(RunTime)",
   OutlineBox,
   {Set Title( "This is the title I want to have" )}
  ),
  Dispatch(
   {"Individual Measurement of Mean(RunTime)"},
   "2",
   ScaleBox,
   {Format( "hr:m:s", 13, 0 )}
  ),
  Dispatch(
   {"Individual Measurement of Mean(RunTime)"},
   "Control Chart Limits frame",
   FrameBox,
   {Frame Size( 64, 208 )}
  )
 )
);

개요 상자 제목을 다른 이름으로 만들기 위해 차트를 변경하는 방법을 JMP에서 설명한 방법에 유의하십시오.

Dispatch(
   {},
   "Individual Measurement of Mean(RunTime)",
   OutlineBox,
   {Set Title( "This is the title I want to have" )}
  )

이제해야 할 일은 스크립트에이 변경 사항을 다시 포함시키고, 요청한 Sub_name에 대한 목록 항목 인 UnitNames [i]의 제목을 대체하는 것입니다.

New Window( "M11 Runtime times Summary - Control Chart",
 V List Box(
  For( i = 1, i <= count_UnitNames, i++,
   Control Chart(
    Sample Label( :Date ),
    Group Size( 1 ),
    KSigma( 3 ),
    Chart Col( :Name( "Mean(Runtime)" ), Individual Measurement( LCL( 0 ) ) ),
    Where( :Sub_name == UnitNames[i] ),
    SendToReport(
    Dispatch(
     {},
     "Individual Measurement of Mean(RunTime)",
     OutlineBox,
     {Set Title( UnitNames[i] )}
    ),
     Dispatch(
      {"Individual Measurement of Mean(Runtime)"},
      "2",
      ScaleBox,
      {Format( "hr:m:s", 11, 0 )}
     )
    )
   )
  )
 )
);

 

Re : IR 차트 레이블 및 LCL

한계에 맞춰 주셔서 감사합니다. 

 

IR 차트의 이름은 어떻게 변경합니까?  수직 창에서 약 16-20 개의 차트를 생성합니다.  내가 테이블 데이터에서 만들 때 그들은 모두 Sub_name 열 값으로 레이블이 붙지 만, 스크립트에서 만들 때 "컨트롤 차트"와 "개별 측정 (평균)"이라는 레이블이 붙습니다.  각 차트에 UnitNames [i]의 값으로 레이블을 지정하고 싶습니다.

 

다시 한번 감사드립니다.

Re : IR 차트 레이블 및 LCL

이 문제를 해결하기 위해 취한 접근 방식은 저장된 한계 테이블을 사용하는 것이 었습니다. 여기서는 "0"값의 하한 만 지정되었으며 IM 차트 사양에서 LCL을 지정하는 예제도 있습니다.

Names Default To Here( 1 );

// Setup some sample data
SNTime2 = Open( "$SAMPLE_DATA/Quality Control/Phase Historical Data.jmp" );
SNTime2:Force << set name("Mean(RunTime)");
SNTime2:Site << set name("Sub_name") << data type( character );
SNTime2 << New Column("Date",format("m/d/y"),formula(today()));

// create a limits table with just a lower limit of zero and save it
dtlim = New Table( "Limits",
 Add Rows( 1 ),
 New Column("_LimitsKey",
  Character( 4 ),
  "Nominal",
  Set Values( {"_LCL"} )
 ),
 New Column("Mean(Runtime)",
  Numeric,
  "Continuous",
  Format( "Best", 10 ),
  Set Values( [0] ),
  Set Display Width
 )
);

close( dtlim, save("$TEMP\limits.jmp"));

// Run your code
Summarize( SNTime2, UnitNames = by( Column( "Sub_name" ) ) );
count_UnitNames = N Items( UnitNames );

New Window( "M11 Runtime times Summary - Control Chart",
 V List Box(
  For( i = 1, i <= count_UnitNames, i++,
   Control Chart(
    Sample Label( :Date ),
    Group Size( 1 ),
    KSigma( 3 ),
    Chart Col( :Name( "Mean(Runtime)" ), Individual Measurement ),
    // Read in limits
    Get Limits( "$TEMP\limits.jmp" ),
    Where( :Sub_name == UnitNames[i] ),
    SendToReport(
     Dispatch(
      {"Individual Measurement of Mean(Runtime)"},
      "2",
      ScaleBox,
      {Format( "hr:m:s", 11, 0 )}
     )
    )
   )
  )
 )
);

한계 테이블 사용에 관한 문서는 품질 및 프로세스 방법 서적에서 찾을 수 있습니다.

     도움말 ==> 서적 ==> 품질 및 프로세스

및 스크립팅 색인

     도움말 ==> 스크립트 색인 ==> 제어 차트

 

IM 차트에서 LCL 사양을 사용하여 동일한 결과를 얻을 수도 있습니다

// You can also just use the LCL paramater on the IM specification
Summarize( SNTime2, UnitNames = by( Column( "Sub_name" ) ) );
count_UnitNames = N Items( UnitNames );

New Window( "M11 Runtime times Summary - Control Chart",
 V List Box(
  For( i = 1, i <= count_UnitNames, i++,
   Control Chart(
    Sample Label( :Date ),
    Group Size( 1 ),
    KSigma( 3 ),
    Chart Col( :Name( "Mean(Runtime)" ), Individual Measurement( LCL(0)) ),
    Where( :Sub_name == UnitNames[i] ),
    SendToReport(
     Dispatch(
      {"Individual Measurement of Mean(Runtime)"},
      "2",
      ScaleBox,
      {Format( "hr:m:s", 11, 0 )}
     )
    )
   )
  )
 )
);