82841_ja-JP

liliconcom

キー列を持たない2行をマージする方法

こんにちはJMPコミュニティ、

 

だから私はインドのリーグでクリケット選手のための統計を分析している友人のためのプロジェクトをやっています。インターネットからデータを取得するためにJMPでインターネットオープンオプションを使用しています。私は下の表を見ます。JMPまたはSASを介して、プレーヤーのチームがある行のすぐ下の行に、プレーヤーの統計と行をマージできる方法があるかどうか私は疑問に思います。どんな助けでも心配されるでしょう

 

ありがとうございました

IC

 

再：どのように私はキー列を持たない2つの行をマージするのですか

あなたの解決をありがとう。すべてのチームを含む行（偶数行）が行列Aになるようにスクリプトを編集しました。 

dt= current data table();
// Find all of the rows that have the teams
dt << select where( Substr( :Player, 1, 1 ) == "(" );

A= dt << Get Rows Where(Substr( :Player, 1, 1 ) == "(");

// Copy the team rows to a new table
dt2 = dt << Subset(
 Selected Rows( 0 ),
 rows(A),
 Selected columns only( 0 )
);

// Delete the team rows from the starting data table
dt << delete rows;

// Join the 2 data tables
dt3 = dt << Join( With( dt2 ), By Row Number );

再：どのように私はキー列を持たない2つの行をマージするのですか

これを行う1つの方法があります。  データを2つのテーブルに分割してから、行番号に基づいてそれらをマージします。  私はスクリプトを使ってこれをやっていますが、スクリプトは対話的なステップを経てJMPが作成したスクリプトをコピーするだけで作られました。  私は怠惰で、タイプするのが好きではないので、私は短縮データテーブルを使用しています。

Names Default To Here( 1 );
// Create a sample data table
dt = New Table( "Untitled 10",
 Add Rows( 6 ),
 New Column( "Player",
  Character,
  "Nominal",
  Set Values( {"AR Bawne", "(Delhi Daredevils)", "VR Aaron", "(Kings XI Punjab)", "AD Nath", "(Gujarat Lions)"} ),
  Set Display Width( 122 )
 ),
 New Column( "Mat",
  Character,
  "Nominal",
  Set Values( {"1", "(Delhi Daredevils)", "6", "(Kings XI Punjab)", "1", "(Gujarat Lions)"} ),
  Set Display Width( 137 )
 ),
 New Column( "Inns",
  Character,
  "Nominal",
  Set Values( {"1", "(Delhi Daredevils)", "2", "(Kings XI Punjab)", "1", "(Gujarat Lions)"} ),
  Set Display Width( 160 )
 )
);

wait(3);

// Find all of the rows that have the teams
dt << select where( Substr( :Player, 1, 1 ) == "(" );

// Copy the team rows to a new table
dt2 = dt << Subset(
 Selected Rows( 0 ),
 Rows( [2, 4, 6] ),
 Selected columns only( 0 )
);

// Delete the team rows from the starting data table
dt << delete rows;

// Change the columns to numeric in the starting data table(just because)
For( i = 2, i <= N Cols( dt ), i++,
 Column( dt, i ) << data type( numeric ) <<
 modeling type( continuous )
);

// Join the 2 data tables
dt3 = dt << Join( With( dt2 ), By Row Number );