55340_zh-TW

liliconcom

紅外圖表標籤和拼箱

我有以下腳本運行良好，它根據數據表中的唯一值生成的列表中的值創建多個IR圖表。  我想將每個圖表標記為與其生成的列表中的值相同。  我還想將我的所有控制下限設置為0。   我看不出怎麼做。

 

總結（SNTime2，UnitNames = by（Column（“Sub_name”）））;
count_UnitNames = nitems（UnitNames）;

新窗口（“M11運行時間摘要 - 控製圖”，
V列錶框（
for（i = 1，i <= count_UnitNames，i ++，
控製圖（
樣品標籤（：日期），
團體規模（1），
KSigma（3），
圖表Col（：名稱（“平均值（運行時間）”），個人測量值），
Where（：Sub_name == UnitNames [i]），
SendToReport（
調度（
{“個人測量平均值（運行時間）}}，
“2”，
ScaleBox，
{格式（“hr：m：s”，11,0）}
）））;
）;
））;

 

謝謝

回复：IR圖表標籤和拼箱

我會告訴你做你想做的所需的改變，但是，我會告訴你你可以自己解決這個問題，因為JMP會告訴你如何做到這一點。

您的請求是更改重複標題創建的大綱框的名稱， “平均值（運行時間）的單獨測量”。  因此，第一步是簡單地在其中一個輸出中更改該標題。

然後轉到紅色三角形並保存更改圖表的腳本

Control Chart(
 Sample Label( :Date ),
 Group Size( 1 ),
 KSigma( 3 ),
 Chart Col( :Name( "Mean(RunTime)" ), Individual Measurement( LCL( 0 ) ) ),
 Where( :Sub_name == UnitNames[i] ),
 SendToReport(
  Dispatch(
   {},
   "Individual Measurement of Mean(RunTime)",
   OutlineBox,
   {Set Title( "This is the title I want to have" )}
  ),
  Dispatch(
   {"Individual Measurement of Mean(RunTime)"},
   "2",
   ScaleBox,
   {Format( "hr:m:s", 13, 0 )}
  ),
  Dispatch(
   {"Individual Measurement of Mean(RunTime)"},
   "Control Chart Limits frame",
   FrameBox,
   {Frame Size( 64, 208 )}
  )
 )
);

請注意JMP如何指示如何更改圖表以使“大綱框”標題成為不同的名稱

Dispatch(
   {},
   "Individual Measurement of Mean(RunTime)",
   OutlineBox,
   {Set Title( "This is the title I want to have" )}
  )

現在您需要做的就是將此更改重新納入您的腳本，並將標題替換為UnitNames [i]，這是您請求的Sub_name的列表條目

New Window( "M11 Runtime times Summary - Control Chart",
 V List Box(
  For( i = 1, i <= count_UnitNames, i++,
   Control Chart(
    Sample Label( :Date ),
    Group Size( 1 ),
    KSigma( 3 ),
    Chart Col( :Name( "Mean(Runtime)" ), Individual Measurement( LCL( 0 ) ) ),
    Where( :Sub_name == UnitNames[i] ),
    SendToReport(
    Dispatch(
     {},
     "Individual Measurement of Mean(RunTime)",
     OutlineBox,
     {Set Title( UnitNames[i] )}
    ),
     Dispatch(
      {"Individual Measurement of Mean(Runtime)"},
      "2",
      ScaleBox,
      {Format( "hr:m:s", 11, 0 )}
     )
    )
   )
  )
 )
);

 

回复：IR圖表標籤和拼箱

謝謝你，這是有限的。 

 

如何更改IR圖表的名稱。  我在垂直窗口中生成大約16到20個圖表。  當我從表數據創建它時，它們都用Sub_name列值標記，但是當我從腳本創建它時，它們被標記為“控製圖”和“單獨測量平均值（運行時間）”。  我希望每個圖表都標有UnitNames [i]中的值。

 

再次感謝。

回复：IR圖表標籤和拼箱

我用來解決此問題的方法是使用保存的限製表，其中僅指定值為“0”的下限，並且還指定了IM圖表規範中的LCL的示例。

Names Default To Here( 1 );

// Setup some sample data
SNTime2 = Open( "$SAMPLE_DATA/Quality Control/Phase Historical Data.jmp" );
SNTime2:Force << set name("Mean(RunTime)");
SNTime2:Site << set name("Sub_name") << data type( character );
SNTime2 << New Column("Date",format("m/d/y"),formula(today()));

// create a limits table with just a lower limit of zero and save it
dtlim = New Table( "Limits",
 Add Rows( 1 ),
 New Column("_LimitsKey",
  Character( 4 ),
  "Nominal",
  Set Values( {"_LCL"} )
 ),
 New Column("Mean(Runtime)",
  Numeric,
  "Continuous",
  Format( "Best", 10 ),
  Set Values( [0] ),
  Set Display Width
 )
);

close( dtlim, save("$TEMP\limits.jmp"));

// Run your code
Summarize( SNTime2, UnitNames = by( Column( "Sub_name" ) ) );
count_UnitNames = N Items( UnitNames );

New Window( "M11 Runtime times Summary - Control Chart",
 V List Box(
  For( i = 1, i <= count_UnitNames, i++,
   Control Chart(
    Sample Label( :Date ),
    Group Size( 1 ),
    KSigma( 3 ),
    Chart Col( :Name( "Mean(Runtime)" ), Individual Measurement ),
    // Read in limits
    Get Limits( "$TEMP\limits.jmp" ),
    Where( :Sub_name == UnitNames[i] ),
    SendToReport(
     Dispatch(
      {"Individual Measurement of Mean(Runtime)"},
      "2",
      ScaleBox,
      {Format( "hr:m:s", 11, 0 )}
     )
    )
   )
  )
 )
);

有關限製表使用的文檔可以在“質量和過程方法”一書中找到

     幫助==>書籍==>質量和流程

並在腳本索引中

     幫助==>腳本索引==>控製圖

 

您也可以在IM圖表上使用LCL規範來獲得相同的結果

// You can also just use the LCL paramater on the IM specification
Summarize( SNTime2, UnitNames = by( Column( "Sub_name" ) ) );
count_UnitNames = N Items( UnitNames );

New Window( "M11 Runtime times Summary - Control Chart",
 V List Box(
  For( i = 1, i <= count_UnitNames, i++,
   Control Chart(
    Sample Label( :Date ),
    Group Size( 1 ),
    KSigma( 3 ),
    Chart Col( :Name( "Mean(Runtime)" ), Individual Measurement( LCL(0)) ),
    Where( :Sub_name == UnitNames[i] ),
    SendToReport(
     Dispatch(
      {"Individual Measurement of Mean(Runtime)"},
      "2",
      ScaleBox,
      {Format( "hr:m:s", 11, 0 )}
     )
    )
   )
  )
 )
);