82841_de-DE

liliconcom

Wie füge ich zwei Zeilen zusammen, die keine Schlüsselspalte haben?

Hallo JMP-Community,

 

Ich mache also ein Projekt für einen Freund, bei dem ich Statistiken für Cricket-Spieler in der indischen Liga analysiere. Ich verwende die Internet-Open-Option in JMP, um die Daten aus dem Internet zu erhalten. Ich bekomme die Tabelle unten. Ich frage mich, ob es durch JMP oder SAS irgendeine Möglichkeit gibt, die Reihen mit den Statistiken des Spielers mit der Reihe darunter zu verbinden, in der sich das Team des Spielers befindet. Jede Hilfe wird geschätzt

 

Vielen Dank

IC

 

Re: Wie füge ich zwei Zeilen zusammen, die keine Schlüsselspalte haben?

Vielen Dank für Ihre Lösung. Ich habe das Skript so bearbeitet, dass die Zeilen mit allen Teams (die geraden Zeilen) eine Matrix A füllen. 

dt= current data table();
// Find all of the rows that have the teams
dt << select where( Substr( :Player, 1, 1 ) == "(" );

A= dt << Get Rows Where(Substr( :Player, 1, 1 ) == "(");

// Copy the team rows to a new table
dt2 = dt << Subset(
 Selected Rows( 0 ),
 rows(A),
 Selected columns only( 0 )
);

// Delete the team rows from the starting data table
dt << delete rows;

// Join the 2 data tables
dt3 = dt << Join( With( dt2 ), By Row Number );

Re: Wie füge ich zwei Zeilen zusammen, die keine Schlüsselspalte haben?

Hier ist eine Möglichkeit, dies zu tun.  Es trennt die Daten in zwei Tabellen und fügt sie basierend auf der Zeilennummer zusammen.  Ich mache das mit einem Skript, aber das Skript wurde erstellt, indem es die interaktiven Schritte durchführte und die von JMP erstellten Skripts kopierte.  Ich verwende eine verkürzte Datentabelle, weil ich faul bin und nicht gerne tippe.

Names Default To Here( 1 );
// Create a sample data table
dt = New Table( "Untitled 10",
 Add Rows( 6 ),
 New Column( "Player",
  Character,
  "Nominal",
  Set Values( {"AR Bawne", "(Delhi Daredevils)", "VR Aaron", "(Kings XI Punjab)", "AD Nath", "(Gujarat Lions)"} ),
  Set Display Width( 122 )
 ),
 New Column( "Mat",
  Character,
  "Nominal",
  Set Values( {"1", "(Delhi Daredevils)", "6", "(Kings XI Punjab)", "1", "(Gujarat Lions)"} ),
  Set Display Width( 137 )
 ),
 New Column( "Inns",
  Character,
  "Nominal",
  Set Values( {"1", "(Delhi Daredevils)", "2", "(Kings XI Punjab)", "1", "(Gujarat Lions)"} ),
  Set Display Width( 160 )
 )
);

wait(3);

// Find all of the rows that have the teams
dt << select where( Substr( :Player, 1, 1 ) == "(" );

// Copy the team rows to a new table
dt2 = dt << Subset(
 Selected Rows( 0 ),
 Rows( [2, 4, 6] ),
 Selected columns only( 0 )
);

// Delete the team rows from the starting data table
dt << delete rows;

// Change the columns to numeric in the starting data table(just because)
For( i = 2, i <= N Cols( dt ), i++,
 Column( dt, i ) << data type( numeric ) <<
 modeling type( continuous )
);

// Join the 2 data tables
dt3 = dt << Join( With( dt2 ), By Row Number );