82841_it-IT

liliconcom

Come faccio a unire due righe che non hanno una colonna chiave

Ciao community JMP,

 

Quindi sto facendo un progetto per un amico dove sto analizzando le statistiche per i giocatori di cricket nella Indian League. Sto utilizzando l'opzione di apertura di Internet in JMP per ottenere i dati da Internet. Prendo la tabella qui sotto. Mi chiedo se ci sia un modo attraverso JMP o SAS che io possa unire le righe con le statistiche del giocatore con la fila proprio sotto quella che ha la squadra del giocatore. Qualsiasi aiuto sarebbe apprezzato

 

Grazie

CIRCUITO INTEGRATO

 

Ri: Come faccio a unire due righe che non hanno una colonna chiave

Grazie per la soluzione. Ho modificato lo script in modo che le righe con tutte le squadre (le righe pari) riempissero una matrice A. 

dt= current data table();
// Find all of the rows that have the teams
dt << select where( Substr( :Player, 1, 1 ) == "(" );

A= dt << Get Rows Where(Substr( :Player, 1, 1 ) == "(");

// Copy the team rows to a new table
dt2 = dt << Subset(
 Selected Rows( 0 ),
 rows(A),
 Selected columns only( 0 )
);

// Delete the team rows from the starting data table
dt << delete rows;

// Join the 2 data tables
dt3 = dt << Join( With( dt2 ), By Row Number );

Ri: Come faccio a unire due righe che non hanno una colonna chiave

Ecco un modo per farlo.  Separa i dati in due tabelle e li unisce in base al numero di riga.  Lo sto facendo con uno script, ma lo script è stato creato seguendo semplicemente i passaggi interattivi per eseguire questa operazione e copiando gli script creati da JMP.  Sto usando una tabella di dati abbreviata, perché sono pigro e non mi piace digitare.

Names Default To Here( 1 );
// Create a sample data table
dt = New Table( "Untitled 10",
 Add Rows( 6 ),
 New Column( "Player",
  Character,
  "Nominal",
  Set Values( {"AR Bawne", "(Delhi Daredevils)", "VR Aaron", "(Kings XI Punjab)", "AD Nath", "(Gujarat Lions)"} ),
  Set Display Width( 122 )
 ),
 New Column( "Mat",
  Character,
  "Nominal",
  Set Values( {"1", "(Delhi Daredevils)", "6", "(Kings XI Punjab)", "1", "(Gujarat Lions)"} ),
  Set Display Width( 137 )
 ),
 New Column( "Inns",
  Character,
  "Nominal",
  Set Values( {"1", "(Delhi Daredevils)", "2", "(Kings XI Punjab)", "1", "(Gujarat Lions)"} ),
  Set Display Width( 160 )
 )
);

wait(3);

// Find all of the rows that have the teams
dt << select where( Substr( :Player, 1, 1 ) == "(" );

// Copy the team rows to a new table
dt2 = dt << Subset(
 Selected Rows( 0 ),
 Rows( [2, 4, 6] ),
 Selected columns only( 0 )
);

// Delete the team rows from the starting data table
dt << delete rows;

// Change the columns to numeric in the starting data table(just because)
For( i = 2, i <= N Cols( dt ), i++,
 Column( dt, i ) << data type( numeric ) <<
 modeling type( continuous )
);

// Join the 2 data tables
dt3 = dt << Join( With( dt2 ), By Row Number );