82841_fr-FR

liliconcom

Comment fusionner deux lignes sans colonne de clé

Bonjour la communauté JMP,

 

Donc, je fais un projet pour un ami où j’analyse les statistiques des joueurs de cricket de la Ligue indienne. J'utilise l'option d'ouverture Internet dans JMP pour obtenir les données à partir d'Internet. Je reçois le tableau ci-dessous. Je me demande s'il existe un moyen d'utiliser JMP ou SAS pour fusionner les lignes avec les statistiques du joueur avec la ligne juste en dessous, qui contient l'équipe du joueur. Toute aide serait appréciée

 

Je vous remercie

IC

 

Re: Comment puis-je fusionner deux lignes qui n'ont pas de colonne clé

Merci pour votre solution. J'ai édité le script pour que les lignes avec toutes les équipes (les lignes paires) remplissent une matrice A. 

dt= current data table();
// Find all of the rows that have the teams
dt << select where( Substr( :Player, 1, 1 ) == "(" );

A= dt << Get Rows Where(Substr( :Player, 1, 1 ) == "(");

// Copy the team rows to a new table
dt2 = dt << Subset(
 Selected Rows( 0 ),
 rows(A),
 Selected columns only( 0 )
);

// Delete the team rows from the starting data table
dt << delete rows;

// Join the 2 data tables
dt3 = dt << Join( With( dt2 ), By Row Number );

Re: Comment puis-je fusionner deux lignes qui n'ont pas de colonne clé

Voici une façon de faire cela.  Il sépare les données en deux tables, puis les fusionne en fonction du numéro de ligne.  Je le fais avec un script, mais le script a été créé en suivant simplement les étapes interactives pour le faire et en copiant les scripts créés par JMP.  J'utilise un tableau de données abrégé, car je suis paresseux et n'aime pas taper.

Names Default To Here( 1 );
// Create a sample data table
dt = New Table( "Untitled 10",
 Add Rows( 6 ),
 New Column( "Player",
  Character,
  "Nominal",
  Set Values( {"AR Bawne", "(Delhi Daredevils)", "VR Aaron", "(Kings XI Punjab)", "AD Nath", "(Gujarat Lions)"} ),
  Set Display Width( 122 )
 ),
 New Column( "Mat",
  Character,
  "Nominal",
  Set Values( {"1", "(Delhi Daredevils)", "6", "(Kings XI Punjab)", "1", "(Gujarat Lions)"} ),
  Set Display Width( 137 )
 ),
 New Column( "Inns",
  Character,
  "Nominal",
  Set Values( {"1", "(Delhi Daredevils)", "2", "(Kings XI Punjab)", "1", "(Gujarat Lions)"} ),
  Set Display Width( 160 )
 )
);

wait(3);

// Find all of the rows that have the teams
dt << select where( Substr( :Player, 1, 1 ) == "(" );

// Copy the team rows to a new table
dt2 = dt << Subset(
 Selected Rows( 0 ),
 Rows( [2, 4, 6] ),
 Selected columns only( 0 )
);

// Delete the team rows from the starting data table
dt << delete rows;

// Change the columns to numeric in the starting data table(just because)
For( i = 2, i <= N Cols( dt ), i++,
 Column( dt, i ) << data type( numeric ) <<
 modeling type( continuous )
);

// Join the 2 data tables
dt3 = dt << Join( With( dt2 ), By Row Number );