49046_it-IT

liliconcom

Come impedire che la finestra di dialogo "Confronto utilità" venga visualizzata in DOE Consumer Choice utilizzando JSL?

Devo esaminare una lunga lista di modelli di scelta del consumatore nel DOE. Sto usando la sintassi JSL, perché voglio che vengano eseguiti senza sorveglianza. Sfortunatamente, questo non funziona, poiché la finestra di dialogo "Confronto utilità" mostra dopo l'avvio di ciascun modello e richiede l'inserimento manuale. Alcuni modelli sollevano questo dialogo e altri no. La sintassi di seguito sembra sollevarla. Mi piacerebbe sapere se c'è sintassi per impedire che accada.

 

Grazie in anticipo!

 

SINTASSI SEGUE - (A causa di problemi di riservatezza, non sono in grado di condividere il file di dati per il test.)

Choice(
 Response Data Table( Data Table( "Selections" ) ),
 Profile DataTable( Choice Profiles ),
 Subject DataTable( Data Table( "Selections" ) ),
 Response Subject ID( :QID ),
 Response Grouping( :QIndex ),
 Profile ID( :Choice ID ),
 Profile Grouping( :Choice Set ),
 Profile Effects(
  :Name( "Attribute A" ),
  :Name( "Attribute B" ),
  :Name( "Attribute C" ),
  :Name( "Attribute D" ),
  :Name( "Attribute E" )
 ),
 Subject Effects( :GENDER ),
 Name( "Firth Bias-Adjusted Estimates" )(1),
 Response Profile ID Chosen( :OptionChosen ),
 Likelihood Ratio Tests( 1 )
);

 

 

Ri: Come posso evitare che la finestra di dialogo "Confronto utilità" venga visualizzata in DOE Consumer Choice

Ciao, 

Non penso che il codice pubblicato causerà l'apertura della finestra di dialogo Confronto delle utilità. Forse hai qualcosa di più simile a questo?

 

 

Open("$SAMPLE_DATA\Pizza Combined.jmp");

Choice(
 One Table( 1 ),
 Subject ID( :Subject ),
 Choice Set ID( :Trial ),
 Profile ID( :Indicator ),
 Profile Effects( :Crust, :Cheese, :Topping ),
 Name( "Firth Bias-Adjusted Estimates" )(1),
 Likelihood Ratio Tests( 1 ),
 Comparisons()
);

Notare i confronti vuoti () nello script. Se si dispone di una specifica incompleta per i confronti di utilità nel codice della piattaforma Choice, ciò causerà l'apertura della finestra di dialogo. 

Se il report richiede confronti di utilità, è sufficiente assicurarsi che i confronti siano completati in modo completo. Questo script viene eseguito anche senza aprire una finestra di confronto. 

Open("$SAMPLE_DATA\Pizza Combined.jmp");

Choice(
 One Table( 1 ),
 Subject ID( :Subject ),
 Choice Set ID( :Trial ),
 Profile ID( :Indicator ),
 Profile Effects( :Crust, :Cheese, :Topping ),
 Name( "Firth Bias-Adjusted Estimates" )(1),
 Likelihood Ratio Tests( 1 ),
 Comparisons(
  {Crust( "Thick" ), Cheese( "Jack" ), Topping( "Pepperoni" )},
  {Crust( "Thin" ), Cheese( "Jack" ), Topping( "Pepperoni" )}
 ),
 Comparisons(
  {Crust( "Thick" ), Cheese( "Mozzarella" ), Topping( "Pepperoni" )},
  {Crust( "Thick" ), Cheese( "Jack" ), Topping( "Pepperoni" )}
 ),
 Comparisons(
  {Crust( "Thick" ), Cheese( "Jack" ), Topping( "Pepperoni" )},
  {Crust( "Thick" ), Cheese( "Jack" ), Topping( "None" )}
 )
);