55340_ja-JP

liliconcom

IRチャートラベルとLCL

私はうまく機能する次のスクリプトを持っています、それはデータテーブルからのユニークな値から生成されたリストの値に基づいて複数のIRチャートを作成します。  各チャートには、それが生成されたリストの値と同じラベルを付けたいと思います。  私はまた、私の下限管理限界をすべて0に設定したいと思います。   私はこれをどうやってやるかわかりません。

 

（SNTime2、UnitNames = by（Column（ "Sub_name"）））;を要約します。
count_UnitNames = nitems（UnitNames）;

新しいウィンドウ（ "M11実行時間の概要 - 管理図"、、
Vリストボックス（
（i = 1、i <= count_UnitNames、i ++、
管理図（
サンプルラベル（：日付）、
グループサイズ（1）
Kシグマ（3）
チャートのCol（：名前（ "平均値（実行時間）"）、個人測定値）、
ここで（：Sub_name == UnitNames [i]）、
SendToReport（
ディスパッチ（
{"平均値の個別測定値（実行時）"}、
"2"、
ScaleBox、
{形式（ "hr：m：s"、11、0）}
）））
;
;）;

 

ありがとう

再：IRチャートラベルとLCL

私はあなたがあなたが望むことをするのに必要な変化をあなたに示すつもりです、しかし、私はJMPがあなたがこれを行う方法をあなたに示すので、あなたがすべて自分でこれを理解できることをあなたに示すことによってそれをします。

あなたの要求はタイトルを繰り返す作成されたアウトラインボックスの名前を変更することです、 「平均値の個別測定（実行時）」  したがって、最初のステップは、いずれかの出力でそのタイトルを変更することです。

それから赤い三角形に行き、変更された図表のためのスクリプトを保存してください

Control Chart(
 Sample Label( :Date ),
 Group Size( 1 ),
 KSigma( 3 ),
 Chart Col( :Name( "Mean(RunTime)" ), Individual Measurement( LCL( 0 ) ) ),
 Where( :Sub_name == UnitNames[i] ),
 SendToReport(
  Dispatch(
   {},
   "Individual Measurement of Mean(RunTime)",
   OutlineBox,
   {Set Title( "This is the title I want to have" )}
  ),
  Dispatch(
   {"Individual Measurement of Mean(RunTime)"},
   "2",
   ScaleBox,
   {Format( "hr:m:s", 13, 0 )}
  ),
  Dispatch(
   {"Individual Measurement of Mean(RunTime)"},
   "Control Chart Limits frame",
   FrameBox,
   {Frame Size( 64, 208 )}
  )
 )
);

アウトラインボックスのタイトルを別の名前にするためにJMPがチャートを変更する方法を示していることに注意してください。

Dispatch(
   {},
   "Individual Measurement of Mean(RunTime)",
   OutlineBox,
   {Set Title( "This is the title I want to have" )}
  )

さて、あなたがしなければならないのは、この変更をあなたのスクリプトに再組み込みし、UnitNames [i]のタイトルをあなたの要求されたSub_nameのあなたのリストエントリに置き換えることです。

New Window( "M11 Runtime times Summary - Control Chart",
 V List Box(
  For( i = 1, i <= count_UnitNames, i++,
   Control Chart(
    Sample Label( :Date ),
    Group Size( 1 ),
    KSigma( 3 ),
    Chart Col( :Name( "Mean(Runtime)" ), Individual Measurement( LCL( 0 ) ) ),
    Where( :Sub_name == UnitNames[i] ),
    SendToReport(
    Dispatch(
     {},
     "Individual Measurement of Mean(RunTime)",
     OutlineBox,
     {Set Title( UnitNames[i] )}
    ),
     Dispatch(
      {"Individual Measurement of Mean(Runtime)"},
      "2",
      ScaleBox,
      {Format( "hr:m:s", 11, 0 )}
     )
    )
   )
  )
 )
);

 

再：IRチャートラベルとLCL

限界のために働いてくれてありがとう。 

 

IRチャートの名前を変更する方法  私は垂直ウィンドウで約16から20のチャートを作成します。  テーブルデータから作成すると、それらはすべてSub_name列の値でラベル付けされますが、スクリプトから作成すると、「管理図」と「平均値の個別測定値（ランタイム）」のラベルが付けられます。  各チャートにUnitNames [i]の値でラベルを付けたいと思います。

 

再度、感謝します。

再：IRチャートラベルとLCL

この問題を解決するために行ったアプローチは、保存された制限テーブルを使用することでした。ここでは、値 "0"の下限だけが指定され、IMチャート仕様でLCLを指定する例も示されています。

Names Default To Here( 1 );

// Setup some sample data
SNTime2 = Open( "$SAMPLE_DATA/Quality Control/Phase Historical Data.jmp" );
SNTime2:Force << set name("Mean(RunTime)");
SNTime2:Site << set name("Sub_name") << data type( character );
SNTime2 << New Column("Date",format("m/d/y"),formula(today()));

// create a limits table with just a lower limit of zero and save it
dtlim = New Table( "Limits",
 Add Rows( 1 ),
 New Column("_LimitsKey",
  Character( 4 ),
  "Nominal",
  Set Values( {"_LCL"} )
 ),
 New Column("Mean(Runtime)",
  Numeric,
  "Continuous",
  Format( "Best", 10 ),
  Set Values( [0] ),
  Set Display Width
 )
);

close( dtlim, save("$TEMP\limits.jmp"));

// Run your code
Summarize( SNTime2, UnitNames = by( Column( "Sub_name" ) ) );
count_UnitNames = N Items( UnitNames );

New Window( "M11 Runtime times Summary - Control Chart",
 V List Box(
  For( i = 1, i <= count_UnitNames, i++,
   Control Chart(
    Sample Label( :Date ),
    Group Size( 1 ),
    KSigma( 3 ),
    Chart Col( :Name( "Mean(Runtime)" ), Individual Measurement ),
    // Read in limits
    Get Limits( "$TEMP\limits.jmp" ),
    Where( :Sub_name == UnitNames[i] ),
    SendToReport(
     Dispatch(
      {"Individual Measurement of Mean(Runtime)"},
      "2",
      ScaleBox,
      {Format( "hr:m:s", 11, 0 )}
     )
    )
   )
  )
 )
);

制限テーブルの使用法に関するドキュメントは、品質とプロセス方法の本にあります。

     ヘルプ==>本==>品質とプロセス

とスクリプティングインデックスに

     ヘルプ==>スクリプトインデックス==>管理図

 

IMチャートでLCL仕様を使用しても同じ結果が得られます。

// You can also just use the LCL paramater on the IM specification
Summarize( SNTime2, UnitNames = by( Column( "Sub_name" ) ) );
count_UnitNames = N Items( UnitNames );

New Window( "M11 Runtime times Summary - Control Chart",
 V List Box(
  For( i = 1, i <= count_UnitNames, i++,
   Control Chart(
    Sample Label( :Date ),
    Group Size( 1 ),
    KSigma( 3 ),
    Chart Col( :Name( "Mean(Runtime)" ), Individual Measurement( LCL(0)) ),
    Where( :Sub_name == UnitNames[i] ),
    SendToReport(
     Dispatch(
      {"Individual Measurement of Mean(Runtime)"},
      "2",
      ScaleBox,
      {Format( "hr:m:s", 11, 0 )}
     )
    )
   )
  )
 )
);