46835_es-ES

liliconcom

Unión de varias tablas y salida

Hola,

 

Probé la función Unir tabla y creo que puede unirse una a la vez (por ejemplo, dt1 unirse con dt2) y obtendremos una tabla de salida (dtnew). ¿Cómo puedo usar la tabla de salida ahora (por ejemplo, dtnew) para unirme a otra tabla (por ejemplo, dt3)?

 

Gracias.

Re: Unir varias tablas y salida

Una de las principales necesidades impulsadas por el cliente que se abordó con la capacidad de unión virtual de la versión 13 de JMP fue la huella de conservación de la memoria. Me alegro de que esto funcione para tu situación.

Re: Unir varias tablas y salida

Eso también ayudaría y ahorra memoria. Gracias Pete

Re: Unir varias tablas y salida

para apilar @txnelson y mi colega @Bill_Worley otra opción potencial más es utilizar también la capacidad de unirse a la tabla virtual de JMP 13. Aquí está el enlace a la documentación en línea de JMP para la capacidad de unión virtual.

 

http://www.jmp.com/support/help/13-2/Virtual_Join_Properties.shtml

 

 

Re: Unir varias tablas y salida

Gracias HTH! Eso también ayuda. Nunca lo había pensado. Aprendiendo otras cosas nuevas

Re: Unir varias tablas y salida

No estoy seguro de si esta es su intención, pero si lo que desea es unir varias tablas y está utilizando JMP 13, puede ir al menú desplegable Tablas y seleccionar JMP Query Builder.Desde allí, puede unirse a hasta 60 mesas a la vez en lugar de tener que crear un script para unirse.

 

HTH

Re: Unir varias tablas y salidaGracias, eso es maravilloso Jim! Logré escribir un script que es similar pero un poco complejo Me acabas de facilitar la comprensión. Valora eso..Re: Unir varias tablas y salida

Aquí hay un método que crea tablas separadas para cada combinación.

Names Default To Here( 1 );

// Create the original table
dtBase = New Table( "Base Table",
 Add Rows( 10 ),
 New Column( "name",
  character,
  Set Values( {"KATIE", "LOUISE", "JANE", "JACLYN", "LILLIE", "TIM", "JAMES", "ROBERT", "BARBARA", "ALICE"} )
 ),
 New Column( "age", Set Values( [12, 12, 12, 12, 12, 12, 12, 12, 13, 13] ) ),
 New Column( "sex", character, Set Values( {"F", "F", "F", "F", "F", "M", "M", "M", "F", "F"} ) )
);

// Create a second table
dt2 = New Table( "Height",
 Add Rows( 10 ),
 New Column( "name",
  character,
  Set Values( {"KATIE", "LOUISE", "JANE", "JACLYN", "LILLIE", "TIM", "JAMES", "ROBERT", "BARBARA", "ALICE"} )
 ),
 New Column( "height", Set Values( [59, 61, 55, 66, 52, 60, 61, 51, 60, 61] ) ),
 Set Label Columns( :name )
);

// Join the two tables and create a reference to the new table
dtjoined = dtBase << Join(
 With( dt2 ),
 By Matching Columns( :name = :name ),
 Drop multiples( 0, 0 ),
 Include Nonmatches( 0, 0 ),
 Preserve main table order( 1 ),
 Merge same name columns( 1 ),
 Match Flag( 0 )
);

// Close the nolonger needed tables and set the base table reference to the new table
Close( dtBase, nosave );
Close( dt2, nosave );
dtBase = dtjoined;

// Create another table to be joined
dt3 = New Table( "Weight",
 Add Rows( 10 ),
 New Column( "name",
  character,
  Set Values( {"KATIE", "LOUISE", "JANE", "JACLYN", "LILLIE", "TIM", "JAMES", "ROBERT", "BARBARA", "ALICE"} )
 ),
 New Column( "weight", Set Values( [95, 123, 74, 145, 64, 84, 128, 79, 112, 107] ) ),
 Set Label Columns( :name )
);

// Join the new table
dtjoined = dtBase << Join(
 With( dt3 ),
 By Matching Columns( :name = :name ),
 Drop multiples( 0, 0 ),
 Include Nonmatches( 0, 0 ),
 Preserve main table order( 1 ),
 Merge same name columns( 1 ),
 Match Flag( 0 )
);

// Close the nolonger needed tables and set the base table reference to the new table
Close( dtBase, nosave );
Close( dt3, nosave );
dtBase = dtjoined;