50206_ko-KR

liliconcom

여러 차트의 프레임 크기 설정

내 현재 스크립트는 다른 제품별로 여러 차트를 제공합니다. 내가 찾고 있는 것입니다.

이제 모든 차트의 프레임 크기를 동일하게 만들고 싶습니다. 나는 디스패치를 사용할 때 구체적이어야 하고 모든 단일 개요 이름을 작성해야 한다는 것을 알게 되었습니다.

문제는 실행할 때마다 다른 제품이 있을 것이고 매번 이름을 변경하지 않아도 된다는 점입니다.

 

이것을 자동화하는 방법이 있습니까?

Data Table( "Data for Comparison" ) << Variability Chart(
 Y( Column( "Mean(Bin_VALUE)" ) ),
 X( :Bin_Size, :Status_Type2 ),
 By( :Product ),
 Show Box Plots( 1 ),
 Std Dev Chart( 0 ),
 SendToReport(
  Dispatch(
   {"Variability Gauge Product= Product 1", "Variability Chart for Mean(Bin_VALUE)"},
   "Variability Chart",
   FrameBox,
   {Frame Size( 800, 240 )}
  ), 

 )
);

Re: 여러 차트의 프레임 크기 설정

내 솔루션은 본질적으로 Jim의 답변과 동일합니다. 플로팅 플랫폼에 대한 참조를 저장한 다음 첨자를 사용하여 메시지를 보냈습니다. Jim은 메시지를 보내기 전에 XPath를 사용하여 참조를 반환했습니다. 내 접근 방식을 사용하려면 목록에서 각 플랫폼을 열 때 참조를 저장한 다음 목록에 메시지를 보내야 합니다. 예를 들어:

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

platform = List();

p = dt << Bivariate(
 Y( :weight ),
 X( :height ),
);

Insert Into( platform, Report( p )[FrameBox(1)] );

p = dt << Oneway(
 Y( :weight ),
 X( :age ),
);

Insert Into( platform, Report( p )[FrameBox(1)] );

platform << Frame Size( 800, 240 );

 

Jim의 솔루션은 더 우아합니다.

디스플레이 상자를 선택하는 방법에 대해서는 위에서 언급하지 않았으므로 파란색으로 강조 표시됩니다. 그 결과는 << 고르다 메시지.

Re: 여러 차트의 프레임 크기 설정

표시,

 

나는 이것을 시도했지만 차트 중 어느 것도 크기를 변경하지 않았습니다. 그것은 작동하지 않았다.

저는 JMP scipting을 처음 접했기 때문에 이 관찰이 도움이 되지 않았다면 유감이지만 스크립트를 붙여넣을 때 알게 된 한 가지는 플랫폼이 파란색으로 바뀌지 않았다는 것입니다.

내가 놓친 다른 것이 있는지 확실하지 않습니다.

Re: 여러 차트의 프레임 크기 설정

짐,

 

이것은 효과가 있었다.

 

제목을 설정하기 위해 아래 시나리오에서 동일한 개념을 사용할 수 있습니까? 하나하나 입력하지 않아도 됩니다.

그래서 이것에서 가십시오.

Template_TM = Expr(
 TM = Oneway(
  Y( Eval( TargetParameter )),
  X( :Process ),
  Each Pair( 1 ),
  Means and Std Dev( 1 ),
  t Test( 1 ),
  Points Jittered( 1 ),
  Box Plots( 1 ),
  Mean Error Bars( 1 ),
  Std Dev Lines( 1 ),
  Comparison Circles( 1 ),
  X Axis Proportional( 0),
  Histograms( 0),
  //Where( :PARAMETER_ID == Eval( TargetParameter )),
  SendToReport(
   Dispatch( {}, "Oneway Analysis of 0.12 By Process", OutlineBox(1), {Set Title( TargetProduct ||"_Oneway Analysis at_" || TargetParameter )} ),
   Dispatch( {}, "Oneway Analysis of 0.16 By Process", OutlineBox(1), {Set Title( TargetProduct ||"_Oneway Analysis at_" || TargetParameter )} ),
   Dispatch( {}, "Oneway Analysis of 0.2 By Process", OutlineBox(1), {Set Title( TargetProduct ||"_Oneway Analysis at_" || TargetParameter )} ),
   Dispatch( {}, "Oneway Analysis of 0.3 By Process", OutlineBox(1), {Set Title( TargetProduct ||"_Oneway Analysis at_" || TargetParameter )} ),
   Dispatch( {}, "1", ScaleBox, {Min( 0 ), Minor Ticks( 1 ), Add Ref Line(Eval(Limit_UCL), "Dotted", "Dark Blue", "UCL", 1)}),
   Dispatch( {}, "Oneway Plot", FrameBox, ),
   Dispatch( {}, "Means Comparisons", OutlineBox, {Close( 1 )} )
  )
 );
);

이에?

Template_TM = Expr(
 TM = Oneway(
  Y( Eval( TargetParameter )),
  X( :Process ),
  Each Pair( 1 ),
  Means and Std Dev( 1 ),
  t Test( 1 ),
  Points Jittered( 1 ),
  Box Plots( 1 ),
  Mean Error Bars( 1 ),
  Std Dev Lines( 1 ),
  Comparison Circles( 1 ),
  X Axis Proportional( 0),
  Histograms( 0),
  //Where( :PARAMETER_ID == Eval( TargetParameter )),
  SendToReport(
   Dispatch( {}, "1", ScaleBox, {Min( 0 ), Minor Ticks( 1 ), Add Ref Line(Eval(Limit_UCL), "Dotted", "Dark Blue", "UCL", 1)}),
   Dispatch( {}, "Oneway Plot", FrameBox, ),
   Dispatch( {}, "Means Comparisons", OutlineBox, {Close( 1 )} )
  )
 );
);
(TM<<XPATH></XPATH>

Re: 여러 차트의 프레임 크기 설정

사실, 우리는 보고서로 보내기 지령. 이 방법은 스크립트를 저장할 때 JMP가 보고서 계층 사용자 정의를 캡처할 수 있도록 하기 위한 것입니다. 권장되는 방법을 시도하십시오.

platform = Data Table( "Data for Comparison" ) << Variability Chart(
 Y( Column( "Mean(Bin_VALUE)" ) ),
 X( :Bin_Size, :Status_Type2 ),
 By( :Product ),
 Show Box Plots( 1 ),
 Std Dev Chart( 0 )
);

Report( platform )[FrameBox(1)] << Frame Size( 800, 240 );

쉽게, 응?

 

Re: 여러 차트의 프레임 크기 설정

XPath를 사용하여 모든 FrameBox() 개체를 검색한 다음 프레임 크기를 모든 개체로 설정할 수 있습니다.

vc = Data Table( "Data for Comparison" ) << Variability Chart(
 Y( Column( "Mean(Bin_VALUE)" ) ),
 X( :Bin_Size, :Status_Type2 ),
 By( :Product ),
 Show Box Plots( 1 ),
 Std Dev Chart( 0 ),
);

(Report(vc) << xpath("//FrameBox")) << Frame Size( 800, 240 );

Re: 여러 차트의 프레임 크기 설정

안녕하십니까?

이 솔루션에 감사드립니다! 모든 플롯에 동일한 DispatchSeg() 명령을 적용하기 위해 이것을 어떻게 사용할 수 있습니까? 현재 내 스크립트에는 12개 이상의 모든 플롯에 대해 다음 코드가 있습니다.

Dispatch(
			{"Variability Gauge Analysis for Plot1",
			"Variability Chart for Plot1"},
			"Variability Chart",
			FrameBox,
			{Frame Size( 400, 200 ),
			DispatchSeg( Box Plot Seg( 1 ), Line Color( "Black" ) ),
			DispatchSeg( Box Plot Seg( 2 ), Line Color( "Black" ) ),
			DispatchSeg( Box Plot Seg( 3 ), Line Color( "Black" ) ),
			DispatchSeg( Box Plot Seg( 4 ), Line Color( "Black" ) ),
			DispatchSeg( Box Plot Seg( 5 ), Line Color( "Black" ) ),
			DispatchSeg( Box Plot Seg( 6 ), Line Color( "Black" ) ),
			DispatchSeg( Box Plot Seg( 7 ), Line Color( "Black" ) ),
			DispatchSeg( Box Plot Seg( 8 ), Line Color( "Black" ) ),
			DispatchSeg( Box Plot Seg( 9 ), Line Color( "Black" ) ),
			DispatchSeg( Box Plot Seg( 10 ), Line Color( "Black" ) ),
			DispatchSeg( Box Plot Seg( 11 ), Line Color( "Black" ) ),
			DispatchSeg( Box Plot Seg( 12 ), Line Color( "Black" ) )
			}
		)

나는 이것을 시도했지만 작동하지 않았습니다.

fb = {Frame Size( 400, 200 ),
	DispatchSeg( Box Plot Seg( 1 ), Line Color( "Black" ) ),
	DispatchSeg( Box Plot Seg( 2 ), Line Color( "Black" ) ),
	DispatchSeg( Box Plot Seg( 3 ), Line Color( "Black" ) ),
	DispatchSeg( Box Plot Seg( 4 ), Line Color( "Black" ) ),
	DispatchSeg( Box Plot Seg( 5 ), Line Color( "Black" ) ),
	DispatchSeg( Box Plot Seg( 6 ), Line Color( "Black" ) ),
	DispatchSeg( Box Plot Seg( 7 ), Line Color( "Black" ) ),
	DispatchSeg( Box Plot Seg( 8 ), Line Color( "Black" ) ),
	DispatchSeg( Box Plot Seg( 9 ), Line Color( "Black" ) ),
	DispatchSeg( Box Plot Seg( 10 ), Line Color( "Black" ) ),
	DispatchSeg( Box Plot Seg( 11 ), Line Color( "Black" ) ),
	DispatchSeg( Box Plot Seg( 12 ), Line Color( "Black" ) )
};
(Report(vc) << xpath("//FrameBox")) << fb;

미리 감사드립니다!

Re: 여러 차트의 프레임 크기 설정

에서:
https://community.jmp.com/t5/Discussions/Change-the-default-color-of-box-plot-lines/mp/762414/highlight/true#M94163

Names Default to Here(1);
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
	
myPlot = Variability Chart(
	Y( :height ),
	X( :age ),
	Variability Analysis( :height, Show Box Plots( 1 ) )
);

mySegs=report(myPlot)[FrameBox(1)]<< find segs; // get all display elements
Filter Each({seg},(mySegs), (seg<< class name)=="BoxPlotSeg") //just keep the Box Plots
 << Set Line Color("Black")