46835_de-DE

liliconcom

Zusammenfügen mehrerer Tabellen und Ausgabe

Hallo,

 

Ich habe die Funktion „Tabelle verbinden“ ausprobiert und denke, dass damit eine Verknüpfung nacheinander möglich ist (z. B. dt1-Verknüpfung mit dt2), und wir erhalten eine Ausgabetabelle (dtnew). Wie kann ich die jetzt ausgegebene Tabelle (z. B. dtnew) verwenden, um sie mit einer anderen Tabelle (z. B. dt3) zu verbinden?

 

Danke schön.

Betreff: Mehrere Tabellen zusammenführen und ausgeben

Eine der wichtigsten kundenorientierten Anforderungen, die durch die Virtual-Join-Funktion von JMP Version 13 erfüllt wurde, war die Speichereinsparung. Ich freue mich sehr, dass dies für Ihre Situation funktioniert.

Betreff: Mehrere Tabellen zusammenführen und ausgeben

Das würde auch helfen und Speicherplatz sparen. Danke Pete

Betreff: Mehrere Tabellen zusammenführen und ausgeben

Zum Aufstapeln @txnelson und mein Kollege @Bill_Worley Eine weitere mögliche Option besteht darin, auch die Virtual Table Join-Funktion von JMP 13 zu nutzen. Hier ist der Link zur JMP-Onlinedokumentation für die virtuelle Join-Funktion.

 

http://www.jmp.com/support/help/13-2/Virtual_Join_Properties.shtml

 

 

Betreff: Mehrere Tabellen zusammenführen und ausgeben

Danke HTH! Das hilft auch. Habe niemals drüber nachgedacht. Noch etwas Neues lernen

Betreff: Mehrere Tabellen zusammenführen und ausgeben

Ich bin mir nicht sicher, ob dies Ihre Absicht ist, aber wenn Sie mehrere Tabellen verknüpfen möchten und JMP 13 verwenden, können Sie im Dropdown-Menü „Tabellen“ JMP Query Builder auswählen.Von dort aus können Sie bis zu 60 Tabellen gleichzeitig verknüpfen, anstatt einen Join per Skript durchführen zu müssen.

 

HTH

Betreff: Mehrere Tabellen zusammenführen und ausgebenDanke, das ist wunderbar, Jim! Ich habe es geschafft, ein Skript zu schreiben, das ähnlich, aber etwas komplex ist Du hast es mir nur leichter gemacht, es zu verstehen. Ich weiß es zu schätzen..Betreff: Mehrere Tabellen zusammenführen und ausgeben

Hier ist eine Methode, die für jeden Join separate Tabellen erstellt.

Names Default To Here( 1 );

// Create the original table
dtBase = New Table( "Base Table",
 Add Rows( 10 ),
 New Column( "name",
  character,
  Set Values( {"KATIE", "LOUISE", "JANE", "JACLYN", "LILLIE", "TIM", "JAMES", "ROBERT", "BARBARA", "ALICE"} )
 ),
 New Column( "age", Set Values( [12, 12, 12, 12, 12, 12, 12, 12, 13, 13] ) ),
 New Column( "sex", character, Set Values( {"F", "F", "F", "F", "F", "M", "M", "M", "F", "F"} ) )
);

// Create a second table
dt2 = New Table( "Height",
 Add Rows( 10 ),
 New Column( "name",
  character,
  Set Values( {"KATIE", "LOUISE", "JANE", "JACLYN", "LILLIE", "TIM", "JAMES", "ROBERT", "BARBARA", "ALICE"} )
 ),
 New Column( "height", Set Values( [59, 61, 55, 66, 52, 60, 61, 51, 60, 61] ) ),
 Set Label Columns( :name )
);

// Join the two tables and create a reference to the new table
dtjoined = dtBase << Join(
 With( dt2 ),
 By Matching Columns( :name = :name ),
 Drop multiples( 0, 0 ),
 Include Nonmatches( 0, 0 ),
 Preserve main table order( 1 ),
 Merge same name columns( 1 ),
 Match Flag( 0 )
);

// Close the nolonger needed tables and set the base table reference to the new table
Close( dtBase, nosave );
Close( dt2, nosave );
dtBase = dtjoined;

// Create another table to be joined
dt3 = New Table( "Weight",
 Add Rows( 10 ),
 New Column( "name",
  character,
  Set Values( {"KATIE", "LOUISE", "JANE", "JACLYN", "LILLIE", "TIM", "JAMES", "ROBERT", "BARBARA", "ALICE"} )
 ),
 New Column( "weight", Set Values( [95, 123, 74, 145, 64, 84, 128, 79, 112, 107] ) ),
 Set Label Columns( :name )
);

// Join the new table
dtjoined = dtBase << Join(
 With( dt3 ),
 By Matching Columns( :name = :name ),
 Drop multiples( 0, 0 ),
 Include Nonmatches( 0, 0 ),
 Preserve main table order( 1 ),
 Merge same name columns( 1 ),
 Match Flag( 0 )
);

// Close the nolonger needed tables and set the base table reference to the new table
Close( dtBase, nosave );
Close( dt3, nosave );
dtBase = dtjoined;