35842_fr-FR

liliconcom

Changer les titres pour aller simple

Mon script ci-dessous, le premier script, ne reconnaîtra aucune modification que j'apporte au titre de l'ensemble. Il reste par défaut sur "Analyse à sens unique de PARAMETER_VALUE par statut" quel que soit ce que j'entre pour le titre défini.

J'ai un script pour la distribution, un deuxième script, et je ne semble pas avoir de problèmes avec, donc je ne suis pas sûr de ce qui se passe.

 

Des idées sur ce que je dois changer ?

 

Merci

 

 

 

Template_TM = Expr(
 TM = Oneway(
  Y(:PARAMETER_VALUE),
  X(:Status),
  Each Pair(1),
  Means and Std Dev(1),
  t Test(1),
  Points Jittered(1),
  Box Plots(1),
  Mean Error Bars(1),
  Std Dev Lines(1),
  Comparison Circles(1),
  X Axis Proportional(0),
  Histograms(0),
  Where(:PARAMETER_ID == Eval(TargetParameter)),
  SendToReport(
   Dispatch({}, "Oneway Analysis of MEAS_DATA By Status", OutlineBox, {Set Title( TargetParameter )}),
   Dispatch({}, "1", ScaleBox, {Scale("Log"), Min(0.0001), Max(5), Inc(1), Minor Ticks(1), Label Row Nesting(1), Add Ref Line(Eval(Limit_UCL), "Dotted", "Dark Blue", "UCL", 1)}),
   Dispatch({}, "MEAS_DATA", TextEditBox, {Set Text("E10 Atoms / cm2")}),
   Dispatch({}, "Oneway Plot", FrameBox,),
   Dispatch({}, "Means Comparisons", OutlineBox, {Close(1)})
  )
 )
);

 

Template_CAP = Expr(

 CAP01 =
  Distribution(
  Continuous Distribution(
  Column(:PARAMETER_VALUE),
  Quantiles(0),
  Horizontal Layout(1),
  Vertical(0),
  Capability Analysis(USL(Eval(Limit_UCL)))),
  Where(:PARAMETER_ID == Eval(TargetParameter) & :Status == "1) POR"),
  SendToReport(
   Dispatch({},"Distributions",OutlineBox,{Set Title( TargetParameter )}),
   Dispatch({"Distribution 1) POR", "PARAMETER_VALUE"},"1",ScaleBox,{Format("Fixed Dec", 15, 3), Min(0), Max(2), Inc(0.2),Minor Ticks(1), Label Row Nesting(1)}),
   Dispatch({"Distributions", "PARAMETER_VALUE"},"Distrib Histogram",FrameBox,{DispatchSeg(LabelSeg(1), {Font("Tw Cen MT", 7, "Plain")})}),
   Dispatch({"Distributions", "PARAMETER_VALUE", "Capability Analysis", " Long Term Sigma"}, "1", ScaleBox, {Format("Fixed Dec", 9, 3), Min(-2), Max(2), Inc(0.5), Minor Ticks(0), Label Row Nesting(1)})
  )
 );

 

Re : Changer les titres pour aller simple

Ha! Je n'ai même pas vu cela, car j'ai dû changer tout le titre pour que cela fonctionne du tout avec ma tentative unique. Content que tu l'aies vu

Re : Changer les titres pour aller simple

Mélanie,

 

Ce guillemet était une faute de frappe. Après avoir copié mon script, j'ai changé cela pour dire TargetParameter et j'ai raté la suppression de ce guillemet supplémentaire.

Vous m'avez cependant aidé à voir mon erreur/problème et cela fonctionne maintenant. (Merci beaucoup)

 

Le problème était dans la première ligne d'expédition, j'avais:

 

Dispatch({}, "Oneway Analysis of MEAS_DATA By Status", OutlineBox, {Set Title(TargetParameter)}),

Quand j'aurais dû avoir :

 

Dispatch({}, "Oneway Analysis of PARAMETER_VALUE By Status", OutlineBox, {Set Title( TargetParameter )}),

Je n'ai pas pensé à changer cela parce que je ne pensais pas que cela ferait une différence, mais je suppose que cela doit correspondre à tout ce qui est entré pour Y et X.

 

Merci encore pour votre réponse, je ne l'aurais probablement pas remarqué sans vous.

 

 

Re : Changer les titres pour aller simple

La première chose que je vois, c'est que lorsque je sélectionne votre script pour Oneway, il y a un guillemet parasite après TargetParameter pour Oneway qui n'est pas là pour Distribution. Vous devez le sélectionner pour le voir - je ne sais pas pourquoi.

{Set Title( TargetParameter")}

Si je lance cela, j'obtiens des erreurs de syntaxe parce que tout est foiré. Mais si je supprime le guillemet, cela fonctionne pour moi. Voici ce que je l'ai changé pour pouvoir l'exécuter.J'ai apporté quelques modifications aux numéros d'axe pour que les données apparaissent dans le graphique, et j'ai commenté la ligne faisant référence à une zone d'édition de texte qui n'apparaît pas dans mon rapport. Mais le titre de la boîte de contour est remplacé par ce que j'ai défini TargetParameter égal à (dans ce cas, "F").

dt = Open("$SAMPLE_DATA/Big Class.jmp");
TargetParameter = "F";
Limit_UCL = 100;

Template_TM = Expr(
 TM = Oneway(
  Y(:weight),
  X(:height),
  Each Pair(1),
  Means and Std Dev(1),
  t Test(1),
  Points Jittered(1),
  Box Plots(1),
  Mean Error Bars(1),
  Std Dev Lines(1),
  Comparison Circles(1),
  X Axis Proportional(0),
  Histograms(0),
  Where(:sex == Eval(TargetParameter)),
  SendToReport(
   Dispatch({}, "Oneway Analysis of weight By height", OutlineBox, {Set Title( TargetParameter )}),
   Dispatch({}, "1", ScaleBox, {Scale("Log"), Min(60), Max(150), Inc(1), Minor Ticks(1), Label Row Nesting(1), Add Ref Line(Eval(Limit_UCL), "Dotted", "Dark Blue", "UCL", 1)}),
  // Dispatch({}, "MEAS_DATA", TextEditBox, {Set Text("E10 Atoms / cm2")}),
   Dispatch({}, "Oneway Plot", FrameBox,),
   Dispatch({}, "Means Comparisons", OutlineBox, {Close(1)})
  )
 );
)