46835_fr-FR

liliconcom

Joindre plusieurs tables et sorties

Salut,

 

J'ai essayé la fonction Join table et je pense qu'elle est capable d'en joindre une à la fois (par exemple, dt1 join with dt2) et nous obtiendrons une table de sortie (dtnew). Comment puis-je utiliser la table de sortie maintenant (par exemple, dtnew) pour rejoindre une autre table (par exemple, dt3).

 

Merci.

Re : Rejoindre plusieurs tables et sortie

L'un des principaux besoins des clients auxquels répondait la fonction de jointure virtuelle de JMP version 13 était l'encombrement de la mémoire. Je suis tellement content que cela fonctionne pour votre situation.

Re : Rejoindre plusieurs tables et sortie

Cela aiderait aussi et cela économise de la mémoire. Merci Pete

Re : Rejoindre plusieurs tables et sortie

A empiler sur @txnelson et mon collègue @Bill_Worley encore une autre option potentielle consiste à utiliser également la fonctionnalité de jointure de table virtuelle de JMP 13. Voici le lien vers la documentation en ligne de JMP pour la fonctionnalité de jointure virtuelle.

 

http://www.jmp.com/support/help/13-2/Virtual_Join_Properties.shtml

 

 

Re : Rejoindre plusieurs tables et sortie

Merci HTH ! Cela aide aussi. Je n'y ai jamais pensé. Apprendre encore de nouvelles choses

Re : Rejoindre plusieurs tables et sortie

Je ne sais pas si c'est votre intention, mais si vous voulez joindre plusieurs tables et que vous utilisez JMP 13, vous pouvez accéder au menu déroulant Tables et sélectionner JMP Query Builder.À partir de là, vous pouvez joindre jusqu'à 60 tables à la fois au lieu d'avoir à créer un script de jointure.

 

HTH

Re : Rejoindre plusieurs tables et sortieMerci, c'est merveilleux Jim ! J'ai réussi à écrire un script similaire mais un peu complexe Vous venez de me faciliter la compréhension. J'apprécie cela..Re : Rejoindre plusieurs tables et sortie

Voici une méthode qui crée des tables séparées pour chaque jointure.

Names Default To Here( 1 );

// Create the original table
dtBase = New Table( "Base Table",
 Add Rows( 10 ),
 New Column( "name",
  character,
  Set Values( {"KATIE", "LOUISE", "JANE", "JACLYN", "LILLIE", "TIM", "JAMES", "ROBERT", "BARBARA", "ALICE"} )
 ),
 New Column( "age", Set Values( [12, 12, 12, 12, 12, 12, 12, 12, 13, 13] ) ),
 New Column( "sex", character, Set Values( {"F", "F", "F", "F", "F", "M", "M", "M", "F", "F"} ) )
);

// Create a second table
dt2 = New Table( "Height",
 Add Rows( 10 ),
 New Column( "name",
  character,
  Set Values( {"KATIE", "LOUISE", "JANE", "JACLYN", "LILLIE", "TIM", "JAMES", "ROBERT", "BARBARA", "ALICE"} )
 ),
 New Column( "height", Set Values( [59, 61, 55, 66, 52, 60, 61, 51, 60, 61] ) ),
 Set Label Columns( :name )
);

// Join the two tables and create a reference to the new table
dtjoined = dtBase << Join(
 With( dt2 ),
 By Matching Columns( :name = :name ),
 Drop multiples( 0, 0 ),
 Include Nonmatches( 0, 0 ),
 Preserve main table order( 1 ),
 Merge same name columns( 1 ),
 Match Flag( 0 )
);

// Close the nolonger needed tables and set the base table reference to the new table
Close( dtBase, nosave );
Close( dt2, nosave );
dtBase = dtjoined;

// Create another table to be joined
dt3 = New Table( "Weight",
 Add Rows( 10 ),
 New Column( "name",
  character,
  Set Values( {"KATIE", "LOUISE", "JANE", "JACLYN", "LILLIE", "TIM", "JAMES", "ROBERT", "BARBARA", "ALICE"} )
 ),
 New Column( "weight", Set Values( [95, 123, 74, 145, 64, 84, 128, 79, 112, 107] ) ),
 Set Label Columns( :name )
);

// Join the new table
dtjoined = dtBase << Join(
 With( dt3 ),
 By Matching Columns( :name = :name ),
 Drop multiples( 0, 0 ),
 Include Nonmatches( 0, 0 ),
 Preserve main table order( 1 ),
 Merge same name columns( 1 ),
 Match Flag( 0 )
);

// Close the nolonger needed tables and set the base table reference to the new table
Close( dtBase, nosave );
Close( dt3, nosave );
dtBase = dtjoined;