50206_fr-FR

liliconcom

Définir la taille du cadre pour plusieurs graphiques

Mon script actuel me donne plusieurs graphiques selon les différents produits. C'est ce que je recherche.

Maintenant, j'aimerais que tous ces graphiques aient la même taille de cadre. Je constate que je dois être précis lorsque j'utilise dispatch et que je dois écrire chaque nom de plan.

Le problème, c'est qu'il y aura des produits différents à chaque fois que je l'exécuterai et je préférerais ne pas avoir à changer les noms à chaque fois.

 

Existe-t-il un moyen d'automatiser cela.

Data Table( "Data for Comparison" ) << Variability Chart(
 Y( Column( "Mean(Bin_VALUE)" ) ),
 X( :Bin_Size, :Status_Type2 ),
 By( :Product ),
 Show Box Plots( 1 ),
 Std Dev Chart( 0 ),
 SendToReport(
  Dispatch(
   {"Variability Gauge Product= Product 1", "Variability Chart for Mean(Bin_VALUE)"},
   "Variability Chart",
   FrameBox,
   {Frame Size( 800, 240 )}
  ), 

 )
);

Re : Définir la taille du cadre pour plusieurs graphiques

Ma solution est essentiellement la même que la réponse de Jim. J'ai enregistré une référence à la plate-forme de traçage, puis je l'ai utilisée avec un indice pour envoyer le message. Jim a utilisé XPath pour renvoyer la référence avant d'envoyer le message. Vous devrez stocker la référence lorsque vous ouvrez chaque plateforme dans une liste, puis envoyer le message à la liste si vous souhaitez utiliser mon approche. Par exemple:

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

platform = List();

p = dt << Bivariate(
 Y( :weight ),
 X( :height ),
);

Insert Into( platform, Report( p )[FrameBox(1)] );

p = dt << Oneway(
 Y( :weight ),
 X( :age ),
);

Insert Into( platform, Report( p )[FrameBox(1)] );

platform << Frame Size( 800, 240 );

 

La solution de Jim est plus élégante.

Il n'y a aucune mention ci-dessus sur la sélection des zones d'affichage afin qu'elles soient surlignées en bleu. Ce résultat est obtenu avec le << Sélectionner message.

Re : Définir la taille du cadre pour plusieurs graphiques

Marque,

 

J'ai essayé cela mais aucun des graphiques n'a changé de taille. Cela n'a pas fonctionné.

Je suis très nouveau dans le script JMP, donc je suis désolé si cette observation n'est pas utile, mais une chose que j'ai remarquée lorsque j'ai collé votre script est que la plate-forme n'est pas devenue bleue.

Je ne sais pas s'il y a autre chose qui me manque.

Re : Définir la taille du cadre pour plusieurs graphiques

Jim,

 

Cela a fonctionné.

 

Puis-je utiliser le même concept dans le scénario ci-dessous, afin de définir les titres. Sans avoir à taper chacun d’eux.

Alors partez de là

Template_TM = Expr(
 TM = Oneway(
  Y( Eval( TargetParameter )),
  X( :Process ),
  Each Pair( 1 ),
  Means and Std Dev( 1 ),
  t Test( 1 ),
  Points Jittered( 1 ),
  Box Plots( 1 ),
  Mean Error Bars( 1 ),
  Std Dev Lines( 1 ),
  Comparison Circles( 1 ),
  X Axis Proportional( 0),
  Histograms( 0),
  //Where( :PARAMETER_ID == Eval( TargetParameter )),
  SendToReport(
   Dispatch( {}, "Oneway Analysis of 0.12 By Process", OutlineBox(1), {Set Title( TargetProduct ||"_Oneway Analysis at_" || TargetParameter )} ),
   Dispatch( {}, "Oneway Analysis of 0.16 By Process", OutlineBox(1), {Set Title( TargetProduct ||"_Oneway Analysis at_" || TargetParameter )} ),
   Dispatch( {}, "Oneway Analysis of 0.2 By Process", OutlineBox(1), {Set Title( TargetProduct ||"_Oneway Analysis at_" || TargetParameter )} ),
   Dispatch( {}, "Oneway Analysis of 0.3 By Process", OutlineBox(1), {Set Title( TargetProduct ||"_Oneway Analysis at_" || TargetParameter )} ),
   Dispatch( {}, "1", ScaleBox, {Min( 0 ), Minor Ticks( 1 ), Add Ref Line(Eval(Limit_UCL), "Dotted", "Dark Blue", "UCL", 1)}),
   Dispatch( {}, "Oneway Plot", FrameBox, ),
   Dispatch( {}, "Means Comparisons", OutlineBox, {Close( 1 )} )
  )
 );
);

pour ça?

Template_TM = Expr(
 TM = Oneway(
  Y( Eval( TargetParameter )),
  X( :Process ),
  Each Pair( 1 ),
  Means and Std Dev( 1 ),
  t Test( 1 ),
  Points Jittered( 1 ),
  Box Plots( 1 ),
  Mean Error Bars( 1 ),
  Std Dev Lines( 1 ),
  Comparison Circles( 1 ),
  X Axis Proportional( 0),
  Histograms( 0),
  //Where( :PARAMETER_ID == Eval( TargetParameter )),
  SendToReport(
   Dispatch( {}, "1", ScaleBox, {Min( 0 ), Minor Ticks( 1 ), Add Ref Line(Eval(Limit_UCL), "Dotted", "Dark Blue", "UCL", 1)}),
   Dispatch( {}, "Oneway Plot", FrameBox, ),
   Dispatch( {}, "Means Comparisons", OutlineBox, {Close( 1 )} )
  )
 );
);
(TM<<XPATH></XPATH>

Re : Définir la taille du cadre pour plusieurs graphiques

Le fait est que nous ne sommes pas censés utiliser le Envoyer au rapport directif. Cette méthode est uniquement destinée à permettre à JMP de capturer les personnalisations de la couche de rapport lorsque vous enregistrez un script. Essayez la méthode recommandée :

platform = Data Table( "Data for Comparison" ) << Variability Chart(
 Y( Column( "Mean(Bin_VALUE)" ) ),
 X( :Bin_Size, :Status_Type2 ),
 By( :Product ),
 Show Box Plots( 1 ),
 Std Dev Chart( 0 )
);

Report( platform )[FrameBox(1)] << Frame Size( 800, 240 );

Facile, hein ?

 

Re : Définir la taille du cadre pour plusieurs graphiques

Vous pouvez utiliser XPath pour récupérer tous les objets FrameBox(), puis définir la taille du cadre sur chacun d'eux.

vc = Data Table( "Data for Comparison" ) << Variability Chart(
 Y( Column( "Mean(Bin_VALUE)" ) ),
 X( :Bin_Size, :Status_Type2 ),
 By( :Product ),
 Show Box Plots( 1 ),
 Std Dev Chart( 0 ),
);

(Report(vc) << xpath("//FrameBox")) << Frame Size( 800, 240 );

Re : Définir la taille du cadre pour plusieurs graphiques

Salut Txnelson,

Merci pour cette solution ! Comment puis-je l'utiliser pour appliquer les mêmes commandes DispatchSeg() à tous mes tracés ? Mon script contient actuellement le code suivant pour TOUS mes 12+ tracés :

Dispatch(
			{"Variability Gauge Analysis for Plot1",
			"Variability Chart for Plot1"},
			"Variability Chart",
			FrameBox,
			{Frame Size( 400, 200 ),
			DispatchSeg( Box Plot Seg( 1 ), Line Color( "Black" ) ),
			DispatchSeg( Box Plot Seg( 2 ), Line Color( "Black" ) ),
			DispatchSeg( Box Plot Seg( 3 ), Line Color( "Black" ) ),
			DispatchSeg( Box Plot Seg( 4 ), Line Color( "Black" ) ),
			DispatchSeg( Box Plot Seg( 5 ), Line Color( "Black" ) ),
			DispatchSeg( Box Plot Seg( 6 ), Line Color( "Black" ) ),
			DispatchSeg( Box Plot Seg( 7 ), Line Color( "Black" ) ),
			DispatchSeg( Box Plot Seg( 8 ), Line Color( "Black" ) ),
			DispatchSeg( Box Plot Seg( 9 ), Line Color( "Black" ) ),
			DispatchSeg( Box Plot Seg( 10 ), Line Color( "Black" ) ),
			DispatchSeg( Box Plot Seg( 11 ), Line Color( "Black" ) ),
			DispatchSeg( Box Plot Seg( 12 ), Line Color( "Black" ) )
			}
		)

J'ai essayé ceci, mais ça n'a pas fonctionné :

fb = {Frame Size( 400, 200 ),
	DispatchSeg( Box Plot Seg( 1 ), Line Color( "Black" ) ),
	DispatchSeg( Box Plot Seg( 2 ), Line Color( "Black" ) ),
	DispatchSeg( Box Plot Seg( 3 ), Line Color( "Black" ) ),
	DispatchSeg( Box Plot Seg( 4 ), Line Color( "Black" ) ),
	DispatchSeg( Box Plot Seg( 5 ), Line Color( "Black" ) ),
	DispatchSeg( Box Plot Seg( 6 ), Line Color( "Black" ) ),
	DispatchSeg( Box Plot Seg( 7 ), Line Color( "Black" ) ),
	DispatchSeg( Box Plot Seg( 8 ), Line Color( "Black" ) ),
	DispatchSeg( Box Plot Seg( 9 ), Line Color( "Black" ) ),
	DispatchSeg( Box Plot Seg( 10 ), Line Color( "Black" ) ),
	DispatchSeg( Box Plot Seg( 11 ), Line Color( "Black" ) ),
	DispatchSeg( Box Plot Seg( 12 ), Line Color( "Black" ) )
};
(Report(vc) << xpath("//FrameBox")) << fb;

Merci d'avance!

Re : Définir la taille du cadre pour plusieurs graphiques

depuis:
https://community.jmp.com/t5/Discussions/Change-the-default-color-of-box-plot-lines/mp/762414/highlight/true#M94163

Names Default to Here(1);
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
	
myPlot = Variability Chart(
	Y( :height ),
	X( :age ),
	Variability Analysis( :height, Show Box Plots( 1 ) )
);

mySegs=report(myPlot)[FrameBox(1)]<< find segs; // get all display elements
Filter Each({seg},(mySegs), (seg<< class name)=="BoxPlotSeg") //just keep the Box Plots
 << Set Line Color("Black")