55340_de-DE

liliconcom

IR Chart Label und LCL

Ich habe das folgende Skript, das gut funktioniert. Es erstellt mehrere IR-Diagramme auf der Grundlage von Werten in einer Liste, die aus den eindeutigen Werten einer Datentabelle erstellt wird.  Ich möchte jedes Diagramm mit dem Wert in der Liste benennen, aus der es generiert wurde.  Ich möchte auch alle meine unteren Kontrollgrenzen auf 0 setzen.   Ich kann nicht sehen, wie das geht.

 

zusammengefassen (SNTime2, UnitNames = by (Column ("Sub_name")));
count_UnitNames = Titel (UnitNames);

Neues Fenster ("M11 Laufzeitzeiten - Übersicht")
V-Listenfeld (
für (i = 1, i <= count_UnitNames, i ++,
Steuerkarte (
Musteretikett (: Datum),
Gruppengröße (1),
KSigma (3),
Diagrammfarbe (: Name ("Mittelwert (Laufzeit)"), Einzelmessung)
Wobei (: Sub_name == UnitNames [i]),
SendToReport (
Versand(
{"Einzelmessung des Mittelwerts (Laufzeit)"},
"2",
ScaleBox,
{Format ("hr: m: s", 11, 0)}
)));
);
));

 

Vielen Dank

Re: IR Chart Label und LCL

Ich werde Ihnen die notwendigen Änderungen zeigen, um das zu tun, was Sie wollen, aber ich werde es tun, indem Sie Ihnen zeigen, dass Sie dies selbst herausfinden könnten, denn JMP zeigt Ihnen, wie Sie dies tun.

Ihre Anfrage besteht darin, den Namen der Gliederungsbox zu ändern, die erstellt wird, um den Titel zu wiederholen. Msgstr "Einzelne Mittelwertmessung (Laufzeit)".  Der erste Schritt besteht also darin, diesen Titel einfach in einem der Ausgänge zu ändern.

Gehen Sie dann zum roten Dreieck und speichern Sie das Skript für das geänderte Diagramm

Control Chart(
 Sample Label( :Date ),
 Group Size( 1 ),
 KSigma( 3 ),
 Chart Col( :Name( "Mean(RunTime)" ), Individual Measurement( LCL( 0 ) ) ),
 Where( :Sub_name == UnitNames[i] ),
 SendToReport(
  Dispatch(
   {},
   "Individual Measurement of Mean(RunTime)",
   OutlineBox,
   {Set Title( "This is the title I want to have" )}
  ),
  Dispatch(
   {"Individual Measurement of Mean(RunTime)"},
   "2",
   ScaleBox,
   {Format( "hr:m:s", 13, 0 )}
  ),
  Dispatch(
   {"Individual Measurement of Mean(RunTime)"},
   "Control Chart Limits frame",
   FrameBox,
   {Frame Size( 64, 208 )}
  )
 )
);

Beachten Sie, wie JMP angegeben hat, wie das Diagramm geändert werden soll, damit der Titel der Gliederungsbox einen anderen Namen erhält

Dispatch(
   {},
   "Individual Measurement of Mean(RunTime)",
   OutlineBox,
   {Set Title( "This is the title I want to have" )}
  )

Jetzt müssen Sie nur noch diese Änderung wieder in Ihr Skript integrieren und den Namen durch UnitNames [i] ersetzen. Dies ist Ihre Listeneinträge für den gewünschten Sub_Name

New Window( "M11 Runtime times Summary - Control Chart",
 V List Box(
  For( i = 1, i <= count_UnitNames, i++,
   Control Chart(
    Sample Label( :Date ),
    Group Size( 1 ),
    KSigma( 3 ),
    Chart Col( :Name( "Mean(Runtime)" ), Individual Measurement( LCL( 0 ) ) ),
    Where( :Sub_name == UnitNames[i] ),
    SendToReport(
    Dispatch(
     {},
     "Individual Measurement of Mean(RunTime)",
     OutlineBox,
     {Set Title( UnitNames[i] )}
    ),
     Dispatch(
      {"Individual Measurement of Mean(Runtime)"},
      "2",
      ScaleBox,
      {Format( "hr:m:s", 11, 0 )}
     )
    )
   )
  )
 )
);

 

Re: IR Chart Label und LCL

Danke, das funktioniert für die Grenzen. 

 

Wie ändere ich den Namen der IR-Karten?  Ich produziere ungefähr 16 bis 20 Diagramme in einem vertikalen Fenster.  Wenn ich sie aus den Tabellendaten erstelle, werden sie alle mit dem Spaltenwert "Sub_name" beschriftet, aber wenn ich sie aus dem Skript erstellt habe, werden sie mit "Kontrolldiagramm" und "Einzelne Messung des Mittelwerts (Laufzeit)" bezeichnet.  Ich möchte, dass jedes Diagramm mit dem Wert in UnitNames [i] gekennzeichnet wird.

 

Danke noch einmal.

Re: IR Chart Label und LCL

Bei der Lösung dieses Problems habe ich eine gespeicherte Grenzwerttabelle verwendet, in der nur ein unterer Grenzwert mit dem Wert "0" angegeben ist. Außerdem wurde ein Beispiel für die Angabe der LCL in der IM-Diagrammspezifikation angegeben.

Names Default To Here( 1 );

// Setup some sample data
SNTime2 = Open( "$SAMPLE_DATA/Quality Control/Phase Historical Data.jmp" );
SNTime2:Force << set name("Mean(RunTime)");
SNTime2:Site << set name("Sub_name") << data type( character );
SNTime2 << New Column("Date",format("m/d/y"),formula(today()));

// create a limits table with just a lower limit of zero and save it
dtlim = New Table( "Limits",
 Add Rows( 1 ),
 New Column("_LimitsKey",
  Character( 4 ),
  "Nominal",
  Set Values( {"_LCL"} )
 ),
 New Column("Mean(Runtime)",
  Numeric,
  "Continuous",
  Format( "Best", 10 ),
  Set Values( [0] ),
  Set Display Width
 )
);

close( dtlim, save("$TEMP\limits.jmp"));

// Run your code
Summarize( SNTime2, UnitNames = by( Column( "Sub_name" ) ) );
count_UnitNames = N Items( UnitNames );

New Window( "M11 Runtime times Summary - Control Chart",
 V List Box(
  For( i = 1, i <= count_UnitNames, i++,
   Control Chart(
    Sample Label( :Date ),
    Group Size( 1 ),
    KSigma( 3 ),
    Chart Col( :Name( "Mean(Runtime)" ), Individual Measurement ),
    // Read in limits
    Get Limits( "$TEMP\limits.jmp" ),
    Where( :Sub_name == UnitNames[i] ),
    SendToReport(
     Dispatch(
      {"Individual Measurement of Mean(Runtime)"},
      "2",
      ScaleBox,
      {Format( "hr:m:s", 11, 0 )}
     )
    )
   )
  )
 )
);

Informationen zur Verwendung von Grenzwerttabellen finden Sie im Buch Qualitäts- und Prozessmethoden

     Hilfe ==> Bücher ==> Qualität und Prozess

und im Scripting Index

     Hilfe ==> Skriptindex ==> Kontrolldiagramm

 

Sie können auch die LCL-Spezifikation im IM-Diagramm verwenden, um dieselben Ergebnisse zu erhalten

// You can also just use the LCL paramater on the IM specification
Summarize( SNTime2, UnitNames = by( Column( "Sub_name" ) ) );
count_UnitNames = N Items( UnitNames );

New Window( "M11 Runtime times Summary - Control Chart",
 V List Box(
  For( i = 1, i <= count_UnitNames, i++,
   Control Chart(
    Sample Label( :Date ),
    Group Size( 1 ),
    KSigma( 3 ),
    Chart Col( :Name( "Mean(Runtime)" ), Individual Measurement( LCL(0)) ),
    Where( :Sub_name == UnitNames[i] ),
    SendToReport(
     Dispatch(
      {"Individual Measurement of Mean(Runtime)"},
      "2",
      ScaleBox,
      {Format( "hr:m:s", 11, 0 )}
     )
    )
   )
  )
 )
);