49647_it-IT

liliconcom

Come eseguo gli script JMP in base a una pianificazione

Ho una serie di analisi JMP che desidero eseguire in produzione e salvare l'output in file HTML interattivi.

Ho capito come inserire le analisi in file di script e dashboard, ma non mi è chiaro come impostare le cose in modo che il computer esegua automaticamente gli script su base giornaliera o oraria.È possibile?

 

Jim

Ri: Come eseguo gli script JMP in base a una pianificazione

Sto usando una macchina Windows.La tua risposta funziona bene, anche se avevo bisogno di specificare che JMP si sarebbe chiuso senza chiedere di ricordare i file aperti.

Grazie mille

Ri: Come eseguo gli script JMP in base a una pianificazione

Non sono sicuro che tu sia su Windows o Mac, ma in Windows utilizzo l'Utilità di pianificazione (cercalo utilizzando il pulsante di avvio) per eseguire il file batch (sceglilo come "Applicazione da eseguire").Il file batch chiama JMP e gli dice quale script aprire.Assicurati di inserire exit( nosave ) alla fine dello script jsl.

 

File batch:

"C:\Program Files\SAS\JMPPRO\13\jmp.exe" "C:/pathto/TaskSchedulerGraphs.jsl"

 

File JSL:

Names default to here( 1 );

dt = Open( "$SAMPLE_DATA/iris.jmp" );

height = { 800, 1080 };

t = Today();

pad = function( {v} , if( v < 10, "0", "" ) || char(v) );

for( i = 1, i <= n items( height ), i++,
 win = New Window( "graph holder",
  dt << Graph Builder(
   Size( floor( height[i] * 16 / 9 ), height[i] ),
   Show Control Panel( 0 ),
   Variables(
    X( :Sepal length ),
    Y( :Sepal width ),
    Group X( :Species ),
    Group Y( :Petal width ),
    Color( :Petal length )
   ),
   Elements( Points( X, Y, Legend( 4 ) ) )
  );
 );
 pic = ( win << Find( ListBox(2) ) ) << get picture;
 ImageFilename = "iris_" || pad( Hour( t ) ) || pad( Minute( t ) ) ||
  pad( Second( t ) ) || "_" || char( height[i] ) || ".png";
 pic << Save Image( "$Desktop/" || ImageFilename );
 win << Close Window;
);

exit(nosave);

Re: Come si assegna una data di inizio?

Il titolo che voglio per questo post è: "Come eseguo gli script JMP in base a una pianificazione, in altre parole in base alla produzione"